V našem předchozím kurzu jsme se zabývali vzorci aplikace Excel, které v případě, že cílová buňka obsahuje danou hodnotu, vracejí do jiného sloupce nějakou hodnotu. Co dalšího můžete kromě toho dělat, pokud buňka obsahuje určitý text nebo číslo? Řadu věcí, jako je počítání nebo sčítání buněk, zvýrazňování, odstraňování nebo kopírování celých řádků a další.

Příklady vzorce Excel 'Počítat, pokud buňka obsahuje'

V aplikaci Microsoft Excel existují dvě funkce pro počítání buněk na základě jejich hodnot, COUNTIF a COUNTIFS. Tyto funkce pokrývají většinu scénářů, i když ne všechny. V níže uvedených příkladech se naučíte, jak vybrat vhodný vzorec Count if cell contains pro konkrétní úlohu.

Počítat, zda buňka obsahuje nějaký text

V situacích, kdy chcete spočítat buňky obsahující libovolný text, použijte jako kritérium ve vzorci COUNTIF zástupný znak hvězdička:

Nebo použijte funkci SUMPRODUCT v kombinaci s ISTEXT:

Ve druhém vzorci funkce ISTEXT vyhodnotí každou buňku v zadaném rozsahu a vrátí pole hodnot TRUE (text) a FALSE (není text); dvojitý unární operátor (--) převede hodnoty TRUE a FALSE na 1 a 0 a funkce SUMPRODUCT tato čísla sečte.

Jak ukazuje obrázek níže, oba vzorce dávají stejný výsledek:

=COUNTIF(A2:A10, "*")

=SOUČIN(--(ISTEXT(A2:A10))

Můžete se také podívat, jak v aplikaci Excel počítat neprázdné buňky.

Počítat, zda buňka obsahuje určitý text

Chcete-li spočítat buňky, které obsahují určitý text, použijte jednoduchý vzorec COUNTIF, jak je uvedeno níže, kde rozsah jsou buňky, které se mají zkontrolovat, a text je hledaný textový řetězec nebo odkaz na buňku obsahující textový řetězec.

Chcete-li například spočítat buňky v rozsahu A2:A10, které obsahují slovo "dress", použijte tento vzorec:

=COUNTIF(A2:A10, "dress")

Nebo ten, který je zobrazen na snímku obrazovky:

Další příklady vzorců najdete zde: Jak počítat buňky s textem v aplikaci Excel: libovolné, konkrétní, filtrované buňky.

Počítat, zda buňka obsahuje text (částečná shoda)

Chcete-li spočítat buňky, které obsahují určitý podřetězec, použijte funkci COUNTIF se zástupným znakem hvězdičky (*).

Chcete-li například spočítat, kolik buněk ve sloupci A obsahuje jako součást svého obsahu slovo "dress", použijte tento vzorec:

=COUNTIF(A2:A10,"*dress*")

Nebo zadejte požadovaný text do některé buňky a spojte tuto buňku se zástupnými znaky:

=COUNTIF(A2:A10,"*"&D1&"*")

Další informace naleznete v části: Vzorce COUNTIF s částečnou shodou.

Počítat, zda buňka obsahuje více podřetězců (logika AND)

Chcete-li spočítat buňky s více podmínkami, použijte funkci COUNTIFS. Excel COUNTIFS může zpracovat až 127 dvojic rozsah/kritérium a započítány budou pouze buňky, které splňují všechny zadané podmínky.

Chcete-li například zjistit, kolik buněk ve sloupci A obsahuje slovo "dress" A "blue", použijte jeden z následujících vzorců:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Nebo

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Počítat, pokud buňka obsahuje číslo

Vzorec pro počítání buněk s čísly je ten nejjednodušší vzorec, jaký si lze představit:

Mějte na paměti, že funkce POČÍTAT v aplikaci Excel počítá buňky obsahující jakoukoli číselnou hodnotu včetně čísel, dat a časů, protože poslední dvě jmenované jsou z hlediska aplikace Excel také čísla.

V našem případě je vzorec následující:

=COUNT(A2:A10)

Chcete-li spočítat buňky, které NEobsahují čísla, použijte funkci SUMPRODUCT spolu s funkcemi ISNUMBER a NOT:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Součet, pokud buňka obsahuje text

Pokud hledáte vzorec aplikace Excel pro vyhledání buněk obsahujících určitý text a sečtení odpovídajících hodnot v jiném sloupci, použijte funkci SUMIF.

Chcete-li například zjistit, kolik šatů je na skladě, použijte tento vzorec:

=SUMIF(A2:A10,"*dress*",B2:B10)

Kde A2:A10 jsou textové hodnoty, které se mají zkontrolovat, a B2:B10 jsou čísla, která se mají sečíst.

Nebo vložte podřetězec, který vás zajímá, do některé buňky (E1) a odkažte se na tuto buňku ve vzorci, jak je znázorněno na obrázku níže:

Na součet s více kritérii , použijte funkci SUMIFS.

Chcete-li například zjistit, kolik modrých šatů je k dispozici, použijte tento vzorec:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Nebo použijte tento:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Kde A2:A10 jsou buňky ke kontrole a B2:B10 jsou buňky k součtu.

Provádění různých výpočtů na základě hodnoty buňky

V minulém tutoriálu jsme probrali tři různé vzorce pro testování více podmínek a vracení různých hodnot v závislosti na výsledcích těchto testů. A nyní se podíváme, jak můžete provádět různé výpočty v závislosti na hodnotě v cílové buňce.

Předpokládejme, že máte ve sloupci B čísla prodejů a chcete na jejich základě vypočítat bonusy: pokud je prodej vyšší než 300 USD, bonus je 10 %; při prodeji mezi 201 a 300 USD je bonus 7 %; při prodeji mezi 101 a 200 USD je bonus 5 % a při prodeji pod 100 USD není bonus žádný.

Chcete-li to provést, jednoduše vynásobte tržby (B2) příslušným procentem. Jak zjistíte, kterým procentem násobit? Testováním různých podmínek pomocí vnořených IF:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

V reálných pracovních listech může být vhodnější zadávat procenta do samostatných buněk a odkazovat na ně ve vzorci:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Klíčové je zafixovat odkazy na bonusové buňky pomocí znaku $, aby se při kopírování vzorce dolů do sloupce nezměnily.

Podmíněné formátování aplikace Excel, pokud buňka obsahuje určitý text

Pokud chcete zvýraznění buňky s určitým textem, nastavte v aplikaci Excel pravidlo podmíněného formátování založené na jednom z následujících vzorců.

Nerozlišuje velká a malá písmena:

Rozlišování velkých a malých písmen:

Chcete-li například zvýraznit SKU, které obsahují slova "dress", vytvořte pravidlo podmíněného formátování s níže uvedeným vzorcem a použijte ho na tolik buněk ve sloupci A, kolik potřebujete, počínaje buňkou A2:

=SEARCH("dress", A2)>0

Vzorec podmíněného formátování aplikace Excel: pokud buňka obsahuje text (více podmínek)

Chcete-li zvýraznit buňky, které obsahují dva nebo více textových řetězců, vnořte několik funkcí Hledat do vzorce AND. Chcete-li například zvýraznit buňky "modré šaty", vytvořte pravidlo založené na tomto vzorci:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

Podrobný postup naleznete v části Jak vytvořit pravidlo podmíněného formátování pomocí vzorce.

Pokud buňka obsahuje určitý text, odstraňte celý řádek

V případě, že chcete odstranit řádky obsahující konkrétní text, použijte tímto způsobem funkci Najít a nahradit aplikace Excel:

1. Vyberte všechny buňky, které chcete zkontrolovat.
2. Stisknutím klávesové zkratky Ctrl + F otevřete Najít a nahradit dialogové okno.
3. V Zjistěte, co zadejte hledaný text nebo číslo a klikněte na tlačítko . Najít vše
4. Klikněte na libovolný výsledek hledání a stisknutím klávesové zkratky Ctrl + A vyberte všechny.
5. Klikněte na Zavřít zavřít tlačítko Najít a nahradit
6. Stiskněte současně klávesu Ctrl a tlačítko minus ( Ctrl - ), což je zkratka Excelu pro Delete.
7. V Odstranit dialogového okna vyberte možnost Celá řada a klikněte na tlačítko OK. Hotovo!

Na obrázku níže odstraňujeme řádky obsahující slovo "dress":

Pokud buňka obsahuje, vyberte nebo zkopírujte celé řádky

V situacích, kdy chcete vybrat nebo zkopírovat řádky s relevantními daty, použijte k filtrování takových řádků funkci Automatický filtr aplikace Excel. Poté stiskněte klávesy Ctrl + A pro výběr filtrovaných dat, Ctrl + C pro jejich zkopírování a Ctrl + V pro vložení dat na jiné místo.

Chcete-li filtrovat buňky se dvěma nebo více kritérii, použijte Rozšířený filtr k vyhledání takových buněk a poté zkopírujte celé řádky s výsledky nebo vyjměte pouze určité sloupce.

Takto se v Excelu manipuluje s buňkami na základě jejich hodnoty. Děkuji vám za přečtení a doufám, že se příští týden uvidíme na našem blogu!

Cvičebnice

Excel If Cell Contains Then - příklady (.xlsx soubor)