Yn ús foarige tutorial seagen wy nei Excel As formules befettet dy't wat wearde werombringe nei in oare kolom as in doelsel in opjûne wearde befettet. Njonken dat, wat kinne jo dwaan as in sel spesifike tekst of nûmer befettet? In ferskaat oan dingen lykas sellen telle of optellje, markearje, fuortsmite of kopiearje fan folsleine rigen, en mear.

Excel 'Telle as sel befettet' formulefoarbylden

In Microsoft Excel, d'r binne twa funksjes om sellen te tellen op basis fan har wearden, COUNTIF en COUNTIFS. Dizze funksjes dekke de measte, hoewol net alle, senario's. De ûndersteande foarbylden sille jo leare hoe't jo in passende Telling kieze as sel formule befettet foar jo bepaalde taak.

Telle as sel in tekst befettet

Yn situaasjes as jo sellen wolle telle mei elke tekst , brûk it asterisk-jokerteken as kritearia yn jo COUNTIF-formule:

Of brûk de SUMPRODUCT-funksje yn kombinaasje mei ISTEXT:

Yn de twadde formule evaluearret de ISTEXT-funksje elke sel yn it opjûne berik en jout in array fan TRUE (tekst) en FALSE (net tekst) wearden werom; de dûbele unêre operator (--) twingt TRUE en FALSE yn 1's en 0's; en SUMPRODUCT telt de nûmers op.

Lykas werjûn yn it skermôfbylding hjirûnder, jouwe beide formules itselde resultaat:

=COUNTIF(A2:A10,"*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Jo kinne ek wolsjoch hoe't jo net-lege sellen telle yn Excel.

Telle as sel spesifike tekst befettet

Om sellen te tellen dy't spesifike tekst befetsje, brûk in ienfâldige COUNTIF-formule lykas hjirûnder werjûn, wêr't berik is de sellen om te kontrolearjen en tekst is de tekststring om te sykjen of in ferwizing nei de sel mei de tekststring.

Om bygelyks sellen te tellen yn it berik A2:A10 dy't it wurd "jurk" befetsje, brûk dizze formule:

=COUNTIF(A2:A10, "dress")

Of de iene werjûn yn it skermôfbylding:

Jo kinne hjir mear formulesfoarbylden fine: Hoe sellen mei tekst yn Excel te tellen: elke, spesifike, filtere sellen.

Telle as sel tekst befettet (diellike oerienkomst)

Om sellen te tellen dy't in bepaalde substring befetsje, brûk de COUNTIF-funksje mei it asterisk-jokerteken (*).

Bygelyks om te tellen hoefolle sellen yn kolom A "jurk" befetsje as ûnderdiel fan har ynhâld, brûk dizze formule:

=COUNTIF(A2:A10,"*dress*")

Of typ de winske tekst yn in sel en keppelje de t-sel mei de jokertekens:

=COUNTIF(A2:A10,"*"&D1&"*")

Sjoch foar mear ynformaasje: COUNTIF-formules mei in part oerienkomst.

Telle as sel befettet meardere substrings (AND logic)

Om sellen te tellen mei meardere betingsten, brûk de COUNTIFS-funksje. Excel COUNTIFS kin maksimaal 127 berik / kritearia-pearen behannelje, en allinich sellen dy't foldogge oan alle oantsjutte betingsten sille wêzeteld.

Om bygelyks út te finen hoefolle sellen yn kolom A "jurk" EN "blau" befetsje, brûk ien fan de folgjende formules:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Of

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Telle as sel nûmer befettet

De formule om sellen te tellen mei sifers is de ienfâldichste formule dy't jo kinne foarstelle:

Hâld asjebleaft yn gedachten dat de COUNT-funksje yn Excel sellen telt dy't elke numerike wearde befetsje, ynklusyf nûmers, datums en tiden, want yn termen fan Excel binne de lêste twa ek nûmers.

Yn ús gefal giet de formule as folget:

=COUNT(A2:A10)

Om sellen te tellen dy't NET sifers befetsje, brûk de SUMPRODUCT-funksje tegearre mei ISNUMBER en NOT:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Som as sel tekst befettet

As jo ​​sykje nei in Excel-formule om sellen te finen dy't spesifike tekst befetsje en de oerienkommende wearden yn sum in oare kolom, brûk de SUMIF-funksje.

Om bygelyks út te finen hoefolle jurken op foarried binne, brûk dizze formule:

=SUMIF(A2:A10,"*dress*",B2:B10)

Wêr A2:A10 binne de tekst wearden om te kontrolearjen en B2:B10 binne de nûmers om op te tellen.

Of set de substring fan belang yn in sel (E1), en ferwize dy sel yn jo formule, lykas werjûn yn 'e skermôfbylding hjirûnder:

Om mei meardere kritearia op te tellen , brûk de SUMIFS-funksje.

Om bygelyks út te finen hoefolle blauwe jurken beskikber binne, gean mei dizze formule:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Of brûk ditien:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Wêr't A2:A10 de sellen binne om te kontrolearjen en B2:B10 de sellen binne om op te tellen.

Utfiere ferskillende berekkeningen basearre op selwearde

Yn ús lêste tutorial hawwe wy trije ferskillende formules besprutsen om meardere betingsten te testen en ferskate wearden werom te jaan ôfhinklik fan de resultaten fan dy tests. En no, litte wy sjen hoe't jo ferskate berekkeningen kinne útfiere ôfhinklik fan de wearde yn in doelsel.

Stel dat jo ferkeapnûmers hawwe yn kolom B en wolle bonussen berekkenje op basis fan dy nûmers: as in ferkeap mear dan $300 is. , de bonus is 10%; foar ferkeap tusken $ 201 en $ 300 is de bonus 7%; foar ferkeap tusken $ 101 en $ 200 de bonus is 5%, en gjin bonus foar ûnder $ 100 ferkeap.

Om it dien te hawwen, fermannichfâldigje gewoan de ferkeap (B2) mei in oerienkommende persintaazje. Hoe witte jo mei hokker persintaazje jo fermannichfâldigje moatte? Troch ferskate betingsten te testen mei geneste IF's:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

Yn echte wurkblêden kin it handiger wêze om persintaazjes yn aparte sellen yn te fieren en dy sellen te ferwizen yn jo formule:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

It wichtichste ding is om de referinsjes fan 'e bonussellen te reparearjen mei it $ teken om te foarkommen dat se feroarje as jo de formule nei de kolom kopiearje.

Excel betingst opmaak as sel spesifike tekst befettet

As jo ​​ markearje sellen wolle mei bepaalde tekst, set dan in Excel betingsten opmaakregel op basearre op ien fan 'e folgjendeformules.

Hoofdlettergefoel:

Hoofdlettergefoel:

Om bygelyks SKU's te markearjen dy't de wurden "jurk" befetsje, meitsje in regel foar betingst opmaak mei de formule hjirûnder en tapasse dizze nei safolle sellen yn kolom A as jo nedich binne, begjinnend mei sel A2:

=SEARCH("dress", A2)>0

Excel betingsten opmaakformule: as sel tekst befettet (meardere betingsten)

Om sellen te markearjen dy't twa of mear teksttekens befetsje, nêst ferskate sykfunksjes binnen in EN-formule. Om bygelyks sellen "blauwe jurk" te markearjen, meitsje in regel basearre op dizze formule:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

Sjoch foar de detaillearre stappen Hoe kinne jo meitsje in regel foar betingst opmaak mei in formule.

As sel beskate tekst befettet, fuortsmite dan de hiele rige

Yn gefal jo rigen mei spesifike tekst wiskje wolle, brûk dan de funksje Sykje en ferfange fan Excel op dizze manier :

1. Selektearje alle sellen dy't jo kontrolearje wolle.
2. Druk op Ctrl + F om it dialoochfinster Sykje en ferfange te iepenjen.
3. In it fak Fyn wat , typ de tekst of it nûmer dat jo sykje, en klikje op de Alles fine
4. Klik op elk sykresultaat, en druk dan op Ctrl + A om alles te selektearjen.
5. Klik op de knop Slute om de Sykje en ferfange
6. Druk tagelyk op Ctrl en de minknop ( Ctrl - ), dat is de Excelfluchtoets foar wiskje.
7. Selektearje yn it dialoochfinster Wiskje Hele rige , en klikje op OK. Dien!

Yn it skermôfbylding hjirûnder wiskje wy rigen mei "jurk":

As sel befettet, selektearje of kopiearje folsleine rigen

Yn situaasjes as jo rigen wolle selektearje of kopiearje mei relevante gegevens, brûk dan it AutoFilter fan Excel om sokke rigen te filterjen. Druk dêrnei op Ctrl + A om de filtere gegevens te selektearjen, Ctrl+C om dizze te kopiearjen, en Ctrl+V om de gegevens op in oare lokaasje te plakjen.

Om sellen te filterjen mei twa of mear kritearia, brûk Avansearre filter om sokke sellen te finen, en kopiearje dan de folsleine rigen mei de resultaten of ekstrahearje allinich spesifike kolommen.

Dit is hoe't jo sellen manipulearje op basis fan har wearde yn Excel. Ik tankje jo foar it lêzen en hoopje jo nije wike op ús blog te sjen!

Oefenwurkboek

Excel As sel dan befettet - foarbylden (.xlsx-bestân)