Dina tutorial urang saméméhna, urang nempo Excel Lamun ngandung rumus nu balik sababaraha nilai ka kolom sejen lamun sél target ngandung hiji nilai dibikeun. Salian ti éta, naon deui anu anjeun tiasa laksanakeun upami sél ngandung téks atanapi nomer khusus? Rupa-rupa hal sapertos ngitung atanapi nyimpulkeun sél, nyorot, ngahapus atanapi nyalin sadayana baris, sareng seueur deui.

Excel 'Itung upami sél ngandung' conto rumus

Dina Microsoft Excel, aya dua fungsi pikeun ngitung sél dumasar kana nilaina, COUNTIF sareng COUNTIFS. Pungsi ieu nyertakeun paling, sanajan teu kabeh, skenario. Conto di handap bakal ngajarkeun anjeun kumaha milih Count anu pas upami sél ngandung rumus pikeun tugas khusus anjeun.

Itung upami sél ngandung téks naon waé

Dina kaayaan nalika anjeun badé ngitung sél anu ngandung téks naon waé. , pake karakter wildcard asterisk salaku kriteria dina rumus COUNTIF anjeun:

Atawa, paké fungsi SUMPRODUCT dina kombinasi jeung ISTEXT:

Dina rumus kadua, fungsi ISTEXT ngaevaluasi unggal sél dina rentang anu ditangtukeun sarta mulihkeun susunan nilai BENER (téks) jeung PALSU (sanés téks); operator unary ganda (--) maksa BENER jeung PALSU kana 1 jeung 0; jeung SUMPRODUCT nambahan jumlahna.

Saperti anu dipidangkeun dina screenshot di handap, duanana rumus ngahasilkeun hasil anu sarua:

=COUNTIF(A2:A10,"*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Anjeun oge bisa hayangtingali kumaha carana ngitung sél non-kosong dina Excel.

Itung lamun sél ngandung téks husus

Pikeun ngitung sél nu ngandung téks husus, make rumus COUNTIF basajan kawas ditémbongkeun di handap, dimana rentang nyaéta sél pikeun dipariksa sarta téks nyaéta string téks anu rék diteangan atawa rujukan ka sél nu ngandung string téks.

Contona, pikeun ngitung sél dina rentang A2:A10 anu ngandung kecap "pakéan", paké rumus ieu:

=COUNTIF(A2:A10, "dress")

Atawa anu dipidangkeun dina screenshot:

Anjeun tiasa mendakan deui conto rumus di dieu: Kumaha ngitung sél nganggo téks dina Excel: naon waé, khusus, sél disaring.

Itung lamun sél ngandung téks (cocok parsial)

Pikeun ngitung sél nu ngandung substring tangtu, paké pungsi COUNTIF jeung karakter wildcard asterisk (*).

Contona, pikeun ngitung sabaraha sél dina kolom A ngandung "baju" salaku bagian tina eusina, make rumus ieu:

=COUNTIF(A2:A10,"*dress*")

Atawa, ketik téks nu dipikahoyong dina sababaraha sél jeung concatenate tha sél t kalayan karakter wildcard:

=COUNTIF(A2:A10,"*"&D1&"*")

Pikeun inpo nu leuwih lengkep, mangga tingali: rumus COUNTIF kalawan parsial cocok.

Itung lamun sél ngandung sababaraha substrings (AND logika)

Pikeun ngitung sél anu gaduh sababaraha kaayaan, paké fungsi COUNTIFS. Excel COUNTIFS tiasa ngadamel dugi ka 127 pasangan rentang/kriteria, sareng ngan sél anu nyumponan sadaya kaayaan anu ditangtukeun bakaldiitung.

Misalna, pikeun manggihan sabaraha sél dina kolom A ngandung "baju" JEUNG "biru", make salah sahiji rumus ieu:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Atawa

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Itung lamun sél ngandung angka

Rumus pikeun ngitung sél jeung angka nyaéta rumus pangbasajanna anu bisa dibayangkeun:

Punten émut yén fungsi COUNT dina Excel ngitung sél anu ngandung nilai numerik naon waé kalebet angka, kaping sareng waktos, sabab tina segi Excel, dua anu terakhir ogé nomer.

Dina kasus urang, rumusna kieu:

=COUNT(A2:A10)

Pikeun ngitung sél nu TEU ngandung angka, paké pungsi SUMPRODUCT babarengan jeung ISNUMBER jeung NOT:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Jumlah lamun sél ngandung téks

Lamun anjeun néangan rumus Excel pikeun manggihan sél nu ngandung téks husus sarta jumlah nilai pakait dina kolom sejen, make fungsi SUMIF.

Contona, pikeun manggihan sabaraha dresses aya di stock, make rumus ieu:

=SUMIF(A2:A10,"*dress*",B2:B10)

Dimana A2:A10 mangrupakeun téks nilai nu kudu dipariksa jeung B2:B10 mangrupa angka nu dijumlahkeun.

Atawa, lebetkeun substring nu dipikaresep dina sababaraha sél (E1), jeung rujuk sél éta dina rumus anjeun, sakumaha ditémbongkeun dina screenshot di handap:

Pikeun jumlah kalawan sababaraha kritéria , paké pungsi SUMIFS.

Misalna, pikeun manggihan sabaraha pakéan biru nu sadia, buka nganggo rumus ieu:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Atawa nganggo ieuhiji:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Dimana A2:A10 mangrupa sél pikeun dipariksa sarta B2:B10 mangrupa sél pikeun jumlah.

Lakukeun itungan béda dumasar kana nilai sél

Dina tutorial panungtungan urang, urang ngabahas tilu rumus béda pikeun nguji sababaraha kaayaan sarta balik nilai béda gumantung kana hasil tés maranéhanana. Ayeuna, hayu urang tingali kumaha anjeun tiasa ngalakukeun itungan anu béda-béda gumantung kana nilai dina sél target.

Anggap anjeun gaduh nomer penjualan dina kolom B sareng hoyong ngitung bonus dumasar kana nomer éta: upami penjualan langkung ti $300 , bonus mangrupa 10%; pikeun jualan antara $ 201 jeung $ 300 bonus nu 7%; keur jualan antara $101 jeung $200 bonus nu 5%, tur euweuh bonus keur sahandapeun $100 jualan.

Pikeun geus rengse, ngan kalikeun jualan (B2) ku persentase pakait. Kumaha anjeun terang nu persentase kalikeun ku? Ku nguji kaayaan anu béda-béda sareng IFs nested:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

Dina lembar kerja kahirupan nyata, bisa jadi leuwih merenah pikeun ngasupkeun persentase dina sél misah tur nuduhkeun sél eta dina rumus anjeun:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Hal utama nyaéta ngalereskeun rujukan sél bonus ku tanda $ pikeun nyegah parobahanana nalika anjeun nyalin rumus ka handap kolom.

Format bersyarat Excel upami sél ngandung téks khusus

Upami anjeun hoyong nyorot sél kalayan téks anu tangtu, setel aturan pormat kondisional Excel dumasar kana salah sahiji ieu.rumus.

Huruf teu sensitip:

Hérélék-sénsitip:

Contona, pikeun nyorot SKU anu ngandung kecap "pakéan", jieun aturan pormat kondisional nganggo rumus di handap ieu sareng larapkeunana. ka saloba sél dina kolom A sakumaha anjeun peryogi dimimitian ku sél A2:

=SEARCH("dress", A2)>0

Rumus pormat kondisional Excel: lamun sél ngandung téks (sababaraha kaayaan)

Pikeun nyorot sél nu ngandung dua atawa leuwih string téks, sarang sababaraha pungsi Search dina rumus AND. Contona, pikeun nyorot sél "baju biru", jieun aturan dumasar kana rumus ieu:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

Pikeun léngkah-léngkah anu lengkep, mangga tingali Kumaha jieun aturan pormat kondisional nganggo rumus.

Lamun sél ngandung téks nu tangtu, hapus sakabéh baris

Lamun hayang mupus baris nu ngandung téks husus, paké fitur Panggihan tur Ganti Excel ku cara kieu :

1. Pilih sadaya sél nu rék dipariksa.
2. Pencét Ctrl + F pikeun muka kotak dialog Teangan jeung Ganti .
3. Dina kotak Panggihan naon , ketik téks atanapi nomer anu anjeun pilari, teras klik Teangan Sadayana
4. Klik kana hasil pamilarian, teras pencét Ctrl + A pikeun milih sadayana.
5. Klik tombol Tutup pikeun nutup Panggihan sareng Ganti
6. Pencét Ctrl sareng tombol minus dina waktos anu sami ( Ctrl -), nyaéta Excelpotong kompas pikeun Hapus.
7. Dina kotak dialog Hapus , pilih Sakabeh baris , teras klik OK. Réngsé!

Dina screenshot di handap, urang mupus baris anu ngandung "baju":

Mun sél ngandung, pilih atawa salin sakabéh baris

Dina kaayaan nalika anjeun hoyong milih atanapi nyalin baris sareng data anu relevan, paké AutoFilter Excel pikeun nyaring baris sapertos kitu. Sanggeus éta, pencét Ctrl + A pikeun milih data nu disaring, Ctrl+C pikeun nyalin, jeung Ctrl+V pikeun nempelkeun data ka lokasi nu séjén.

Pikeun nyaring sél nu mibanda dua atawa leuwih kriteria, paké Advanced Filter pikeun milarian sél sapertos kitu, teras salin sadayana baris kalayan hasil atanapi ékstrak ngan ukur kolom khusus.

Ieu kumaha anjeun ngamanipulasi sél dumasar kana nilaina dina Excel. Kuring hatur nuhun pikeun maca sareng ngarepkeun anjeun tiasa ningali dina blog urang minggu payun!

Buku kerja Praktek

Excel Upami Sél Ngandung Lajeng - conto (file .xlsx)