Oldingi qo'llanmamizda, agar maqsadli katak ma'lum qiymatga ega bo'lsa, boshqa ustunga qiymat qaytaradigan formulalarni o'z ichiga olgan Excel If dasturini ko'rib chiqdik. Bundan tashqari, agar hujayrada ma'lum bir matn yoki raqam bo'lsa, yana nima qilishingiz mumkin? Yacheykalarni sanash yoki jamlash, butun qatorlarni ajratib ko'rsatish, olib tashlash yoki nusxalash va boshqalar kabi turli xil narsalar.

Excel "Agar hujayra mavjud bo'lsa, hisoblash" formula misollari

In Microsoft Excelda hujayralarni qiymatlari asosida hisoblash uchun ikkita funktsiya mavjud: COUNTIF va COUNTIFS. Bu funksiyalar hammasi bo‘lmasa ham, ko‘pchilik stsenariylarni qamrab oladi. Quyidagi misollar, agar hujayrada sizning vazifangiz uchun formula bo'lsa, tegishli hisoblashni qanday tanlashni o'rgatadi.

Hujayrada matn bo'lsa, hisoblang

Har qanday matnni o'z ichiga olgan katakchalarni sanamoqchi bo'lgan holatlarda , COUNTIF formulangizdagi mezon sifatida yulduzcha joker belgidan foydalaning:

Yoki SUMPRODUCT funksiyasidan ISTEXT:

Ikkinchi formulada ISTEXT funksiyasi belgilangan diapazondagi har bir katakchani baholaydi va TRUE (matn) va FALSE (matn emas) qiymatlari massivini qaytaradi; qo'sh birlik operatori (--) TRUE va FALSE ni 1 va 0 ga majburlaydi; va SUMPRODUCT raqamlarni qo'shadi.

Quyidagi skrinshotda ko'rsatilganidek, ikkala formula ham bir xil natijani beradi:

=COUNTIF(A2:A10,"*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Siz ham xohlaysizExcelda bo'sh bo'lmagan kataklarni qanday hisoblashni ko'rib chiqing.

Yacheykada ma'lum matn bo'lsa, hisoblang

Muayyan matnni o'z ichiga olgan hujayralarni hisoblash uchun quyida ko'rsatilgandek oddiy COUNTIF formulasidan foydalaning, bu erda diapazon tekshiriladigan katakchalar va matn izlanadigan matn qatori yoki matn qatori joylashgan katakka havola.

Masalan, A2:A10 diapazonidagi "libos" so'zini o'z ichiga olgan kataklarni hisoblash uchun quyidagi formuladan foydalaning:

=COUNTIF(A2:A10, "dress")

Yoki skrinshotda ko'rsatilgan:

Ko'proq formulalar misollarini bu yerda topishingiz mumkin: Excelda matnli hujayralarni qanday hisoblash mumkin: har qanday, maxsus, filtrlangan hujayralar.

Yacheykada matn bo'lsa (qisman mos) hisoblang

Ma'lum bir pastki qatorni o'z ichiga olgan katakchalarni hisoblash uchun yulduzcha joker belgisi (*) bilan COUNTIF funksiyasidan foydalaning.

Masalan, hisoblash uchun A ustunidagi nechta katakda ularning mazmunida "kiyim" mavjud bo'lsa, quyidagi formuladan foydalaning:

=COUNTIF(A2:A10,"*dress*")

Yoki qaysidir katakka kerakli matnni kiriting va uni birlashtiring. joker belgilar bilan t katak:

=COUNTIF(A2:A10,"*"&D1&"*")

Qo'shimcha ma'lumot uchun qarang: Qisman mos keladigan COUNTIF formulalari.

Agar bo'lsa, hisoblang. yacheykada bir nechta pastki qatorlar mavjud (VA mantiq)

Bir nechta shartli hujayralarni sanash uchun COUNTIFS funksiyasidan foydalaning. Excel COUNTIFS 127 tagacha diapazon/kriteriya juftlarini ishlay oladi va faqat barcha belgilangan shartlarga javob beradigan hujayralar bo'ladi.hisoblangan.

Masalan, A ustunidagi nechta katakchada "ko'ylak" VA "ko'k" borligini bilish uchun quyidagi formulalardan birini ishlating:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Yoki

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Yacheykada raqam bo'lsa hisoblash

Raqamli katakchalarni hisoblash formulasi tasavvur qilish mumkin bo'lgan eng oddiy formuladir:

Iltimos, esda tutingki, Excel-dagi COUNT funksiyasi har qanday raqamli qiymatga ega bo'lgan katakchalarni, jumladan raqamlar, sana va vaqtlarni hisoblaydi, chunki Excelda oxirgi ikkitasi ham raqamlardir.

Bizning holatlarimizda formula quyidagicha bo'ladi:

=COUNT(A2:A10)

Raqamlarni o'z ichiga YO'Q katakchalarni hisoblash uchun ISNUMBER va YO'Q bilan birgalikda SUMPRODUCT funksiyasidan foydalaning:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Agar yacheyka matn bo'lsa yig'ing

Agar siz ma'lum matnni o'z ichiga olgan katakchalarni topish va tegishli qiymatlarni yig'ish uchun Excel formulasini izlayotgan bo'lsangiz boshqa ustunda SUMIF funksiyasidan foydalaning.

Masalan, qancha libos borligini bilish uchun quyidagi formuladan foydalaning:

=SUMIF(A2:A10,"*dress*",B2:B10)

Bu erda A2:A10 matn tekshirilishi kerak bo'lgan qiymatlar va B2:B10 yig'indisi uchun raqamlardir.

Yoki qiziq bo'lgan pastki qatorni qaysidir katakka (E1) qo'ying va quyidagi skrinshotda ko'rsatilganidek, formulangizdagi o'sha katakka havola qiling:

Koʻp mezonli yigʻindini uchun SUMIFS funksiyasidan foydalaning.

Masalan, qancha koʻk liboslar mavjudligini bilish uchun oʻting. ushbu formula bilan:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Yoki buni ishlatingbiri:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Bu erda A2:A10 - tekshiriladigan katakchalar va B2:B10 - yig'indisi.

Bajaring hujayra qiymatiga asoslangan turli hisoblar

Oxirgi darsimizda biz bir nechta shartlarni sinab ko'rish va ushbu testlar natijalariga qarab turli qiymatlarni qaytarish uchun uchta turli formulani muhokama qildik. Keling, maqsadli katakdagi qiymatga qarab turli xil hisob-kitoblarni qanday bajarishingiz mumkinligini ko'rib chiqaylik.

Aytaylik, siz B ustunida savdo raqamlaringiz bor va shu raqamlar asosida bonuslarni hisoblamoqchi bo'lsangiz: agar sotuv 300 dollardan ortiq bo'lsa. , bonus - 10%; 201 dan 300 dollargacha bo'lgan sotuvlar uchun bonus 7% ni tashkil qiladi; $101 dan 200$ gacha bo'lgan sotuvlar uchun bonus 5% ni tashkil qiladi va $100 dan kam bo'lgan sotuvlar uchun bonus yo'q.

Buni amalga oshirish uchun sotuvlarni (B2) mos keladigan foizga ko'paytirish kifoya. Qaysi foizga ko'paytirishni qanday bilasiz? Turli sharoitlarni oʻrnatilgan IF’lar bilan sinab koʻrish orqali:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

Haqiqiy hayotdagi ish varaqlarida foizlarni alohida katakchalarga kiritish va formulangizdagi ushbu kataklarga havola qilish qulayroq boʻlishi mumkin:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Asosiysi, formulani ustunga koʻchirganingizda ularning oʻzgarishiga yoʻl qoʻymaslik uchun bonus xujayralari havolalarini $ belgisi bilan tuzatishdir.

Yacheykada ma'lum bir matn bo'lsa, Excel shartli formatlash

Agar siz ma'lum bir matnli katakchalarni ta'kidlashni istasangiz, quyidagilardan biriga asoslanib Excel shartli formatlash qoidasini o'rnating.formulalar.

Harf-kichik harflar sezgir emas:

Harf-kichik harf sezgir:

Masalan, "libos" so'zlarini o'z ichiga olgan SKU'larni ajratib ko'rsatish uchun quyidagi formula bilan shartli formatlash qoidasini tuzing va uni qo'llang A ustunidagi qancha katakchaga A2 katakchasidan boshlash kerak bo'lsa:

=SEARCH("dress", A2)>0

Excel shartli formatlash formulasi: agar hujayra matn bo'lsa (bir nechta shartlar)

Ikki yoki undan ortiq matn qatorlarini o'z ichiga olgan katakchalarni ajratib ko'rsatish uchun bir nechta Qidiruv funksiyalarini AND formulasiga joylashtiring. Masalan, "ko'k libos" katakchalarini ajratib ko'rsatish uchun quyidagi formula asosida qoida yarating:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

Batafsil qadamlar uchun "Qanday qilish" bo'limiga qarang. formula bilan shartli formatlash qoidasini yarating.

Agar hujayrada ma'lum matn bo'lsa, butun qatorni olib tashlang

Agar siz ma'lum bir matnni o'z ichiga olgan qatorlarni o'chirmoqchi bo'lsangiz, Excelning "Topish va almashtirish" funksiyasidan shu tarzda foydalaning. :

1. Tekshirmoqchi boʻlgan barcha katakchalarni tanlang.
2. Topish va almashtirish muloqot oynasini ochish uchun Ctrl + F tugmalarini bosing.
3. Ichkarida Nimani toping oynasiga qidirayotgan matn yoki raqamni kiriting va Hammasini toping
4. Har qanday qidiruv natijasini bosing va keyin Ctrl + A tugmalarini bosing. hammasini tanlash uchun.
5. Topish va almashtirishni yopish uchun Yopish tugmasini bosing
6. Bir vaqtning o'zida Ctrl va minus tugmasini bosing ( Ctrl - ), ya'ni ExcelYo'q qilish uchun yorliq.
7. O'chirish muloqot oynasida Butun qator -ni tanlang va OK tugmasini bosing. Bajarildi!

Quyidagi skrinshotda biz "libos" ni o'z ichiga olgan qatorlarni o'chirib tashlaymiz:

Agar hujayrada bo'lsa, butun qatorlarni tanlang yoki nusxa oling

Tegishli maʼlumotlarga ega qatorlarni tanlash yoki nusxalash zarur boʻlgan holatlarda bunday qatorlarni filtrlash uchun Excelning Avtomatik filtridan foydalaning. Shundan so'ng, filtrlangan ma'lumotlarni tanlash uchun Ctrl + A, ularni nusxalash uchun Ctrl+C va ma'lumotlarni boshqa joyga joylashtirish uchun Ctrl+V tugmalarini bosing.

Ikki yoki undan ortiq mezonga ega hujayralarni filtrlash uchun Kengaytirilgan filtrdan foydalaning. bunday kataklarni toping va keyin natijalar bilan butun satrlardan nusxa oling yoki faqat ma'lum ustunlarni ajratib oling.

Mana shunday yacheykalarni Excelda ularning qiymatiga qarab boshqarasiz. O'qiganingiz uchun tashakkur va keyingi haftada blogimizda ko'rishga umid qilaman!

Mashq qilish kitobi

Excel Agar hujayra tarkibida bo'lsa - misollar (.xlsx fayli)