Meie eelmises õpetuses vaatlesime Exceli Kui sisaldab valemeid, mis tagastavad mingi väärtuse teise veergu, kui sihtruut sisaldab antud väärtust. Peale selle, mida saab veel teha, kui lahter sisaldab konkreetset teksti või arvu? Erinevaid asju, nagu lahtrite loendamine või summeerimine, esiletõstmine, tervete ridade eemaldamine või kopeerimine ja palju muud.

Exceli "Arvuta, kui lahter sisaldab" valemi näited

Microsoft Excelis on kaks funktsiooni lahtrite loendamiseks nende väärtuste põhjal, COUNTIF ja COUNTIFS. Need funktsioonid katavad enamiku, kuigi mitte kõik stsenaariumid. Allpool toodud näidetest saate teada, kuidas valida sobiva loendamisvalemi Count if cell contains teie konkreetse ülesande jaoks.

Loeb, kas lahter sisaldab teksti

Kui soovite loendada lahtreid, mis sisaldavad mis tahes teksti, kasutage oma COUNTIF-valemis kriteeriumina tärnimärki:

Või kasutage funktsiooni SUMPRODUCT koos funktsiooniga ISTEXT:

Teises valemis hindab funktsioon ISTEXT iga lahtrit määratud vahemikus ja tagastab TRUE (tekst) ja FALSE (mitte tekst) väärtuste massiivi; kahekordne unaarne operaator (--) muudab TRUE ja FALSE 1 ja 0 väärtusteks; ja SUMPRODUCT liidab arvud kokku.

Nagu on näidatud alloleval ekraanipildil, annavad mõlemad valemid sama tulemuse:

=COUNTIF(A2:A10, "*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Samuti võite vaadata, kuidas lugeda Excelis mitte-tühje lahtreid.

Loeb, kui lahter sisaldab konkreetset teksti

Konkreetset teksti sisaldavate lahtrite loendamiseks kasutage lihtsat COUNTIF valemit, nagu allpool näidatud, kus vahemik on rakud, mida kontrollida ja tekst on otsitav tekstistring või viide tekstistringi sisaldavale lahtrisse.

Näiteks selleks, et lugeda vahemikus A2:A10 olevaid lahtreid, mis sisaldavad sõna "kleit", kasutage seda valemit:

=COUNTIF(A2:A10, "kleit")

Või siis see, mis on näidatud ekraanipildil:

Rohkem näiteid valemite kohta leiate siit: Kuidas lugeda Exceli tekstiga lahtreid: mis tahes, konkreetseid, filtreeritud lahtreid.

Loeb, kui lahter sisaldab teksti (osaline kokkulangevus)

Teatud alamtähte sisaldavate lahtrite loendamiseks kasutage funktsiooni COUNTIF koos tärniga (*).

Näiteks, kui soovite lugeda, mitu lahtrit veerus A sisaldab "kleit" kui osa nende sisust, kasutage seda valemit:

=COUNTIF(A2:A10,"*dress*")

Või sisestage soovitud tekst mõnda lahtrisse ja ühendage see lahter metsikutega:

=COUNTIF(A2:A10,"*"&D1&"*")

Lisateavet leiate dokumendist: COUNTIFi valemid koos osalise vastavusega.

Loeb, kui lahter sisaldab mitu alajaotust (AND-loogika)

Mitme tingimusega lahtrite loendamiseks kasutage funktsiooni COUNTIFS. Excel COUNTIFS saab töödelda kuni 127 vahemiku/kriteeriumi paari ja loendisse lähevad ainult need lahtrid, mis vastavad kõigile määratud tingimustele.

Näiteks, kui soovite teada saada, mitu lahtrit veerus A sisaldab "kleit" JA "sinine", kasutage ühte järgmistest valemitest:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Või

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Loendatakse, kui lahter sisaldab numbrit

Valem numbritega lahtrite lugemiseks on kõige lihtsam valem, mida võiks ette kujutada:

Pidage meeles, et Exceli funktsioon COUNT loeb lahtreid, mis sisaldavad mis tahes numbrilist väärtust, sealhulgas numbreid, kuupäevi ja kellaaegu, sest Exceli mõistes on kaks viimast samuti numbrid.

Meie puhul on valem järgmine:

=COUNT(A2:A10)

Numbreid EI sisaldavate lahtrite loendamiseks kasutage funktsiooni SUMPRODUCT koos funktsioonidega ISNUMBER ja NOT:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Summa, kui lahter sisaldab teksti

Kui otsite Exceli valemit, et leida konkreetset teksti sisaldavaid lahtreid ja summeerida teises veerus olevad vastavad väärtused, kasutage funktsiooni SUMIF.

Näiteks selleks, et teada saada, kui palju kleite on laos, kasutage järgmist valemit:

=SUMIF(A2:A10,"*dress*",B2:B10)

Kus A2:A10 on kontrollitavad tekstiväärtused ja B2:B10 on summeeritavad numbrid.

Või pange huvipakkuv alajaotus mõnda lahtrisse (E1) ja viidake sellele lahtrisse oma valemis, nagu on näidatud alloleval ekraanipildil:

aadressile summa mitme kriteeriumiga , kasutage funktsiooni SUMIFS.

Näiteks, et teada saada, kui palju siniseid kleite on saadaval, kasuta järgmist valemit:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Või kasutage seda:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Kus A2:A10 on kontrollitavad lahtrid ja B2:B10 on lahtrid, mida tuleb summeerida.

Teha erinevaid arvutusi lahtri väärtuse alusel

Meie viimases õpetuses arutasime kolme erinevat valemit, et testida mitut tingimust ja tagastada erinevaid väärtusi sõltuvalt nende testide tulemustest. Ja nüüd vaatame, kuidas saate teha erinevaid arvutusi sõltuvalt sihtruutu väärtusest.

Oletame, et teil on müüginumbrid veerus B ja soovite arvutada boonuseid nende numbrite alusel: kui müük on üle 300 dollari, on boonus 10%; müügi puhul 201-300 dollarini on boonus 7%; müügi puhul 101-200 dollarini on boonus 5% ja alla 100 dollari suuruse müügi puhul ei ole boonust.

Selleks tuleb lihtsalt korrutada müük (B2) vastava protsendiga. Kuidas te teate, millise protsendiga korrutada? Erinevate tingimuste testimise teel, kasutades sisseehitatud IF-e:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

Reaalsetes töölehtedes võib olla mugavam sisestada protsendid eraldi lahtritesse ja viidata valemites nendele lahtritele:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Oluline on boonusrakkude viidete fikseerimine $-märgiga, et need ei muutuks, kui kopeerite valemi veeru alla.

Exceli tingimuslik vorming, kui lahter sisaldab konkreetset teksti

Kui soovite esile lahtritesse teatud teksti, seadistage Exceli tingimusliku vormindamise reegel, mis põhineb ühel järgmistest valemitest.

Suur- ja väiketähtedeta:

Suur- ja väiketähendusega:

Näiteks sõnu "kleit" sisaldavate SKUde esiletõstmiseks koostage tingimusliku vormingu reegel alljärgneva valemiga ja rakendage seda nii paljudele lahtritele veerus A kui vaja, alustades lahtrist A2:

=SEARCH("dress", A2)>0

Exceli tingimusliku vormingu valem: kui lahter sisaldab teksti (mitu tingimust)

Selleks, et tõsta esile lahtrid, mis sisaldavad kahte või enamat tekstijada, pesitsege mitu Search-funktsiooni AND-vormeli sisse. Näiteks, et tõsta esile lahtrid "sinine kleit", looge selle valemi põhjal reegel:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

Üksikasjalikud sammud leiate jaotisest Kuidas luua tingimusliku vormingu reeglit valemiga.

Kui lahter sisaldab teatud teksti, eemalda kogu rida

Kui soovite kustutada konkreetset teksti sisaldavaid ridu, kasutage sel viisil Exceli funktsiooni Find and Replace:

1. Valige kõik lahtrid, mida soovite kontrollida.
2. Vajutage Ctrl + F, et avada Leia ja asenda dialoogiaknas.
3. In the Leia, mida kasti, sisestage otsitav tekst või number ja klõpsake nuppu Leia kõik
4. Klõpsake ükskõik millisel otsingutulemusel ja vajutage Ctrl + A, et valida kõik.
5. Klõpsake nuppu Sulge nuppu, et sulgeda Leia ja asenda
6. Vajutage samaaegselt Ctrl ja miinusnuppu ( Ctrl - ), mis on Exceli otsetee Delete.
7. In the Kustuta dialoogiaknas valige Kogu rida ja klõpsake OK. Valmis!

Allpool oleval ekraanipildil kustutame ridu, mis sisaldavad "kleit":

Kui lahter sisaldab, valige või kopeerige terveid ridu

Olukordades, kus soovite asjakohaseid andmeid sisaldavaid ridu valida või kopeerida, kasutage selliste ridade filtreerimiseks Exceli automaatset filtrit. Pärast seda vajutage Ctrl + A, et filtreeritud andmed valida, Ctrl + C, et neid kopeerida, ja Ctrl + V, et kleepida andmed teise kohta.

Kahe või enama kriteeriumiga lahtrite filtreerimiseks kasutage selliste lahtrite leidmiseks täiustatud filtrit ja kopeerige seejärel kogu rida koos tulemustega või võtke välja ainult teatud veerud.

Nii saab Excelis lahtritega manipuleerida nende väärtuse alusel. Tänan teid lugemise eest ja loodan, et näeme teid järgmisel nädalal meie blogis!

Praktiline töövihik

Excel If Cell Contains Then - näited (.xlsx fail)