در آموزش قبلی، ما به Excel If نگاه می‌کردیم که حاوی فرمول‌هایی است که اگر سلول هدف حاوی مقدار مشخصی باشد مقداری به ستون دیگری برمی‌گرداند. جدا از آن، اگر سلولی حاوی متن یا عدد خاصی باشد، چه کارهای دیگری می توانید انجام دهید؟ موارد مختلفی مانند شمارش یا جمع سلول‌ها، برجسته کردن، حذف یا کپی کردن کل ردیف‌ها و موارد دیگر.

Excel "Count if cell حاوی" مثال‌های فرمول

در مایکروسافت اکسل، دو تابع برای شمارش سلول ها بر اساس مقادیر آنها وجود دارد، COUNTIF و COUNTIFS. این توابع اکثر سناریوها، البته نه همه، را پوشش می دهند. مثال‌های زیر به شما آموزش می‌دهند که اگر سلول حاوی فرمول برای کار خاص شما باشد، چگونه تعداد مناسبی را انتخاب کنید.

اگر سلول حاوی هر متنی باشد شمارش کنید

در شرایطی که می‌خواهید سلول‌های حاوی هر متنی را بشمارید. در فرمول COUNTIF خود از کاراکتر علامت ستاره به عنوان معیار استفاده کنید:

یا، از تابع SUMPRODUCT در ترکیب با ISTEXT استفاده کنید:

در فرمول دوم، تابع ISTEXT هر سلول را در محدوده مشخص شده ارزیابی می کند و آرایه ای از مقادیر TRUE (متن) و FALSE (نه متن) را برمی گرداند. عملگر دوگانه یکنواختی (--) TRUE و FALSE را به 1 و 0 تبدیل می کند. و SUMPRODUCT اعداد را جمع می کند.

همانطور که در تصویر زیر نشان داده شده است، هر دو فرمول نتیجه یکسانی دارند:

=COUNTIF(A2:A10,"*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

شما هم ممکن است بخواهیدبه نحوه شمارش سلول های غیر خالی در اکسل نگاه کنید.

شمارش اگر سلول حاوی متن خاصی است

برای شمارش سلول هایی که حاوی متن خاصی هستند، از فرمول COUNTIF ساده مانند شکل زیر استفاده کنید، جایی که range سلول هایی است که باید بررسی شوند و text رشته متنی برای جستجو یا مرجعی به سلول حاوی رشته متن است.

به عنوان مثال، برای شمارش سلول‌هایی در محدوده A2:A10 که حاوی کلمه "dress" هستند، از این فرمول استفاده کنید:

=COUNTIF(A2:A10, "dress")

یا نمونه ای که در تصویر نشان داده شده است:

شما می توانید نمونه فرمول های بیشتری را در اینجا بیابید: نحوه شمارش سلول ها با متن در اکسل: هر سلول خاص و فیلتر شده.

اگر سلول حاوی متن باشد (تطابق جزئی) شمارش کنید

برای شمارش سلول هایی که دارای یک رشته فرعی خاص هستند، از تابع COUNTIF با کاراکتر علامت ستاره (*) استفاده کنید.

به عنوان مثال، برای شمارش چند سلول در ستون A حاوی "dress" به عنوان بخشی از محتوای آنها است، از این فرمول استفاده کنید:

=COUNTIF(A2:A10,"*dress*")

یا، متن مورد نظر را در برخی از سلول ها تایپ کنید و آن را به هم متصل کنید. سلول t با نویسه‌های عام:

=COUNTIF(A2:A10,"*"&D1&"*")

برای اطلاعات بیشتر، لطفاً به: فرمول‌های COUNTIF با تطابق جزئی مراجعه کنید.

اگر شمارش کنید سلول حاوی چندین زیر رشته (AND منطق) است

برای شمارش سلول های دارای شرایط متعدد، از تابع COUNTIFS استفاده کنید. Excel COUNTIFS می تواند تا 127 جفت محدوده/معیار را مدیریت کند و تنها سلول هایی که همه شرایط مشخص شده را برآورده می کنند، خواهند بود.شمارش شد.

به عنوان مثال، برای اینکه بفهمید چند سلول در ستون A حاوی "dress" و "آبی" است، از یکی از فرمول های زیر استفاده کنید:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

یا

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

اگر سلول حاوی عدد باشد، شمارش کنید

فرمول شمارش سلول ها با اعداد ساده ترین فرمولی است که می توان تصور کرد:

لطفاً به خاطر داشته باشید که تابع COUNT در اکسل سلول های حاوی هر مقدار عددی از جمله اعداد، تاریخ و زمان را می شمارد، زیرا از نظر اکسل دو مورد آخر نیز اعداد هستند.

در مورد ما، فرمول به شرح زیر است:

=COUNT(A2:A10)

برای شمارش سلول هایی که اعداد ندارند، از تابع SUMPRODUCT همراه با ISNUMBER و NOT استفاده کنید:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

مجموع اگر سلول حاوی متن باشد

اگر به دنبال یک فرمول اکسل برای یافتن سلول های حاوی متن خاص و مجموع مقادیر مربوطه در ستون دیگری، از تابع SUMIF استفاده کنید.

به عنوان مثال، برای اینکه بدانید چند لباس موجود است، از این فرمول استفاده کنید:

=SUMIF(A2:A10,"*dress*",B2:B10)

که در آن A2:A10 هستند متن مقادیری که باید بررسی شوند و B2:B10 اعدادی هستند که باید جمع شوند.

یا، رشته فرعی مورد نظر را در یک سلول (E1) قرار دهید و به آن سلول در فرمول خود ارجاع دهید، همانطور که در تصویر زیر نشان داده شده است:

برای جمع کردن با چند معیار ، از تابع SUMIFS استفاده کنید.

به عنوان مثال، برای اطلاع از تعداد لباس های آبی موجود، بروید با این فرمول:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

یا از این استفاده کنیدone:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

جایی که A2:A10 سلول‌هایی هستند که باید بررسی شوند و B2:B10 سلول‌هایی هستند که باید جمع شوند.

اجرا محاسبات مختلف بر اساس مقدار سلول

در آخرین آموزش خود، سه فرمول مختلف را برای آزمایش شرایط متعدد و برگرداندن مقادیر مختلف بسته به نتایج آن تست ها مورد بحث قرار دادیم. و اکنون، بیایید ببینیم که چگونه می‌توانید محاسبات مختلف را بسته به مقدار در یک سلول هدف انجام دهید.

فرض کنید اعداد فروش در ستون B دارید و می‌خواهید پاداش‌ها را بر اساس آن اعداد محاسبه کنید: اگر فروش بیش از 300 دلار باشد. ، پاداش 10٪ است. برای فروش بین 201 تا 300 دلار، پاداش 7 درصد است. برای فروش بین 101 تا 200 دلار، پاداش 5 درصد است و برای فروش کمتر از 100 دلار جایزه وجود ندارد.

برای انجام آن، به سادگی فروش (B2) را در درصد مربوطه ضرب کنید. چگونه می دانید در کدام درصد ضرب کنید؟ با آزمایش شرایط مختلف با IF های تو در تو:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

در کاربرگ های واقعی، ممکن است وارد کردن درصدها در سلول های جداگانه و ارجاع آن سلول ها در فرمول راحت تر باشد:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

نکته کلیدی این است که ارجاعات سلول های پاداش را با علامت $ ثابت کنید تا از تغییر آنها در هنگام کپی کردن فرمول در پایین ستون جلوگیری کنید.

اگر سلول حاوی متن خاصی است قالب بندی مشروط اکسل

اگر می خواهید سلول ها را با متن خاصی برجسته کنید، یک قانون قالب بندی شرطی اکسل را بر اساس یکی از موارد زیر تنظیم کنید.فرمول‌ها.

حساس به حروف کوچک و بزرگ:

حساس به حروف کوچک و بزرگ:

به عنوان مثال، برای برجسته کردن SKUهایی که حاوی کلمات "dress" هستند، یک قانون قالب بندی شرطی با فرمول زیر ایجاد کنید و آن را اعمال کنید. به تعداد سلول های ستون A که نیاز دارید که با سلول A2 شروع می شود:

=SEARCH("dress", A2)>0

فرمول قالب بندی شرطی اکسل: اگر سلول حاوی متن باشد (شرایط چندگانه)

برای برجسته کردن سلول هایی که حاوی دو یا چند رشته متن هستند، چندین تابع جستجو را در یک فرمول AND قرار دهید. به عنوان مثال، برای برجسته کردن سلول های "لباس آبی"، یک قانون بر اساس این فرمول ایجاد کنید:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

برای جزئیات مراحل، لطفاً به نحوه انجام یک قانون قالب بندی شرطی با یک فرمول ایجاد کنید.

اگر سلول حاوی متن خاصی است، کل ردیف را حذف کنید

در صورتی که می خواهید ردیف های حاوی متن خاصی را حذف کنید، از ویژگی Find and Replace اکسل به این روش استفاده کنید. :

1. همه سلول هایی را که می خواهید بررسی کنید انتخاب کنید.
2. Ctrl + F را فشار دهید تا کادر گفتگوی Find and Replace باز شود.
3. در کادر چیست را پیدا کنید ، متن یا عدد مورد نظر خود را تایپ کنید و بر روی Find All
4. کلیک کنید بر روی هر نتیجه جستجو کلیک کنید و سپس Ctrl + A را فشار دهید. برای انتخاب همه.
5. دکمه بستن را برای بستن یافتن و جایگزینی
6. کلید Ctrl و دکمه منهای را همزمان فشار دهید ( Ctrl - ) که اکسل استمیانبر برای Delete.
7. در کادر محاوره ای Delete ، Entire row را انتخاب کرده و روی OK کلیک کنید. تمام شد!

در تصویر زیر، ما ردیف‌های حاوی "dress" را حذف می‌کنیم:

اگر سلول حاوی کل ردیف‌ها است، کل ردیف‌ها را انتخاب یا کپی کنید

در شرایطی که می‌خواهید ردیف‌هایی را با داده‌های مرتبط انتخاب یا کپی کنید، از فیلتر خودکار اکسل برای فیلتر کردن چنین ردیف‌هایی استفاده کنید. پس از آن، Ctrl + A را برای انتخاب داده های فیلتر شده، Ctrl+C برای کپی کردن و Ctrl+V برای چسباندن داده ها در مکان دیگری فشار دهید.

برای فیلتر کردن سلول های دارای دو یا چند معیار، از فیلتر پیشرفته استفاده کنید. برای یافتن چنین سلول‌هایی، و سپس کل ردیف‌ها را با نتایج کپی کنید یا فقط ستون‌های خاصی را استخراج کنید.

به این ترتیب سلول‌ها را بر اساس مقدار آنها در اکسل دستکاری می‌کنید. از شما سپاسگزارم که خواندید و امیدوارم هفته آینده شما را در وبلاگ خود ببینم!

کتاب کار تمرینی

Excel If Cell Contains then - مثالها (فایل xlsx.)