आमच्या मागील ट्युटोरियलमध्ये, आम्ही Excel If मध्ये सूत्रे पाहत होतो जे लक्ष्य सेलमध्ये दिलेले मूल्य असल्यास दुसर्‍या कॉलममध्ये काही मूल्य परत करतात. त्याशिवाय, सेलमध्ये विशिष्ट मजकूर किंवा संख्या असल्यास तुम्ही आणखी काय करू शकता? सेल मोजणे किंवा बेरीज करणे, संपूर्ण पंक्ती हायलाइट करणे, काढणे किंवा कॉपी करणे आणि बरेच काही.

एक्सेल 'सेलमध्ये असल्यास मोजा' सूत्र उदाहरणे

मध्ये मायक्रोसॉफ्ट एक्सेल, सेल त्यांच्या मूल्यांवर आधारित मोजण्यासाठी दोन कार्ये आहेत, COUNTIF आणि COUNTIFS. या फंक्शन्समध्ये सर्वच परिस्थिती नसल्या तरी बर्‍याच गोष्टींचा समावेश होतो. सेलमध्ये तुमच्या विशिष्ट कार्यासाठी सूत्र असल्यास योग्य गणना कशी निवडावी हे खाली दिलेली उदाहरणे तुम्हाला शिकवतील.

सेलमध्ये कोणताही मजकूर असल्यास मोजा

तुम्हाला कोणताही मजकूर असलेल्या सेलची गणना करायची असेल अशा परिस्थितीत , तुमच्या COUNTIF सूत्रातील निकष म्हणून तारांकित वाइल्डकार्ड वर्ण वापरा:

किंवा, ISTEXT:

दुसऱ्या सूत्रात, ISTEXT फंक्शन निर्दिष्ट श्रेणीतील प्रत्येक सेलचे मूल्यमापन करते आणि TRUE (टेक्स्ट) आणि FALSE (टेक्स्ट नाही) व्हॅल्यूजची अॅरे देते; दुहेरी युनरी ऑपरेटर (--) TRUE आणि FALSE ला 1 आणि 0 मध्ये जबरदस्ती करते; आणि SUMPRODUCT संख्या जोडते.

खालील स्क्रीनशॉटमध्ये दाखवल्याप्रमाणे, दोन्ही सूत्रे समान परिणाम देतात:

=COUNTIF(A2:A10,"*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

तुम्ही देखील करू शकताएक्सेलमध्ये रिक्त नसलेल्या सेलची गणना कशी करायची ते पहा.

सेलमध्ये विशिष्ट मजकूर असल्यास मोजा

विशिष्ट मजकूर असलेल्या सेलची गणना करण्यासाठी, खाली दर्शविल्याप्रमाणे एक साधा COUNTIF सूत्र वापरा, जेथे श्रेणी तपासण्यासाठी सेल आहे आणि मजकूर शोधण्यासाठी मजकूर स्ट्रिंग आहे किंवा मजकूर स्ट्रिंग असलेल्या सेलचा संदर्भ आहे.

उदाहरणार्थ, "ड्रेस" शब्द असलेल्या A2:A10 श्रेणीतील सेल मोजण्यासाठी, हे सूत्र वापरा:

=COUNTIF(A2:A10, "dress")

किंवा स्क्रीनशॉटमध्ये दर्शविलेले एक:

तुम्ही येथे अधिक सूत्र उदाहरणे शोधू शकता: Excel मध्ये मजकूर असलेल्या सेलची गणना कशी करायची: कोणतेही, विशिष्ट, फिल्टर केलेले सेल.

सेलमध्ये मजकूर असल्यास मोजा (आंशिक जुळणी)

विशिष्ट सबस्ट्रिंग असलेल्या सेलची गणना करण्यासाठी, तारांकित वाइल्डकार्ड वर्ण (*) सह COUNTIF फंक्शन वापरा.

उदाहरणार्थ, मोजण्यासाठी स्तंभ A मधील किती सेलमध्ये त्यांच्या सामग्रीचा एक भाग म्हणून "ड्रेस" आहे, हे सूत्र वापरा:

=COUNTIF(A2:A10,"*dress*")

किंवा, काही सेलमध्ये इच्छित मजकूर टाइप करा आणि एकत्र करा. वाइल्डकार्ड वर्णांसह t सेल:

=COUNTIF(A2:A10,"*"&D1&"*")

अधिक माहितीसाठी, कृपया पहा: आंशिक जुळणीसह COUNTIF सूत्रे.

तर मोजा सेलमध्ये एकाधिक सबस्ट्रिंग्स आहेत (आणि तर्कशास्त्र)

एकाधिक अटींसह सेल मोजण्यासाठी, COUNTIFS फंक्शन वापरा. Excel COUNTIFS 127 श्रेणी/निकष जोड्या हाताळू शकते आणि केवळ सर्व निर्दिष्ट अटी पूर्ण करणारे सेल असतीलमोजले.

उदाहरणार्थ, स्तंभ A मध्ये "ड्रेस" आणि "निळा" किती सेल आहेत हे शोधण्यासाठी, खालीलपैकी एक सूत्र वापरा:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

किंवा

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

सेलमध्ये संख्या असल्यास मोजा

संख्या असलेल्या सेल मोजण्याचे सूत्र हे सर्वात सोपे सूत्र आहे ज्याची कल्पना करता येते:

कृपया लक्षात ठेवा की Excel मधील COUNT फंक्शन संख्या, तारखा आणि वेळा यासह कोणतेही संख्यात्मक मूल्य असलेल्या सेलची गणना करते, कारण Excel च्या दृष्टीने शेवटचे दोन देखील संख्या आहेत.

आमच्या बाबतीत, सूत्र खालीलप्रमाणे आहे:

=COUNT(A2:A10)

संख्या नसलेल्या सेलची गणना करण्यासाठी, SUMPRODUCT फंक्शन ISNUMBER आणि NOT सह वापरा:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

सेलमध्ये मजकूर असल्यास बेरीज

तुम्ही विशिष्ट मजकूर असलेले सेल शोधण्यासाठी आणि संबंधित मूल्यांची बेरीज करण्यासाठी एक्सेल सूत्र शोधत असाल तर दुसरा स्तंभ, SUMIF फंक्शन वापरा.

उदाहरणार्थ, स्टॉकमध्ये किती कपडे आहेत हे शोधण्यासाठी, हे सूत्र वापरा:

=SUMIF(A2:A10,"*dress*",B2:B10)

A2:A10 कुठे आहेत मजकूर तपासण्यासाठी मूल्ये आणि B2:B10 ही बेरीज करण्यासाठी संख्या आहेत.

किंवा, काही सेल (E1) मध्ये स्वारस्य असलेले सबस्ट्रिंग ठेवा आणि खालील स्क्रीनशॉटमध्ये दर्शविल्याप्रमाणे, तुमच्या सूत्रामध्ये त्या सेलचा संदर्भ द्या:<1

एकाधिक निकषांची बेरीज करण्यासाठी , SUMIFS फंक्शन वापरा.

उदाहरणार्थ, किती निळे कपडे उपलब्ध आहेत हे शोधण्यासाठी, जा या सूत्रासह:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

किंवा हे वापराएक:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

जेथे A2:A10 हे तपासायचे सेल आहेत आणि B2:B10 हे सेल बेरीज आहेत.

परफॉर्म करा सेल व्हॅल्यूवर आधारित भिन्न गणना

आमच्या शेवटच्या ट्युटोरियलमध्ये, आम्ही अनेक परिस्थिती तपासण्यासाठी आणि त्या चाचण्यांच्या परिणामांवर अवलंबून भिन्न मूल्ये परत करण्यासाठी तीन भिन्न सूत्रांवर चर्चा केली. आणि आता, लक्ष्य सेलमधील मूल्यानुसार तुम्ही वेगवेगळी गणना कशी करू शकता ते पाहू.

समजा तुमच्याकडे कॉलम B मध्ये विक्री क्रमांक आहेत आणि तुम्हाला त्या संख्यांच्या आधारे बोनसची गणना करायची आहे: जर विक्री $300 पेक्षा जास्त असेल , बोनस 10% आहे; $201 आणि $300 मधील विक्रीसाठी बोनस 7% आहे; $101 आणि $200 मधील विक्रीसाठी बोनस 5% आहे आणि $100 पेक्षा कमी विक्रीसाठी बोनस नाही.

ते पूर्ण करण्यासाठी, फक्त विक्री (B2) संबंधित टक्केवारीने गुणाकार करा. कोणत्या टक्केवारीने गुणाकार करावा हे कसे कळेल? नेस्टेड IFs सह भिन्न परिस्थितींचे परीक्षण करून:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

वास्तविक जीवनातील वर्कशीटमध्ये, वेगळ्या सेलमध्ये टक्केवारी इनपुट करणे आणि त्या सेलचा तुमच्या सूत्रामध्ये संदर्भ देणे अधिक सोयीचे असू शकते:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

तुम्ही कॉलमच्या खाली फॉर्म्युला कॉपी करता तेव्हा ते बदलण्यापासून रोखण्यासाठी $ चिन्हासह बोनस सेलचे संदर्भ निश्चित करणे ही मुख्य गोष्ट आहे.

सेलमध्ये विशिष्ट मजकूर असल्यास एक्सेल कंडिशनल फॉरमॅटिंग

तुम्हाला विशिष्ट मजकूरासह सेल हायलाइट करायचे असल्यास, खालीलपैकी एकावर आधारित एक्सेल कंडिशनल फॉरमॅटिंग नियम सेट करासूत्र.

केस-संवेदनशील:

केस-संवेदनशील:

उदाहरणार्थ, "ड्रेस" शब्द असलेले SKU हायलाइट करण्यासाठी, खालील सूत्रासह सशर्त स्वरूपन नियम बनवा आणि तो लागू करा तुम्हाला सेल A2 पासून सुरुवात करणे आवश्यक आहे तितक्या सेलमध्ये A2:

=SEARCH("dress", A2)>0

Excel कंडिशनल फॉरमॅटिंग फॉर्म्युला: सेलमध्ये मजकूर असल्यास (एकाधिक अटी)

दोन किंवा अधिक मजकूर स्ट्रिंग असलेल्या सेल हायलाइट करण्यासाठी, AND सूत्रामध्ये अनेक शोध कार्ये नेस्ट करा. उदाहरणार्थ, "ब्लू ड्रेस" सेल हायलाइट करण्यासाठी, या सूत्रावर आधारित नियम तयार करा:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

तपशीलवार पायऱ्यांसाठी, कृपया कसे करायचे ते पहा सूत्रासह सशर्त स्वरूपन नियम तयार करा.

सेलमध्ये ठराविक मजकूर असल्यास, संपूर्ण पंक्ती काढून टाका

तुम्हाला विशिष्ट मजकूर असलेल्या पंक्ती हटवायच्या असल्यास, अशा प्रकारे एक्सेलचे शोधा आणि बदला वैशिष्ट्य वापरा :

1. तुम्हाला तपासायचे असलेले सर्व सेल निवडा.
2. शोधा आणि बदला डायलॉग बॉक्स उघडण्यासाठी Ctrl + F दाबा.
3. मध्ये काय शोधा बॉक्स, तुम्ही शोधत असलेला मजकूर किंवा नंबर टाइप करा आणि सर्व शोधा
4. कोणत्याही शोध परिणामावर क्लिक करा आणि नंतर Ctrl + A दाबा. सर्व निवडण्यासाठी.
5. बंद करण्यासाठी बंद करा बटणावर क्लिक करा शोधा आणि बदला
6. Ctrl आणि वजा बटण एकाच वेळी दाबा ( Ctrl - ), जे एक्सेल आहेहटवण्यासाठी शॉर्टकट.
7. हटवा डायलॉग बॉक्समध्ये, संपूर्ण पंक्ती निवडा आणि ओके क्लिक करा. पूर्ण झाले!

खालील स्क्रीनशॉटमध्ये, आम्ही "ड्रेस" असलेल्या पंक्ती हटवत आहोत:

सेलमध्ये असल्यास, संपूर्ण पंक्ती निवडा किंवा कॉपी करा

तुम्हाला संबंधित डेटासह पंक्ती निवडायची किंवा कॉपी करायची असल्यास अशा पंक्ती फिल्टर करण्यासाठी एक्सेलचे ऑटोफिल्टर वापरा. त्यानंतर, फिल्टर केलेला डेटा निवडण्यासाठी Ctrl + A दाबा, कॉपी करण्यासाठी Ctrl+C आणि डेटा दुसर्‍या ठिकाणी पेस्ट करण्यासाठी Ctrl+V दाबा.

दोन किंवा अधिक निकषांसह सेल फिल्टर करण्यासाठी, प्रगत फिल्टर वापरा. अशा सेल शोधण्यासाठी, आणि नंतर परिणामांसह संपूर्ण पंक्ती कॉपी करा किंवा फक्त विशिष्ट स्तंभ काढा.

तुम्ही एक्सेलमधील त्यांच्या मूल्याच्या आधारावर अशा प्रकारे हाताळू शकता. वाचल्याबद्दल मी तुमचा आभारी आहे आणि पुढील आठवड्यात तुम्हाला आमच्या ब्लॉगवर भेटण्याची आशा आहे!

सराव वर्कबुक

एक्सेल जर सेलमध्ये असेल तर - उदाहरणे (.xlsx फाइल)