U našem prethodnom vodiču, gledali smo kako Excel If sadrži formule koje vraćaju neku vrijednost u drugu kolonu ako ciljna ćelija sadrži datu vrijednost. Osim toga, šta još možete učiniti ako ćelija sadrži određeni tekst ili broj? Razne stvari kao što su brojanje ili zbrajanje ćelija, isticanje, uklanjanje ili kopiranje cijelih redova i još mnogo toga.

Primjeri formule 'Broj ako ćelija sadrži' Excel

U Microsoft Excel, postoje dvije funkcije za brojanje ćelija na osnovu njihovih vrijednosti, COUNTIF i COUNTIFS. Ove funkcije pokrivaju većinu, iako ne sve, scenarije. Primjeri u nastavku će vas naučiti kako odabrati odgovarajući broj ako ćelija sadrži formulu za vaš određeni zadatak.

Broj ako ćelija sadrži bilo koji tekst

U situacijama kada želite prebrojati ćelije koje sadrže bilo koji tekst , koristite zamjenski znak zvjezdice kao kriterij u vašoj formuli COUNTIF:

Ili koristite funkciju SUMPRODUCT u kombinaciji sa ISTEXT:

U drugoj formuli, funkcija ISTEXT procjenjuje svaku ćeliju u navedenom rasponu i vraća niz vrijednosti TRUE (tekst) i FALSE (ne tekst); dvostruki unarni operator (--) navodi TRUE i FALSE u 1 i 0; a SUMPRODUCT zbraja brojeve.

Kao što je prikazano na slici ispod, obje formule daju isti rezultat:

=COUNTIF(A2:A10,"*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Možda i vi želitepogledajte kako prebrojati neprazne ćelije u Excelu.

Broj ako ćelija sadrži određeni tekst

Da biste prebrojali ćelije koje sadrže određeni tekst, koristite jednostavnu formulu COUNTIF kao što je prikazano ispod, gdje je raspon su ćelije koje treba provjeriti, a tekst je tekstualni niz za pretraživanje ili referenca na ćeliju koja sadrži tekstualni niz.

Na primjer, da prebrojite ćelije u rasponu A2:A10 koje sadrže riječ "dress", koristite ovu formulu:

=COUNTIF(A2:A10, "dress")

Ili onaj prikazan na snimku ekrana:

Ovdje možete pronaći više primjera formula: Kako prebrojati ćelije s tekstom u Excelu: bilo koje, specifične, filtrirane ćelije.

Broj ako ćelija sadrži tekst (djelimično podudaranje)

Da prebrojite ćelije koje sadrže određeni podniz, koristite funkciju COUNTIF sa zamjenskim znakom zvjezdice (*).

Na primjer, za brojanje koliko ćelija u koloni A sadrži "dress" kao dio svog sadržaja, koristite ovu formulu:

=COUNTIF(A2:A10,"*dress*")

Ili upišite željeni tekst u neku ćeliju i spojite ga t ćelija sa zamjenskim znakovima:

=COUNTIF(A2:A10,"*"&D1&"*")

Za više informacija pogledajte: COUNTIF formule s djelomičnim podudaranjem.

Broj ako ćelija sadrži više podnizova (I logika)

Za brojanje ćelija s više uvjeta, koristite funkciju COUNTIFS. Excel COUNTIFS može obraditi do 127 parova raspona/kriterijuma, a samo ćelije koje ispunjavaju sve navedene uslove bit ćeprebrojano.

Na primjer, da saznate koliko ćelija u koloni A sadrži "haljinu" I "plavu", koristite jednu od sljedećih formula:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Ili

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Broj ako ćelija sadrži broj

Formula za brojanje ćelija s brojevima je najjednostavnija formula koju možete zamisliti:

Imajte na umu da funkcija COUNT u Excelu broji ćelije koje sadrže bilo koju numeričku vrijednost uključujući brojeve, datume i vremena, jer u smislu Excela, posljednje dvije su također brojevi.

U našem slučaju, formula glasi kako slijedi:

=COUNT(A2:A10)

Da prebrojite ćelije koje NE sadrže brojeve, koristite funkciju SUMPRODUCT zajedno sa ISBROJ i NE:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Zbroj ako ćelija sadrži tekst

Ako tražite Excel formulu da pronađete ćelije koje sadrže određeni tekst i zbrojite odgovarajuće vrijednosti u drugu kolonu, koristite funkciju SUMIF.

Na primjer, da saznate koliko je haljina na zalihama, koristite ovu formulu:

=SUMIF(A2:A10,"*dress*",B2:B10)

Gdje su A2:A10 tekst vrijednosti koje treba provjeriti i B2:B10 su brojevi za sumiranje.

Ili stavite podniz od interesa u neku ćeliju (E1) i referencirajte tu ćeliju u vašoj formuli, kao što je prikazano na snimku ekrana ispod:

Da zbrojite s više kriterija , koristite funkciju SUMIFS.

Na primjer, da saznate koliko je plavih haljina dostupno, idite sa ovom formulom:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Ili koristite ovojedan:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Gdje su A2:A10 ćelije koje treba provjeriti, a B2:B10 ćelije koje se zbrajaju.

Izvrši različiti proračuni zasnovani na vrijednosti ćelije

U našem posljednjem tutorijalu raspravljali smo o tri različite formule za testiranje više uvjeta i vraćanje različitih vrijednosti ovisno o rezultatima tih testova. A sada, da vidimo kako možete izvesti različite kalkulacije u zavisnosti od vrijednosti u ciljnoj ćeliji.

Pretpostavimo da imate brojeve prodaje u koloni B i želite izračunati bonuse na osnovu tih brojeva: ako je prodaja veća od 300 USD , bonus je 10%; za prodaju između $201 i $300 bonus je 7%; za prodaju između $101 i $200 bonus je 5%, a nema bonusa za prodaju ispod $100.

Da biste to učinili, jednostavno pomnožite prodaju (B2) sa odgovarajućim postotkom. Kako znate s kojim postotkom pomnožiti? Testiranjem različitih uslova sa ugniježđenim IF-ovima:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

U radnim listovima u stvarnom životu, možda bi bilo zgodnije unijeti procente u zasebne ćelije i referencirati te ćelije u vašoj formuli:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Ključna stvar je fiksiranje referenci bonus ćelija sa znakom $ kako bi se spriječilo njihovo mijenjanje kada kopirate formulu niz kolonu.

Excel uvjetno oblikovanje ako ćelija sadrži određeni tekst

Ako želite istaknuti ćelije s određenim tekstom, postavite Excel pravilo uvjetnog oblikovanja na osnovu jednog od sljedećihformule.

Osjetljivo na velika i mala slova:

Osjetljivo na velika i mala slova:

Na primjer, da biste istakli SKU-ove koji sadrže riječi "haljina", napravite pravilo uslovnog oblikovanja sa donjom formulom i primijenite ga na onoliko ćelija u stupcu A koliko vam je potrebno počevši od ćelije A2:

=SEARCH("dress", A2)>0

Excel formula za uvjetno oblikovanje: ako ćelija sadrži tekst (više uvjeta)

Da biste istakli ćelije koje sadrže dva ili više tekstualnih nizova, ugniježdite nekoliko funkcija pretraživanja unutar formule I. Na primjer, da biste istakli ćelije "plave haljine", kreirajte pravilo zasnovano na ovoj formuli:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

Za detaljne korake pogledajte Kako kreirajte pravilo uvjetnog oblikovanja s formulom.

Ako ćelija sadrži određeni tekst, uklonite cijeli red

U slučaju da želite izbrisati redove koji sadrže određeni tekst, koristite Excelovu funkciju Find and Replace na ovaj način :

1. Izaberite sve ćelije koje želite provjeriti.
2. Pritisnite Ctrl + F da otvorite Pronađi i zamijeni dijaloški okvir.
3. U okvir Pronađi što , upišite tekst ili broj koji tražite i kliknite na Pronađi sve
4. Kliknite na bilo koji rezultat pretraživanja, a zatim pritisnite Ctrl + A da odaberete sve.
5. Kliknite na dugme Zatvori da zatvorite Pronađi i zamijeni
6. Pritisnite Ctrl i dugme minus istovremeno ( Ctrl - ), što je Excelprečica za Izbriši.
7. U dijaloškom okviru Izbriši odaberite Cijeli red i kliknite OK. Gotovo!

Na snimku ekrana ispod, brišemo redove koji sadrže "dress":

Ako ćelija sadrži, odaberite ili kopirajte cijele redove

U situacijama kada želite odabrati ili kopirati redove s relevantnim podacima, koristite Excelov AutoFilter za filtriranje takvih redova. Nakon toga, pritisnite Ctrl + A da odaberete filtrirane podatke, Ctrl+C da ih kopirate i Ctrl+V da zalijepite podatke na drugu lokaciju.

Da filtrirate ćelije s dva ili više kriterija, koristite Napredni filter da biste pronašli takve ćelije, a zatim kopirajte cijele redove s rezultatima ili izdvojite samo određene stupce.

Ovo je način na koji manipulirate ćelijama na osnovu njihove vrijednosti u Excelu. Zahvaljujem vam što ste čitali i nadam se da se vidimo na našem blogu sljedeće sedmice!

Radna sveska za vježbanje

Excel ako ćelija sadrži onda - primjeri (.xlsx datoteka)