Udžbenik pokazuje kako kombinirati funkcije V LOOKUP i IF zajedno u v-pretraživanje s uvjetom if u Excelu. Također ćete naučiti kako koristiti formule IF ISNA VLOOKUP za zamjenu pogrešaka #N/A vlastitim tekstom, nulom ili praznom ćelijom.

Iako su funkcije VLOOKUP i IF korisne same za sebe, zajedno donose još vrijednija iskustva. Ovaj vodič podrazumijeva da dobro zapamtite sintaksu dviju funkcija, u suprotnom možda želite obnoviti svoje znanje slijedeći gornje veze.

Vlookup s If naredbom: return True/ False, Yes/No itd.

Jedan od najčešćih scenarija kada zajedno kombinirate If i Vlookup je usporedba vrijednosti koju vraća Vlookup s uzorkom vrijednosti i vraćanje Da / Ne ili Točno / Netočno kao rezultat.

U većini slučajeva, sljedeća generička formula bi dobro funkcionirala:

Prevedeno na jednostavan engleski, formula upućuje Excel da vrati True ako je Vlookup istinit (tj. jednak navedenoj vrijednosti). Ako je Vlookup false (nije jednak navedenoj vrijednosti), formula vraća False .

U nastavku ćete pronaći nekoliko stvarnih upotreba ove IF Vlookup formule.

Primjer 1. Potražite određenu vrijednost

Recimo, imate popis stavki u stupcu A i količinu u stupcu B. Izrađujete nadzornu ploču za svoje korisnike i potrebna vam je formulakoji bi provjerio količinu artikla u E1 i obavijestio korisnika je li artikl na zalihi ili je rasprodan.

Izvlačite količinu uobičajenim Vlookupom s formulom točnog podudaranja poput ove:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

Zatim napišite IF naredbu koja uspoređuje Vlookupov rezultat s nulom i vraća "Ne" ako je jednak 0, "Da" inače:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

Umjesto Da/Ne , možete vratiti TOČNO/NETOČNO ili Na zalihi/Rasprodano ili bilo koja druga dva izbora. Na primjer:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

Također možete usporediti vrijednost koju vraća Vlookup s uzorkom teksta . U ovom slučaju, obavezno stavite tekstualni niz u navodnike, ovako:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

Primjer 2. Usporedite Vlookup rezultat s drugom ćelijom

Još jedan tipičan primjer Vlookup s If uvjetom u Excelu uspoređuje Vlookup izlaz s vrijednošću u drugoj ćeliji. Na primjer, možemo provjeriti je li veći ili jednak broju u ćeliji G2:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

I ovdje je naša If formula s Vlookupom na djelu:

Na sličan način, možete koristiti bilo koji drugi logički operator zajedno s referencom ćelije u vašoj Excel If Vlookup formuli.

Primjer 3. Vlookup vrijednosti u kraćem popisu

Za usporedbu svake ćelije u ciljnom stupcu s drugim popisom i vraćanje True ili Yes ako se pronađe podudaranje, False ili No inače upotrijebite ovu generičku formulu IF ISNA VLOOKUP:

Ako Vlookup rezultira pogreškom #N/A, formula vraća "Ne", što znači da tražena vrijednost nije pronađena na popisu za traženje. Ako se pronađe podudaranje, vraća se "Da". Na primjer:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

Ako vaša poslovna logika zahtijeva suprotne rezultate, jednostavno zamijenite "Da" i "Ne" da biste preokrenuli logiku formule:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Excel If Vlookup formula za izvođenje različitih izračuna

Osim prikazivanja vlastitih tekstualnih poruka, If funkcija s Vlookupom može izvoditi različite izračune na temelju kriterija koje navedete.

Idemo dalje s našim primjerom, izračunajmo proviziju određenog prodavača (F1) ovisno o njihovoj učinkovitosti: 20% provizije za one koji su zaradili 200 USD i više, 10% za sve ostale .

Za ovo provjerite je li vrijednost koju vraća Vlookup veća ili jednaka 200, i ako jest, pomnožite je s 20%, inače s 10%:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

Gdje su A2:A10 imena prodavača, a C2:C10 prodaja.

Ako je ISNA VLOOKUP za skrivanje #N/A pogrešaka

Ako funkcija VLOOKUP ne može pronaći određenu vrijednost, javlja se pogreška #N/A. Da biste uhvatili tu pogrešku i zamijenili je vlastitim tekstom, ugradite Vlookup formulu u logički test funkcije IF, ovako:

Naravno, možete upisati bilo koji tekst koji želite umjesto "Nije pronađeno".

Pretpostavimo da imate popis prodavačaimena u jednom stupcu i iznose prodaje u drugom stupcu. Vaš zadatak je izvući broj koji odgovara imenu koje korisnik unese u F1. Ako ime nije pronađeno, prikažite poruku koja to pokazuje.

S imenima u A2:A10 i iznosima C2:C10, zadatak se može ispuniti sa sljedećom If Vlookup formulom:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

Ako je ime pronađeno, vraća se odgovarajući iznos prodaje:

Ako vrijednost pretraživanja nije pronađena, Nije pronađeno pojavljuje se poruka umjesto #N/A pogreške:

Kako ova formula funkcionira

Logika formule je vrlo jednostavna: koristite funkciju ISNA da provjerite Vlookup za #N/A pogreške. Ako dođe do pogreške, ISNA vraća TRUE, inače FALSE. Gornje vrijednosti idu na logički test funkcije IF, koja radi jedno od sljedećeg:

• Ako je logički test TRUE (pogreška #N/A), prikazuje se vaša poruka.
• Ako je logički test FALSE (pronađena je vrijednost traženja), Vlookup normalno vraća podudaranje.

IFNA VLOOKUP u novijim verzijama Excela

Počevši od Excela 2013, vi može koristiti funkciju IFNA umjesto IF ISNA za hvatanje i obradu pogrešaka #N/A:

U našem primjeru, formula bi poprimite sljedeći oblik:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

Savjet. Ako želite uhvatiti sve vrste pogrešaka, ne samo #N/A, koristite VLOOKUP u kombinaciji s funkcijom IFERROR. Više detalja možete pronaći ovdje: IFERRORVLOOKUP u Excelu.

Excel Vlookup: ako nije pronađen vraća 0

Kada radite s numeričkim vrijednostima, možda ćete htjeti vratiti nulu kada tražena vrijednost nije pronađena. Da biste to učinili, upotrijebite formulu IF ISNA VLOOKUP o kojoj smo govorili gore uz malu izmjenu: umjesto tekstualne poruke unesite 0 u value_if_true argument funkcije IF:

U našoj oglednoj tablici formula bi bila sljedeća:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

U najnovije verzije programa Excel 2016 i 2013, možete ponovno koristiti kombinaciju IFNA Vlookup:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: ako nije pronađen vrati praznu ćeliju

Ovo je još jedna varijanta izjave "Vlookup if then": ne vraća ništa kada vrijednost pretraživanja nije pronađena. Da biste to učinili, uputite svoju formulu da vrati prazan niz ("") umjesto pogreške #N/A:

Ispod nekoliko potpunih primjera formula:

Za sve verzije Excela:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Za Excel 2016 i Excel 2013:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

If s podudaranjem indeksa - lijevi vlookup s uvjetom If

Iskusni korisnici programa Excel znaju da funkcija VLOOKUP nije jedini način za okomito pretraživanje u programu Excel. Kombinacija INDEX MATCH također se može koristiti u tu svrhu i još je moćnija i svestranija. Dobra vijest je da Index Match može raditi zajedno s IF na potpuno isti način kaoVlookup.

Na primjer, imate brojeve narudžbi u stupcu A i imena prodavača u stupcu B. Tražite formulu za izvlačenje broja narudžbe za određenog prodavatelja.

Vlookup se ne može koristi se u ovom slučaju jer ne može pretraživati ​​s desna na lijevo. Index Match će funkcionirati bez problema sve dok se tražena vrijednost nalazi u traženom stupcu. Ako nije, pojavit će se pogreška #N/A. Da biste standardni zapis pogreške zamijenili vlastitim tekstom, ugniježdite Index Match unutar IF ISNA:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

U programu Excel 2016 i 2016 možete koristiti IFNA umjesto IF ISNA kako biste formulu učinili više compact:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

Na sličan način, možete koristiti Index Match u drugim If formulama.

Ovako koristite Vlookup i IF izjava zajedno u Excelu. Kako biste pobliže pogledali formule o kojima se govori u ovom vodiču, slobodno možete preuzeti naš primjer radne knjige u nastavku. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeći tjedan!

Radna knjiga za vježbe za preuzimanje

Excel IF Vlookup - primjeri formula (.xlsx datoteka)