이전 자습서에서는 대상 셀에 지정된 값이 포함된 경우 Excel If contains 수식이 다른 열에 일부 값을 반환하는 수식을 살펴보았습니다. 그 외에도 셀에 특정 텍스트나 숫자가 포함된 경우 무엇을 할 수 있습니까? 셀 수 계산 또는 합계, 전체 행 강조 표시, 제거 또는 복사 등과 같은 다양한 작업. Microsoft Excel에는 COUNTIF와 COUNTIFS라는 값을 기준으로 셀 수를 세는 두 가지 함수가 있습니다. 이러한 기능은 전부는 아니지만 대부분의 시나리오를 다룹니다. 아래 예는 셀에 특정 작업에 대한 수식이 포함된 경우 적절한 계산을 선택하는 방법을 알려줍니다.

셀에 텍스트가 포함된 경우 계산

텍스트가 포함된 셀의 수를 계산하려는 경우 , 별표 와일드카드 문자를 COUNTIF 수식의 기준으로 사용:

또는 SUMPRODUCT 함수를 ISTEXT:

두 번째 수식에서 ISTEXT 함수는 지정된 범위의 각 셀을 평가하고 TRUE(텍스트) 및 FALSE(텍스트 아님) 값의 배열을 반환합니다. 이중 단항 연산자(--)는 TRUE와 FALSE를 1과 0으로 강제 변환합니다. 및 SUMPRODUCT는 숫자를 더합니다.

아래 스크린샷에 표시된 것처럼 두 수식은 동일한 결과를 산출합니다.

=COUNTIF(A2:A10,"*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

다음을 수행할 수도 있습니다.Excel에서 비어 있지 않은 셀 수를 계산하는 방법을 살펴보세요.

셀에 특정 텍스트가 포함된 경우 계산

특정 텍스트가 포함된 셀 수를 계산하려면 아래와 같이 간단한 COUNTIF 수식을 사용합니다. 여기서 range 는 확인할 셀이고 text 는 검색할 텍스트 문자열이거나 텍스트 문자열을 포함하는 셀에 대한 참조입니다.

예를 들어 A2:A10 범위에서 "dress"라는 단어가 포함된 셀의 수를 계산하려면 다음 수식을 사용합니다.

=COUNTIF(A2:A10, "dress")

또는 스크린샷에 표시된 것:

여기에서 더 많은 수식 예제를 찾을 수 있습니다. Excel에서 텍스트가 있는 셀 계산 방법: 임의의, 특정, 필터링된 셀.

셀에 텍스트가 포함된 경우 계산(부분 일치)

특정 하위 문자열이 포함된 셀의 수를 계산하려면 별표 와일드카드 문자(*)와 함께 COUNTIF 함수를 사용합니다.

예: 계산 A 열에 "드레스"가 내용의 일부로 포함된 셀 수는 다음 공식을 사용하십시오.

=COUNTIF(A2:A10,"*dress*")

또는 일부 셀에 원하는 텍스트를 입력하고 연결하십시오. 와일드카드 문자가 포함된 t 셀:

=COUNTIF(A2:A10,"*"&D1&"*")

자세한 내용은 부분 일치가 있는 COUNTIF 수식을 참조하십시오.

다음의 경우 계산 셀에 여러 하위 문자열 포함(AND 논리)

여러 조건이 있는 셀을 계산하려면 COUNTIFS 함수를 사용합니다. Excel COUNTIFS는 최대 127개의 범위/조건 쌍을 처리할 수 있으며 지정된 모든 조건을 충족하는 셀만

예를 들어 A열에서 "드레스" AND "파란색"이 포함된 셀 수를 확인하려면 다음 수식 중 하나를 사용합니다.

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

또는

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

셀에 숫자가 포함된 경우 계산

숫자가 있는 셀을 계산하는 공식은 상상할 수 있는 가장 간단한 공식입니다.

Excel의 COUNT 함수는 숫자, 날짜 및 시간을 포함한 모든 숫자 값을 포함하는 셀을 계산합니다. Excel에서는 마지막 두 개도 숫자이기 때문입니다.

이 경우 수식은 다음과 같습니다.

=COUNT(A2:A10)

숫자가 포함되지 않은 셀의 수를 계산하려면 SUMPRODUCT 함수를 ISNUMBER 및 NOT과 함께 사용하세요.

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

셀에 텍스트가 포함된 경우 합계

특정 텍스트가 포함된 셀을 찾고 해당 값의 합계를 구하는 Excel 수식을 찾는 경우 다른 열에는 SUMIF 함수를 사용하세요.

예를 들어 재고가 있는 드레스 수를 확인하려면 다음 공식을 사용하세요.

=SUMIF(A2:A10,"*dress*",B2:B10)

여기서 A2:A10은 텍스트 확인할 값과 B2:B10은 합산할 숫자입니다.

또는 아래 스크린샷과 같이 원하는 하위 문자열을 일부 셀(E1)에 넣고 수식에서 해당 셀을 참조합니다.

여러 기준 을 합산하려면 SUMIFS 기능을 사용하세요.

예를 들어 사용 가능한 파란색 드레스가 몇 개인지 확인하려면 이 수식으로:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

또는 다음을 사용합니다.one:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

여기서 A2:A10은 확인할 셀이고 B2:B10은 합산할 셀입니다.

수행 셀 값에 따라 다른 계산

지난 자습서에서 여러 조건을 테스트하고 해당 테스트 결과에 따라 다른 값을 반환하는 세 가지 다른 수식에 대해 설명했습니다. 이제 대상 셀의 값에 따라 어떻게 다른 계산을 수행할 수 있는지 살펴보겠습니다.

B열에 판매 수치가 있고 해당 수치를 기준으로 보너스를 계산하려는 경우: 판매액이 $300 이상인 경우 , 보너스는 10%입니다. $201에서 $300 사이의 판매에 대해 보너스는 7%입니다. 101달러에서 200달러 사이의 판매에 대해서는 보너스가 5%이고 100달러 미만의 판매에 대해서는 보너스가 없습니다.

매출액(B2)에 해당 비율을 곱하면 됩니다. 곱할 백분율을 어떻게 알 수 있습니까? 중첩된 IF로 다양한 조건을 테스트하여:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

실제 워크시트에서는 별도의 셀에 백분율을 입력하고 공식에서 해당 셀을 참조하는 것이 더 편리할 수 있습니다.

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

가장 중요한 것은 수식을 열 아래로 복사할 때 변경되지 않도록 보너스 셀의 참조를 $ 기호로 고정하는 것입니다.

셀에 특정 텍스트가 포함된 경우 Excel 조건부 서식

특정 텍스트가 있는 셀을 강조 하려면 다음 중 하나를 기준으로 Excel 조건부 서식 규칙을 설정합니다.수식.

대소문자 구분:

대소문자 구분:

예를 들어 "dress"라는 단어가 포함된 SKU를 강조 표시하려면 아래 수식으로 조건부 서식 규칙을 만들어 적용합니다. 셀 A2부터 시작하여 열 A의 셀 수만큼:

=SEARCH("dress", A2)>0

Excel 조건부 서식 수식: 셀에 텍스트가 포함된 경우(여러 조건)

두 개 이상의 텍스트 문자열이 포함된 셀을 강조 표시하려면 AND 수식 내에 여러 검색 기능을 중첩하십시오. 예를 들어 "파란색 드레스" 셀을 강조 표시하려면 다음 수식을 기반으로 규칙을 만듭니다.

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

자세한 단계는 방법을 참조하십시오. 수식으로 조건부 서식 규칙을 만듭니다.

셀에 특정 텍스트가 포함된 경우 전체 행을 제거합니다.

특정 텍스트가 포함된 행을 삭제하려면 이 방법으로 Excel의 찾기 및 바꾸기 기능을 사용하세요. :

1. 확인하려는 모든 셀을 선택합니다.
2. Ctrl + F를 눌러 찾기 및 바꾸기 대화 상자를 엽니다.
3. 에서 찾을 내용 상자에 찾고자 하는 텍스트나 숫자를 입력하고 모두 찾기
4. 검색 결과를 클릭한 다음 Ctrl + A를 누릅니다. 모두 선택합니다.
5. 닫기 버튼을 클릭하여 찾기 및 바꾸기
6. Ctrl과 빼기 버튼을 동시에 누릅니다( Ctrl - ), Excel입니다.삭제 바로 가기입니다.
7. 삭제 대화 상자에서 전체 행 을 선택하고 확인을 클릭합니다. Done!

아래 스크린샷에서 "dress"가 포함된 행을 삭제하고 있습니다.

셀에 포함된 경우 전체 행을 선택하거나 복사합니다.

관련 데이터가 있는 행을 선택하거나 복사하려는 경우 Excel의 자동 필터를 사용하여 해당 행을 필터링합니다. 그런 다음 Ctrl + A를 눌러 필터링된 데이터를 선택하고 Ctrl+C를 눌러 복사하고 Ctrl+V를 눌러 데이터를 다른 위치에 붙여넣습니다.

2개 이상의 기준으로 셀을 필터링하려면 고급 필터를 사용하세요. 이러한 셀을 찾은 다음 결과와 함께 전체 행을 복사하거나 특정 열만 추출합니다.

이것은 Excel에서 해당 값을 기반으로 셀을 조작하는 방법입니다. 읽어 주셔서 감사합니다. 다음 주 블로그에서 뵙기를 바랍니다!

연습 워크북

Excel If Cell Contains Then - 예제(.xlsx 파일)