Önceki eğitimimizde, bir hedef hücre belirli bir değer içeriyorsa başka bir sütuna bir değer döndüren formüller içeriyorsa Excel'e bakıyorduk. Bunun dışında, bir hücre belirli bir metin veya sayı içeriyorsa başka ne yapabilirsiniz? Hücreleri saymak veya toplamak, vurgulamak, tüm satırları kaldırmak veya kopyalamak ve daha fazlası gibi çeşitli şeyler.

Excel 'Hücre içeriyorsa say' formülü örnekleri

Microsoft Excel'de, hücreleri değerlerine göre saymak için iki işlev vardır: EĞERSAY ve EĞERSAY. Bu işlevler, tüm senaryoları olmasa da çoğunu kapsar. Aşağıdaki örnekler, özel göreviniz için uygun bir Hücre içeriyorsa say formülünü nasıl seçeceğinizi öğretecektir.

Hücre herhangi bir metin içeriyorsa sayın

Herhangi bir metin içeren hücreleri saymak istediğiniz durumlarda, EĞERSAY formülünüzde ölçüt olarak yıldız işareti joker karakterini kullanın:

Veya SUMPRODUCT işlevini ISTEXT ile birlikte kullanın:

İkinci formülde, ISTEXT işlevi belirtilen aralıktaki her hücreyi değerlendirir ve DOĞRU (metin) ve YANLIŞ (metin değil) değerlerinden oluşan bir dizi döndürür; çift tekli işleç (--) DOĞRU ve YANLIŞ'ı 1'lere ve 0'lara zorlar; ve SUMPRODUCT sayıları toplar.

Aşağıdaki ekran görüntüsünde gösterildiği gibi, her iki formül de aynı sonucu verir:

=COUNTIF(A2:A10, "*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Excel'de boş olmayan hücrelerin nasıl sayılacağına da bakmak isteyebilirsiniz.

Hücre belirli bir metin içeriyorsa say

Belirli bir metni içeren hücreleri saymak için aşağıda gösterildiği gibi basit bir EĞERSAY formülü kullanın, burada aralık kontrol edilecek hücrelerdir ve Metin aranacak metin dizesi veya metin dizesini içeren hücreye bir referanstır.

Örneğin, A2:A10 aralığındaki "dress" sözcüğünü içeren hücreleri saymak için şu formülü kullanın:

=COUNTIF(A2:A10, "elbise")

Ya da ekran görüntüsünde gösterilen:

Burada daha fazla formül örneği bulabilirsiniz: Excel'de metin içeren hücreler nasıl sayılır: herhangi, belirli, filtrelenmiş hücreler.

Hücre metin içeriyorsa say (kısmi eşleşme)

Belirli bir alt dizeyi içeren hücreleri saymak için, COUNTIF işlevini yıldız işareti joker karakteriyle (*) birlikte kullanın.

Örneğin, A sütunundaki kaç hücrenin içeriğinin bir parçası olarak "elbise" içerdiğini saymak için bu formülü kullanın:

=COUNTIF(A2:A10,"*dress*")

Veya istediğiniz metni bir hücreye yazın ve bu hücreyi joker karakterlerle birleştirin:

=COUNTIF(A2:A10,"*"&D1&"*")

Daha fazla bilgi için lütfen bakınız: Kısmi eşleşmeli COUNTIF formülleri.

Hücre birden fazla alt dize içeriyorsa say (AND mantığı)

Birden çok koşula sahip hücreleri saymak için EĞERSAY işlevini kullanın. Excel EĞERSAY, 127 adede kadar aralık/kriter çiftini işleyebilir ve yalnızca belirtilen koşulların tümünü karşılayan hücreler sayılır.

Örneğin, A sütununda kaç hücrenin "elbise" VE "mavi" içerdiğini bulmak için aşağıdaki formüllerden birini kullanın:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Ya da

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Hücre sayı içeriyorsa sayın

Hücreleri sayılarla saymak için kullanılan formül, hayal edilebilecek en basit formüldür:

Excel'deki COUNT işlevinin sayılar, tarihler ve saatler dahil olmak üzere herhangi bir sayısal değer içeren hücreleri saydığını lütfen unutmayın, çünkü Excel açısından son ikisi de sayıdır.

Bizim durumumuzda formül aşağıdaki gibidir:

=COUNT(A2:A10)

Sayı içermeyen hücreleri saymak için, SUMPRODUCT işlevini ISNUMBER ve NOT ile birlikte kullanın:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Hücre metin içeriyorsa topla

Belirli bir metni içeren hücreleri bulmak ve başka bir sütunda karşılık gelen değerleri toplamak için bir Excel formülü arıyorsanız, SUMIF işlevini kullanın.

Örneğin, stokta kaç elbise olduğunu bulmak için şu formülü kullanın:

=SUMIF(A2:A10,"*dress*",B2:B10)

Burada A2:A10 kontrol edilecek metin değerleri ve B2:B10 toplanacak sayılardır.

Veya ilgilenilen alt dizeyi bir hücreye (E1) yerleştirin ve aşağıdaki ekran görüntüsünde gösterildiği gibi formülünüzde bu hücreye başvuruda bulunun:

için birden fazla ölçütle toplama SUMIFS işlevini kullanın.

Örneğin, kaç tane mavi elbise olduğunu bulmak için şu formülü kullanın:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Ya da bunu kullan:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Burada A2:A10 kontrol edilecek hücreler ve B2:B10 toplanacak hücrelerdir.

Hücre değerine göre farklı hesaplamalar gerçekleştirme

Son eğitimimizde, birden fazla koşulu test etmek ve bu testlerin sonuçlarına bağlı olarak farklı değerler döndürmek için üç farklı formülden bahsetmiştik. Şimdi de, bir hedef hücredeki değere bağlı olarak nasıl farklı hesaplamalar yapabileceğinizi görelim.

B sütununda satış rakamlarınız olduğunu ve bu rakamlara göre ikramiye hesaplamak istediğinizi varsayalım: 300 doların üzerinde bir satış varsa ikramiye %10; 201 ila 300 dolar arasındaki satışlar için ikramiye %7; 101 ila 200 dolar arasındaki satışlar için ikramiye %5 ve 100 doların altındaki satışlar için ikramiye yok.

Bunu yapmak için, satışları (B2) ilgili bir yüzdeyle çarpmanız yeterlidir. Hangi yüzdeyle çarpacağınızı nasıl anlarsınız? İç içe IF'lerle farklı koşulları test ederek:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

Gerçek hayattaki çalışma sayfalarında, yüzdeleri ayrı hücrelere girmek ve formülünüzde bu hücrelere başvurmak daha uygun olabilir:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Önemli olan, formülü sütundan aşağı kopyaladığınızda değişmelerini önlemek için bonus hücrelerinin referanslarını $ işaretiyle sabitlemektir.

Hücre belirli bir metin içeriyorsa Excel koşullu biçimlendirme

Eğer istiyorsan vurgulamak belirli metin içeren hücreler için, aşağıdaki formüllerden birini temel alan bir Excel koşullu biçimlendirme kuralı ayarlayın.

Harf büyüklüğüne duyarsız:

Harfe duyarlı:

Örneğin, "elbise" sözcüklerini içeren SKU'ları vurgulamak için, aşağıdaki formülle bir koşullu biçimlendirme kuralı oluşturun ve A2 hücresinden başlayarak A sütununda ihtiyacınız olan sayıda hücreye uygulayın:

=SEARCH("elbise", A2)>0

Excel koşullu biçimlendirme formülü: hücre metin içeriyorsa (birden çok koşul)

İki veya daha fazla metin dizesi içeren hücreleri vurgulamak için, birkaç Arama işlevini bir VE formülü içinde yerleştirin. Örneğin, "mavi elbise" hücrelerini vurgulamak için, bu formüle dayalı bir kural oluşturun:

=AND(SEARCH("elbise", A2)>0, SEARCH("mavi", A2)>0)

Ayrıntılı adımlar için lütfen Formülle koşullu biçimlendirme kuralı oluşturma bölümüne bakın.

Hücre belirli bir metin içeriyorsa, tüm satırı kaldırın

Belirli bir metni içeren satırları silmek istemeniz durumunda, Excel'in Bul ve Değiştir özelliğini bu şekilde kullanın:

1. Kontrol etmek istediğiniz tüm hücreleri seçin.
2. Açmak için Ctrl + F tuşlarına basın Bul ve Değiştir iletişim kutusu.
3. İçinde Ne olduğunu bulun kutusuna aradığınız metni veya sayıyı yazın ve Tümünü Bul
4. Herhangi bir arama sonucuna tıklayın ve ardından tümünü seçmek için Ctrl + A tuşlarına basın.
5. Tıklayınız Kapat düğmesini kapatmak için Bul ve Değiştir
6. Ctrl ve eksi düğmesine aynı anda basın ( Ctrl - ), bu Sil için Excel kısayoludur.
7. İçinde Silme iletişim kutusunu seçin, ardından Tüm sıra ve Tamam'a tıklayın. Bitti!

Aşağıdaki ekran görüntüsünde, "elbise" içeren satırları siliyoruz:

Hücre içeriyorsa, tüm satırları seçin veya kopyalayın

İlgili verileri içeren satırları seçmek veya kopyalamak istediğiniz durumlarda, bu tür satırları filtrelemek için Excel'in Otomatik Filtresini kullanın. Bundan sonra, filtrelenmiş verileri seçmek için Ctrl + A tuşlarına, kopyalamak için Ctrl+C tuşlarına ve verileri başka bir konuma yapıştırmak için Ctrl+V tuşlarına basın.

Hücreleri iki veya daha fazla ölçütle filtrelemek için, bu tür hücreleri bulmak üzere Gelişmiş Filtre'yi kullanın ve ardından sonuçları içeren tüm satırları kopyalayın veya yalnızca belirli sütunları ayıklayın.

Excel'de hücreleri değerlerine göre bu şekilde değiştirebilirsiniz. Okuduğunuz için teşekkür eder, gelecek hafta blogumuzda görüşmek dileğiyle!

Alıştırma çalışma kitabı

Excel If Cell Contains Then - örnekler (.xlsx dosyası)