Алдыңғы оқулығымызда, егер мақсатты ұяшықта берілген мән болса, кейбір мәндерді басқа бағанға қайтаратын формулалар болса, Excel бағдарламасын қарастырдық. Бұдан басқа, ұяшықта белгілі бір мәтін немесе сан болса, тағы не істеуге болады? Ұяшықтарды санау немесе қосу, бүкіл жолдарды бөлектеу, жою немесе көшіру және т.б. сияқты әртүрлі әрекеттер.

Excel "Ұяшық бар болса санау" формула мысалдары

Ішінде Microsoft Excel бағдарламасында ұяшықтарды мәндеріне қарай санайтын екі функция бар: COUNTIF және COUNTIFS. Бұл функциялар сценарийлердің барлығын болмаса да, көпшілігін қамтиды. Төмендегі мысалдар ұяшықта нақты тапсырмаға арналған формула болса, сәйкес Санды таңдау жолын үйретеді.

Ұяшықта мәтін бар-жоғын санау

Кез келген мәтіні бар ұяшықтарды санағыңыз келетін жағдайларда , COUNTIF формулаңыздағы шарт ретінде жұлдызша қойылмалы таңбасын пайдаланыңыз:

Немесе SUMPRODUCT функциясын ISTEXT:

Екінші формулада ISTEXT функциясы көрсетілген ауқымдағы әрбір ұяшықты бағалайды және АҚИҚАТ (мәтін) және ЖАЛҒАН (мәтін емес) мәндерінің жиымын қайтарады; қос унарлық оператор (--) TRUE және FALSE мәндерін 1 және 0-ге мәжбүрлейді; және SUMPRODUCT сандарды қосады.

Төмендегі скриншотта көрсетілгендей, екі формула да бірдей нәтиже береді:

=COUNTIF(A2:A10,"*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Сіз де қалауыңыз мүмкінExcel бағдарламасында бос емес ұяшықтарды санау жолын қараңыз.

Ұяшықта белгілі бір мәтін болса, санаңыз

Арнайы мәтіні бар ұяшықтарды санау үшін төменде көрсетілгендей қарапайым COUNTIF формуласын пайдаланыңыз, мұнда ауқым - тексерілетін ұяшықтар және мәтін - ізделетін мәтін жолы немесе мәтіндік жолды қамтитын ұяшыққа сілтеме.

Мысалы, "көйлек" сөзі бар A2:A10 ауқымындағы ұяшықтарды санау үшін мына формуланы пайдаланыңыз:

=COUNTIF(A2:A10, "dress")

Немесе скриншотта көрсетілген:

Көбірек формула мысалдарын мына жерден таба аласыз: Excel бағдарламасында мәтіні бар ұяшықтарды қалай санауға болады: кез келген, арнайы, сүзілген ұяшықтар.

Ұяшықта мәтін болса (жартылай сәйкестік) санау

Белгілі бір ішкі жолды қамтитын ұяшықтарды санау үшін жұлдызша қойылмалы таңбасымен (*) COUNTIF функциясын пайдаланыңыз.

Мысалы, санау үшін А бағанындағы қанша ұяшықта олардың мазмұнының бір бөлігі ретінде «көйлек» болса, мына формуланы пайдаланыңыз:

=COUNTIF(A2:A10,"*dress*")

Немесе кейбір ұяшыққа қажетті мәтінді теріп, оны біріктіріңіз қойылмалы таңбалары бар t ұяшығы:

=COUNTIF(A2:A10,"*"&D1&"*")

Қосымша ақпарат алу үшін мынаны қараңыз: ішінара сәйкес келетін COUNTIF формулалары.

Егер санау керек ұяшықта бірнеше ішкі жолдар бар (ЖӘНЕ логика)

Бірнеше шарттары бар ұяшықтарды санау үшін COUNTIFS функциясын пайдаланыңыз. Excel COUNTIFS 127-ге дейін ауқымды/шарттар жұбын өңдей алады және барлық көрсетілген шарттарға сәйкес келетін ұяшықтар ғана болады.саналды.

Мысалы, А бағанында қанша ұяшықта «көйлек» ЖӘНЕ «көк» бар екенін білу үшін келесі формулалардың бірін пайдаланыңыз:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Немесе

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Егер ұяшықта сан болса, санау

Сандары бар ұяшықтарды санау формуласы елестетуге болатын ең қарапайым формула:

Excel бағдарламасындағы COUNT функциясы кез келген сандық мәнді қамтитын ұяшықтарды санайтынын есте сақтаңыз, соның ішінде сандар, күндер және уақыттар, өйткені Excel терминінде соңғы екеуі де сандар болып табылады.

Біздің жағдайда формула келесідей болады:

=COUNT(A2:A10)

САНДАРЫ ЖОҚ ұяшықтарды санау үшін ISNUMBER және ЕМЕС дегенмен бірге SUMPRODUCT функциясын пайдаланыңыз:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Егер ұяшықта мәтін болса, сома

Егер сіз арнайы мәтіні бар ұяшықтарды табу және сәйкес мәндерді қосу үшін Excel формуласын іздесеңіз басқа бағанда SUMIF функциясын пайдаланыңыз.

Мысалы, қоймада қанша көйлек бар екенін білу үшін мына формуланы пайдаланыңыз:

=SUMIF(A2:A10,"*dress*",B2:B10)

Мұндағы A2:A10 мәтін тексерілетін мәндер және B2:B10 қосылатын сандар.

Немесе, қызықты ішкі жолды кейбір ұяшыққа (E1) қойыңыз және төмендегі скриншотта көрсетілгендей формулаңыздағы сол ұяшыққа сілтеме жасаңыз:

Бірнеше критерийлері бар қосынды үшін SUMIFS функциясын пайдаланыңыз.

Мысалы, қанша көк көйлек бар екенін білу үшін өтіңіз. мына формуламен:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Немесе мынаны пайдаланыңызбіреуі:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Мұндағы A2:A10 - тексерілетін ұяшықтар және B2:B10 - қосылатын ұяшықтар.

Орындаңыз. ұяшық мәніне негізделген әртүрлі есептеулер

Соңғы оқулықта біз бірнеше шарттарды тексеру және сол сынақтардың нәтижелеріне байланысты әртүрлі мәндерді қайтару үшін үш түрлі формуланы талқыладық. Ал енді мақсатты ұяшықтағы мәнге байланысты әртүрлі есептеулерді қалай орындауға болатынын көрейік.

Егер сіз B бағанында сату нөмірлері бар және сол сандар негізінде бонустарды есептегіңіз келсе: егер сатылым $300-ден асса. , бонус 10% құрайды; $201 және $300 аралығындағы сатылымдар үшін бонус 7% құрайды; $101 және $200 аралығындағы сатылымдар үшін бонус 5% құрайды, ал $100-ден аз сатылымдар үшін бонус жоқ.

Оны орындау үшін сатылымдарды (B2) сәйкес пайызға көбейтіңіз. Қай пайызды көбейту керектігін қалай білуге ​​болады? Кірістірілген IFs көмегімен әртүрлі шарттарды сынау арқылы:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

Нақты өмірдегі жұмыс парақтарында пайыздарды бөлек ұяшықтарға енгізу және формуладағы сол ұяшықтарға сілтеме жасау ыңғайлырақ болуы мүмкін:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Ең бастысы, формуланы бағанға көшіргенде олардың өзгеруін болдырмау үшін бонус ұяшықтарының сілтемелерін $ белгісімен бекіту.

Егер ұяшықта белгілі бір мәтін болса, Excel шартты пішімдеу

Егер белгілі бір мәтіні бар ұяшықтарды ерекшелеу қажет болса, төмендегілердің біріне негізделген Excel шартты пішімдеу ережесін орнатыңыз.формулалар.

Регізгі әріптерді ескермейді:

әріптерді ескермейді:

Мысалы, құрамында "көйлек" сөздері бар SKU мәндерін бөлектеу үшін төмендегі формуламен шартты пішімдеу ережесін жасаңыз және оны қолданыңыз A2 ұяшығынан басталатын A бағанындағы ұяшықтардың санына дейін:

=SEARCH("dress", A2)>0

Excel шартты пішімдеу формуласы: ұяшықта мәтін болса (бірнеше шарттар)

Екі немесе одан да көп мәтін жолдары бар ұяшықтарды бөлектеу үшін ЖӘНЕ формуласының ішінде бірнеше Іздеу функцияларын кірістіріңіз. Мысалы, «көк көйлек» ұяшықтарын бөлектеу үшін мына формулаға негізделген ережені жасаңыз:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

Егжей-тегжейлі қадамдарды «Қалай істеу керек» бөлімінен қараңыз. формуламен шартты пішімдеу ережесін жасаңыз.

Егер ұяшықта белгілі бір мәтін болса, бүкіл жолды алып тастаңыз

Егер белгілі бір мәтіні бар жолдарды жойғыңыз келсе, Excel бағдарламасының "Табу және ауыстыру" мүмкіндігін осылай пайдаланыңыз. :

1. Тексергіңіз келетін барлық ұяшықтарды таңдаңыз.
2. Табу және ауыстыру диалогтық терезесін ашу үшін Ctrl + F пернелерін басыңыз.
3. Ішінде Нені табу жолағында іздеген мәтінді немесе нөмірді теріңіз де, Барлығын табу
4. Кез келген іздеу нәтижесін нұқыңыз, содан кейін Ctrl + A пернелерін басыңыз. барлығын таңдау үшін.
5. Табу және ауыстыруды жабу үшін Жабу түймесін басыңыз
6. Ctrl және минус түймесін бір уақытта басыңыз ( Ctrl - ), бұл Excel бағдарламасыЖою таңбашасы.
7. Жою тілқатысу терезесінде Толық жол параметрін таңдап, OK түймесін басыңыз. Дайын!

Төмендегі скриншотта біз "көйлек" бар жолдарды жоямыз:

Егер ұяшықта болса, барлық жолдарды таңдаңыз немесе көшіріңіз

Сәйкес деректері бар жолдарды таңдағыңыз немесе көшіргіңіз келетін жағдайларда мұндай жолдарды сүзу үшін Excel автосүзгісін пайдаланыңыз. Осыдан кейін сүзгіленген деректерді таңдау үшін Ctrl + A пернелер тіркесімін, көшіру үшін Ctrl+C, ал деректерді басқа орынға қою үшін Ctrl+V пернелер тіркесімін басыңыз.

Екі немесе одан да көп шарты бар ұяшықтарды сүзу үшін Кеңейтілген сүзгіні пайдаланыңыз. осындай ұяшықтарды тауып, содан кейін нәтижелері бар жолдарды түгел көшіріңіз немесе тек арнайы бағандарды шығарыңыз.

Осылайша Excel бағдарламасындағы мәніне қарай ұяшықтарды басқарасыз. Оқығаныңыз үшін алғыс айтамын және келесі аптада блогымызда көреміз деп үміттенемін!

Тәжірибелік жұмыс кітабы

Excel, егер ұяшық құрамында болса - мысалдар (.xlsx файлы)