Dok Microsoft Excel nudi niz funkcija za rad s radnim danima, mjesecima i godinama, samo je jedna dostupna tjednima - funkcija WEEKNUM. Dakle, ako tražite način da dobijete broj tjedna iz datuma, WEEKNUM je funkcija koju želite.

U ovom kratkom vodiču, ukratko ćemo govoriti o sintaksi i argumentima programa Excel WEEKNUM, i zatim porazgovarajte o nekoliko primjera formula koji pokazuju kako možete koristiti funkciju WEEKNUM za izračunavanje brojeva tjedana u svojim radnim listovima programa Excel.

Funkcija WEEKNUM programa Excel - sintaksa

Funkcija WEEKNUM je koristi se u Excelu za vraćanje broja tjedna određenog datuma u godini (broj između 1 i 54). Ima dva argumenta, prvi je obavezan, a drugi nije obavezan:

• Serijski_broj - bilo koji datum unutar tjedna čiji broj pokušavate pronaći. To može biti referenca na ćeliju koja sadrži datum, datum unesen pomoću funkcije DATE ili vraćen nekom drugom formulom.
• Return_type (neobavezno) - broj koji određuje na koji dan počinje tjedan. Ako se izostavi, koristi se zadana vrsta 1 (tjedan koji počinje u nedjelju).

Ovdje je kompletan popis return_type vrijednosti podržanih u formulama WEEKNUM.

U funkciji WEEKNUM koriste se dva različita sustava numeriranja tjedana :

• Sustav 1. Razmatra se tjedan koji sadrži 1. siječnja 1. tjedan u godini i označen je brojem 1. tjedan. U ovom sustavu tjedan tradicionalno počinje nedjeljom.
• Sustav 2. Ovo je ISO sustav datuma tjedna koji je dio ISO 8601 standard za datum i vrijeme. U ovom sustavu tjedan počinje u ponedjeljak, a tjedan koji sadrži prvi četvrtak u godini smatra se 1. tjednom. Opće je poznat kao europski sustav numeriranja tjedana i koristi se uglavnom u vladi i poslovanju za fiskalne godine i mjerenje vremena.

Svi gore navedeni tipovi povrata odnose se na sustav 1, osim tipa povrata 21 koji se koristi u sustavu 2.

Napomena. U programu Excel 2007 i ranijim verzijama dostupne su samo opcije 1 i 2. Vrste povrata od 11 do 21 podržane su samo u Excelu 2010 i Excelu 2013.

Formule programa Excel WEEKNUM za pretvaranje datuma u broj tjedna (od 1 do 54)

Sljedeća snimka zaslona pokazuje kako možete dobiti brojeve tjedana iz datuma pomoću najjednostavnije formule =WEEKNUM(A2) :

U gore navedenomformula, argument return_type je izostavljen, što znači da se koristi zadana vrsta 1 - tjedan koji počinje u nedjelju.

Ako biste radije počeli s nekim drugim danom u tjednu, recimo ponedjeljkom, tada upotrijebite 2 u drugom argumentu:

=WEEKNUM(A2, 2)

Umjesto pozivanja na ćeliju, možete navesti datum izravno u formuli pomoću funkcije DATE(godina, mjesec, dan), na primjer:

=WEEKNUM(DATE(2015,4,15), 2)

Gornja formula vraća 16, što je broj tjedna koji sadrži 15. travnja 2015., s tjednom koji počinje u ponedjeljak.

U scenarijima iz stvarnog života , funkcija Excel WEEKNUM rijetko se koristi samostalno. Najčešće biste ga koristili u kombinaciji s drugim funkcijama za izvođenje raznih izračuna na temelju broja tjedna, kao što je prikazano u daljnjim primjerima.

Kako pretvoriti broj tjedna u datum u Excelu

Kao što Upravo vidjeli, nije velika stvar pretvoriti datum u broj tjedna pomoću funkcije Excel WEEKNUM. Ali što ako tražite suprotno, tj. pretvaranje broja tjedna u datum? Nažalost, ne postoji Excel funkcija koja bi to mogla učiniti odmah. Dakle, morat ćemo konstruirati vlastite formule.

Pretpostavimo da imate godinu u ćeliji A2 i broj tjedna u B2, a sada želite izračunati početni i završni datum u ovom tjednu.

Napomena. Ovaj primjer formule temelji se na ISO brojevima tjedana, s tjednom koji počinje u ponedjeljak.

Formula za vraćanje Početkadatum tjedna je sljedeći:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

Gdje je A2 godina, a B2 broj tjedna.

Imajte na umu da formula vraća datum kao serijski broj, a da bi se prikazao kao datum, trebate formatirati ćeliju u skladu s tim. Detaljne upute možete pronaći u odjeljku Promjena formata datuma u Excelu. A ovdje je rezultat koji vraća formula:

Naravno, formula za pretvaranje broja tjedna u datum nije trivijalna i može potrajati neko vrijeme da se dobije tvoja glava oko logike. U svakom slučaju, dat ću sve od sebe da pružim smisleno objašnjenje onima koji su znatiželjni da dođu do dna.

Kao što vidite, naša se formula sastoji od 2 dijela:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - izračunava datum zadnjeg ponedjeljka u prethodnoj godini.
• B2 * 7 - zbraja broj tjedana pomnožen sa 7 (broj dana u tjednu) kako bi se dobio ponedjeljak (početni datum) tjedna u pitanje.

U ISO sustavu numeriranja tjedana, tjedan 1 je tjedan koji sadrži prvi četvrtak u godini. Prema tome, prvi ponedjeljak je uvijek između 29. prosinca i 4. siječnja. Dakle, da bismo pronašli taj datum, moramo pronaći ponedjeljak neposredno prije 5. siječnja.

U Microsoft Excelu možete izdvojiti dan u tjednu iz datum pomoću funkcije WEEKDAY. I možete koristiti sljedeću generičku formulu da dobijete ponedjeljak neposredno prije bilo kojeg datuma:

Ako je naškrajnji cilj je bio pronaći ponedjeljak neposredno prije 5. siječnja godine u A2, mogli bismo koristiti sljedeće funkcije DATE:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

Ali ono što zapravo trebamo nije prvi ponedjeljak u ove godine, nego zadnji ponedjeljak prethodne godine. Dakle, morate oduzeti 7 dana od 5. siječnja i stoga dobivate -2 u prvoj funkciji DATUM:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

U usporedbi s lukavom formulom koju ste upravo naučili, izračunavanjem Završni datum tjedna je komad kolača :) Da biste dobili nedjelju dotičnog tjedna, jednostavno dodajte 6 dana Početnom datumu , tj. =D2+6

Alternativno, možete dodati 6 izravno u formulu:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

Kako biste bili sigurni da formule uvijek daju točne datume, pogledajte sljedeće snimka zaslona. Gore navedene formule Datum početka i Datum završetka kopiraju se u stupac D odnosno E:

Drugi načini pretvaranja broja tjedna u datum u programu Excel

Ako gornja formula temeljena na ISO tjednom sustavu datuma ne ispunjava vaše zahtjeve, isprobajte jedno od sljedećih rješenja.

Formula 1. Tjedan koji sadrži 1. siječnja je tjedan 1, tjedan od ponedjeljka do nedjelje

Kao što se sjećate, prethodna formula radi na temelju ISO sustava datuma gdje se prvi četvrtak u godini smatra 1. tjednom. Ako radite na temelju datumskog sustava u kojem se tjedan koji sadrži 1. siječnja smatra 1. tjednom, koristite sljedećeformule:

Datum početka:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

Datum završetka:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

Formula 2. Tjedan koji sadrži siječanj-1 je tjedan 1, ned-sub tjedan

Ove formule su slične gornjim s jedinom razlikom što su napisane za nedjelju - subotu tjedan.

Datum početka:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

Datum završetka:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

Formula 3. Uvijek počnite računati 1. siječnja, tjedan od ponedjeljka do nedjelje

Dok prethodne formule vraćaju ponedjeljak (ili nedjelju) 1. tjedna, bez obzira pada li unutar ove ili prethodne godine, ova formula datuma početka uvijek vraća 1. siječnja kao datum početka 1. tjedna bez obzira na dan u tjednu. Analogno tome, formula za datum završetka uvijek vraća 31. prosinca kao datum završetka zadnjeg tjedna u godini, bez obzira na dan u tjednu. U svim ostalim aspektima, ove formule rade slično gornjoj formuli 1.

Datum početka:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

Datum završetka:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

Formula 4. Uvijek počnite brojati 1. siječnja, tjedan ned-sub

Za izračun datuma početka i završetka za tjedan od nedjelje do subote potrebna je samo jedna mala prilagodba u gornjim formulama :)

Datum početka:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

Datum završetka:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

Kako dobiti mjesec iz broja tjedna

Da biste dobili mjesec koji odgovara tjednu broj, pronaći ćete prvi dan u određenom tjednu kao što je objašnjeno u ovomeprimjer, a zatim zamotajte tu formulu u Excel MONTH funkciju ovako:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

Napomena. Upamtite da gornja formula radi na temelju ISO sustava datuma tjedna , gdje tjedan počinje u ponedjeljak, a tjedan koji sadrži 1. četvrtak u godini smatra se 1. tjednom. Na primjer, u 2016. godini, prvi četvrtak je 7. siječnja i zato 1. tjedan počinje 4. siječnja 2016.

Kako dobiti broj tjedna u mjesecu (od 1 do 6)

Ako vaša poslovna logika zahtijeva pretvaranje određenog datuma u broj tjedna unutar odgovarajućeg mjeseca, možete koristiti kombinaciju WEEKNUM, Funkcije DATE i MONTH:

Pod pretpostavkom da ćelija A2 sadrži originalni datum, upotrijebite sljedeću formulu za tjedan koji počinje ponedjeljkom (primijetite 21 u argumentu return_type WEEKNUM-a):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

Za tjedan koji počinje nedjeljom , izostavite argument return_type:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

Kako zbrojite vrijednosti i pronađite prosjek prema broju tjedna

Sada kada znate kako pretvoriti datum u broj tjedna u Excelu, da vidimo kako možete koristiti brojeve tjedana u drugim izračunima.

Pretpostavimo , imate neke mjesečne podatke o prodaji i želite znati ukupni iznos za svaki tjedan.

Za početak, saznajmo broj tjedna koji odgovara svakoj prodaji. Ako su vaši datumi u stupcu A, a prodaja u stupcu B, kopirajte formulu =WEEKNUM(A2) u stupac C počevši od ćelijeC2.

A zatim napravite popis brojeva tjedana u nekom drugom stupcu (recimo, u stupcu E) i izračunajte prodaju za svaki tjedan pomoću sljedeće formule SUMIF:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

Gdje je E2 broj tjedna.

U ovom primjeru radimo s popisom rasprodaja u ožujku, tako da imamo brojeve tjedana od 10 do 14, kao prikazano na sljedećoj snimci zaslona:

Na sličan način možete izračunati prosjek prodaje za određeni tjedan:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

Ako se pomoćni stupac s formulom WEEKNUM ne uklapa dobro u vaš raspored podataka, sa žaljenjem vam moram reći da ne postoji jednostavan način da ga se riješite jer je Excel WEEKNUM jedna od tih funkcija koji ne prihvaća argumente raspona. Stoga se ne može koristiti unutar SUMPRODUCT ili bilo koje druge formule niza poput funkcije MONTH u sličnom scenariju.

Kako istaknuti ćelije na temelju broja tjedna

Recimo da imate dugačak popis datuma u nekom stupcu i želite istaknuti samo one koji se odnose na određeni tjedan. Sve što trebate je pravilo uvjetnog oblikovanja s formulom WEEKNUM slično ovoj:

=WEEKNUM($A2)=10

Kao što je prikazano na snimci zaslona u nastavku, pravilo ističe prodaju koja je ostvarena unutar 10. tjedna, što je prvi tjedan u ožujku 2015. Budući da se pravilo primjenjuje na A2:B15, ono ističe vrijednosti u oba stupca. Ovdje možete saznati više o stvaranju pravila uvjetnog oblikovanjavodič: Excel uvjetno oblikovanje na temelju druge vrijednosti ćelije.

Ovako možete izračunati brojeve tjedana u Excelu, pretvoriti broj tjedna u datum i izdvojiti broj tjedna iz datuma. Nadamo se da će se formule WEEKNUM koje ste danas naučili pokazati korisnima u vašim radnim listovima. U sljedećem vodiču govorit ćemo o izračunavanju dobi i godina u Excelu. Zahvaljujem vam na čitanju i nadam se da se vidimo sljedeći tjedan!