In ons vorige tutoriaal het ons gekyk na Excel As bevat formules wat 'n waarde na 'n ander kolom terugstuur as 'n teikensel 'n gegewe waarde bevat. Behalwe dit, wat anders kan jy doen as 'n sel spesifieke teks of nommer bevat? 'n Verskeidenheid dinge soos tel of optel van selle, uitlig, verwyder of kopieer van hele rye, en meer.

Excel 'Tel as sel bevat' formulevoorbeelde

In Microsoft Excel, daar is twee funksies om selle te tel op grond van hul waardes, COUNTIF en COUNTIFS. Hierdie funksies dek die meeste, maar nie alle nie, scenario's. Die onderstaande voorbeelde sal jou leer hoe om 'n gepaste Telling te kies as sel formule bevat vir jou spesifieke taak.

Tel as sel enige teks bevat

In situasies wanneer jy selle wil tel wat enige teks bevat , gebruik die asterisk-jokerteken as die kriteria in jou COUNTIF-formule:

Of gebruik die SUMPRODUCT-funksie in kombinasie met ISTEXT:

In die tweede formule evalueer die ISTEXT-funksie elke sel in die gespesifiseerde reeks en gee 'n skikking van WAAR (teks) en ONWAAR (nie teks nie) waardes terug; die dubbel unêre operateur (--) dwing WAAR en ONWAAR in 1'e en 0'e; en SUMPRODUCT tel die getalle bymekaar.

Soos in die skermkiekie hieronder getoon, lewer beide formules dieselfde resultaat:

=COUNTIF(A2:A10,"*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Jy wil dalk ookkyk hoe om nie-leë selle in Excel te tel.

Tel as sel spesifieke teks bevat

Om selle te tel wat spesifieke teks bevat, gebruik 'n eenvoudige COUNTIF formule soos hieronder getoon, waar reeks is die selle om na te gaan en teks is die teksstring waarna gesoek moet word of 'n verwysing na die sel wat die teksstring bevat.

Om byvoorbeeld selle in die reeks A2:A10 te tel wat die woord "rok" bevat, gebruik hierdie formule:

=COUNTIF(A2:A10, "dress")

Of die een wat in die skermkiekie gewys word:

Jy kan meer formules voorbeelde hier vind: Hoe om selle met teks in Excel te tel: enige, spesifieke, gefiltreerde selle.

Tel as sel teks bevat (gedeeltelike passing)

Om selle te tel wat 'n sekere substring bevat, gebruik die COUNTIF-funksie met die asterisk-jokerteken (*).

Om byvoorbeeld te tel hoeveel selle in kolom A "rok" as deel van hul inhoud bevat, gebruik hierdie formule:

=COUNTIF(A2:A10,"*dress*")

Of, tik die verlangde teks in een of ander sel en voeg dit saam t-sel met die jokertekenkarakters:

=COUNTIF(A2:A10,"*"&D1&"*")

Vir meer inligting, sien asseblief: COUNTIF-formules met gedeeltelike passing.

Tel as sel bevat veelvuldige substringe (AND logika)

Om selle met veelvuldige toestande te tel, gebruik die COUNTIFS-funksie. Excel COUNTIFS kan tot 127 reeks/kriteria-pare hanteer, en slegs selle wat aan al die gespesifiseerde voorwaardes voldoen, salgetel.

Om byvoorbeeld uit te vind hoeveel selle in kolom A "rok" EN "blou" bevat, gebruik een van die volgende formules:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Of

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Tel as sel getal bevat

Die formule om selle met getalle te tel is die eenvoudigste formule wat 'n mens jou kan voorstel:

Hou asseblief in gedagte dat die COUNT-funksie in Excel selle tel wat enige numeriese waarde bevat, insluitend getalle, datums en tye, want in terme van Excel is die laaste twee ook getalle.

In ons geval gaan die formule soos volg:

=COUNT(A2:A10)

Om selle te tel wat NIE getalle bevat nie, gebruik die SOMPRODUK-funksie saam met ISNUMMER en NIE:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Som as sel teks bevat

As jy 'n Excel-formule soek om selle te vind wat spesifieke teks bevat en die ooreenstemmende waardes in 'n ander kolom, gebruik die SUMIF-funksie.

Om byvoorbeeld uit te vind hoeveel rokke in voorraad is, gebruik hierdie formule:

=SUMIF(A2:A10,"*dress*",B2:B10)

Waar A2:A10 die teks waardes om te kontroleer en B2:B10 is die getalle om te som.

Of plaas die substring van belang in een of ander sel (E1) en verwys na daardie sel in jou formule, soos in die skermkiekie hieronder getoon:

Om met veelvuldige kriteria op te som , gebruik die SUMIFS-funksie.

Om byvoorbeeld uit te vind hoeveel blou rokke beskikbaar is, gaan met hierdie formule:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Of gebruik diteen:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Waar A2:A10 die selle is om te kontroleer en B2:B10 die selle is om op te som.

Voer uit verskillende berekeninge gebaseer op selwaarde

In ons laaste tutoriaal het ons drie verskillende formules bespreek om veelvuldige toestande te toets en verskillende waardes terug te gee na gelang van die resultate van daardie toetse. En nou, kom ons kyk hoe jy verskillende berekeninge kan uitvoer na gelang van die waarde in 'n teikensel.

Gestel jy het verkoopsnommers in kolom B en wil bonusse bereken op grond van daardie getalle: as 'n verkoop meer as $300 is. , die bonus is 10%; vir verkope tussen $201 en $300 is die bonus 7%; vir verkope tussen $101 en $200 is die bonus 5%, en geen bonus vir minder as $100 verkope nie.

Om dit te laat doen, vermenigvuldig eenvoudig die verkope (B2) met 'n ooreenstemmende persentasie. Hoe weet jy met watter persentasie om te vermenigvuldig? Deur verskillende toestande met geneste IF's te toets:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

In werklike werkblaaie kan dit geriefliker wees om persentasies in aparte selle in te voer en na daardie selle in jou formule te verwys:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Die belangrikste ding is om die bonusselle se verwysings met die $-teken reg te stel om te verhoed dat hulle verander wanneer jy die formule in die kolom af kopieer.

Excel voorwaardelike formatering as sel spesifieke teks bevat

As jy selle met sekere teks wil uitlig , stel 'n Excel voorwaardelike formateringreël op gebaseer op een van die volgendeformules.

Hoofletter-onsensitief:

Hooflettersensitief:

Om byvoorbeeld SKU's uit te lig wat die woorde "rok" bevat, maak 'n voorwaardelike formateringreël met die onderstaande formule en pas dit toe na soveel selle in kolom A as wat jy nodig het, begin met sel A2:

=SEARCH("dress", A2)>0

Excel voorwaardelike formatering formule: as sel teks bevat (veelvuldige voorwaardes)

Om selle uit te lig wat twee of meer teksstringe bevat, nes verskeie Soekfunksies binne 'n EN-formule. Byvoorbeeld, om "blou rok"-selle uit te lig, skep 'n reël gebaseer op hierdie formule:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

Vir die gedetailleerde stappe, sien asseblief Hoe om skep 'n voorwaardelike formateringreël met 'n formule.

As sel sekere teks bevat, verwyder die hele ry

In die geval dat jy rye wat spesifieke teks bevat wil uitvee, gebruik Excel se Soek en Vervang-kenmerk op hierdie manier :

1. Kies alle selle wat jy wil nagaan.
2. Druk Ctrl + F om die Vind en vervang dialoogkassie oop te maak.
3. In die Vind wat -blokkie, tik die teks of nommer waarna jy soek, en klik die Vind alles
4. Klik op enige soekresultaat, en druk dan Ctrl + A om alles te kies.
5. Klik die Sluit -knoppie om die Vind en vervang
6. Druk Ctrl en die minusknoppie gelyktydig ( Ctrl - ), wat die Excel iskortpad vir Delete.
7. In die Delete dialoogkassie, kies Hele ry en klik OK. Klaar!

In die skermkiekie hieronder vee ons rye uit wat "rok" bevat:

As sel bevat, kies of kopieer hele rye

In situasies wanneer jy rye met relevante data wil selekteer of kopieer, gebruik Excel se AutoFilter om sulke rye te filter. Druk daarna Ctrl + A om die gefiltreerde data te kies, Ctrl+C om dit te kopieer, en Ctrl+V om die data na 'n ander plek te plak.

Om selle met twee of meer kriteria te filter, gebruik Gevorderde Filter om sulke selle te vind, en kopieer dan die hele rye met die resultate of onttrek slegs spesifieke kolomme.

Dit is hoe jy selle manipuleer op grond van hul waarde in Excel. Ek bedank jou vir die lees en hoop om jou volgende week op ons blog te sien!

Oefenwerkboek

Excel As Cell Dan bevat - voorbeelde (.xlsx-lêer)