Во нашето претходно упатство, гледавме Excel If содржи формули кои враќаат одредена вредност во друга колона ако целната ќелија содржи дадена вредност. Настрана од тоа, што друго можете да направите ако ќелијата содржи специфичен текст или број? Различни работи како што се броење или сумирање ќелии, истакнување, отстранување или копирање цели редови и друго.

Excel „Count if cell contain“ примери на формула

Во Microsoft Excel, постојат две функции за броење ќелии врз основа на нивните вредности, COUNTIF и COUNTIFS. Овие функции ги покриваат повеќето, иако не сите, сценарија. Примерите подолу ќе ве научат како да изберете соодветно Броење ако ќелијата содржи формула за вашата конкретна задача.

Сметајте ако ќелијата содржи кој било текст

Во ситуации кога сакате да броите ќелии што содржат кој било текст , користете го знакот со ѕвездичка како критериум во формулата COUNTIF:

Или, користете ја функцијата SUMPRODUCT во комбинација со ISTEXT:

Во втората формула, функцијата ISTEXT ја оценува секоја ќелија во наведениот опсег и враќа низа од TRUE (текст) и FALSE (не текст) вредности; двојниот унарен оператор (--) ги принудува ТОЧНО и НЕТОЧНО во 1 и 0; и SUMPRODUCT ги собира броевите.

Како што е прикажано на сликата подолу, двете формули го даваат истиот резултат:

=COUNTIF(A2:A10,"*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Можеби ќе сакате и виепогледнете како да броите непразни ќелии во Excel.

Сметајте ако ќелијата содржи специфичен текст

За да ги броите ќелиите што содржат специфичен текст, користете едноставна формула COUNTIF како што е прикажано подолу, каде што опсег е ќелиите за проверка и текст е текстуалната низа за пребарување или референца до ќелијата што ја содржи текстуалната низа.

На пример, за броење ќелии во опсегот A2:A10 што го содржат зборот „фустан“, користете ја оваа формула:

=COUNTIF(A2:A10, "dress")

Или онаа прикажана на сликата од екранот:

Можете да најдете повеќе примери на формули овде: Како да броите ќелии со текст во Excel: какви било, специфични, филтрирани ќелии.

Брота ако ќелијата содржи текст (делумно совпаѓање)

За да ги броите ќелиите што содржат одредена подниза, користете ја функцијата COUNTIF со знакот за ѕвездичка (*).

На пример, за броење колку ќелии во колоната А содржат „фустан“ како дел од нивната содржина, користете ја оваа формула:

=COUNTIF(A2:A10,"*dress*")

Или, напишете го саканиот текст во некоја ќелија и спојте го t ќелија со знаците за џвакање:

=COUNTIF(A2:A10,"*"&D1&"*")

За повеќе информации, погледнете: COUNTIF формули со делумно совпаѓање.

Сметајте ако ќелијата содржи повеќе поднизи (И логика)

За броење ќелии со повеќе услови, користете ја функцијата COUNTIFS. Excel COUNTIFS може да се справи со до 127 парови опсег/критериум, а само ќелиите што ги исполнуваат сите наведени услови ќе бидатброено.

На пример, за да дознаете колку ќелии во колоната А содржат „фустан“ И „сино“, користете една од следниве формули:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Или

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

брои ако ќелијата содржи број

Формулата за броење ќелии со броеви е наједноставната формула што може да се замисли:

Ве молиме имајте на ум дека функцијата COUNT во Excel брои ќелии што содржат која било нумеричка вредност вклучувајќи броеви, датуми и времиња, бидејќи во однос на Excel последните две се исто така броеви.

Во нашиот случај, формулата оди како што следува:

=COUNT(A2:A10)

За броење ќелии кои НЕ содржат броеви, користете ја функцијата SUMPRODUCT заедно со ISNUMBER и NOT:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Сум ако ќелијата содржи текст

Ако барате формула на Excel за да најдете ќелии што содржат специфичен текст и да ги сумирате соодветните вредности во друга колона, користете ја функцијата SUMIF.

На пример, за да дознаете колку фустани има на залиха, користете ја оваа формула:

=SUMIF(A2:A10,"*dress*",B2:B10)

Каде што се A2:A10 текст вредностите што треба да се проверат и B2:B10 се броевите што треба да се сумираат.

Или, ставете ја поднизата од интерес во некоја ќелија (E1) и упатете ја таа ќелија во вашата формула, како што е прикажано на сликата од екранот подолу:

За сумирање со повеќе критериуми , користете ја функцијата SUMIFS.

На пример, за да дознаете колку сини фустани се достапни, одете со оваа формула:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Или користете го оваеден:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Каде што A2:A10 се ќелиите за проверка и B2:B10 се ќелиите за сумирање.

Изврши различни пресметки врз основа на вредноста на ќелијата

Во нашиот последен туторијал, разговаравме за три различни формули за тестирање на повеќе услови и враќање на различни вредности во зависност од резултатите од тие тестови. И сега, ајде да видиме како можете да извршите различни пресметки во зависност од вредноста во целната ќелија.

Да претпоставиме дека имате продажни броеви во колоната Б и сакате да пресметате бонуси врз основа на тие бројки: ако продажбата е над 300 долари , бонусот е 10%; за продажба помеѓу $201 и $300 бонусот е 7%; за продажба помеѓу 101 и 200 долари бонусот е 5%, а нема бонус за продажба под 100 долари.

За да го направите тоа, едноставно помножете ја продажбата (B2) со соодветен процент. Како да знаете со кој процент да се помножите? Со тестирање на различни услови со вгнездени IF:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

Во работните листови од реалниот живот, можеби е попогодно да внесувате проценти во посебни ќелии и да ги упатувате тие ќелии во вашата формула:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Клучната работа е да ги поправите референците на бонусните ќелии со знакот $ за да ги спречите да се менуваат кога ќе ја копирате формулата во колоната.

Условно форматирање на Excel ако ќелијата содржи специфичен текст

Ако сакате да означите ќелиите со одреден текст, поставете правило за условно форматирање на Excel врз основа на едно од следнивеформули.

Не осетливи на букви:

Чувствителна на букви:

На пример, за да се означат SKU кои ги содржат зборовите "dress", направете условно правило за форматирање со формулата подолу и применете ја до онолку ќелии во колоната А колку што ви треба, почнувајќи со ќелијата A2:

=SEARCH("dress", A2)>0

Формула за условно форматирање на Excel: ако ќелијата содржи текст (повеќе услови)

За да означите ќелии што содржат две или повеќе текстуални низи, вгнездувајте неколку функции за пребарување во формулата И. На пример, за да ги нагласите ќелиите „син фустан“, креирајте правило засновано на оваа формула:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

За деталните чекори, погледнете Како да креирајте правило за условно форматирање со формула.

Ако ќелијата содржи одреден текст, отстранете го целиот ред

Во случај да сакате да избришете редови што содржат специфичен текст, користете ја функцијата Најдете и замени на Excel на овој начин :

1. Изберете ги сите ќелии што сакате да ги проверите.
2. Притиснете Ctrl + F за да го отворите полето за дијалог Најди и замени .
3. Во полето Најди што , напишете го текстот или бројот што го барате и кликнете на Најди ги сите
4. Кликнете на кој било резултат од пребарувањето, а потоа притиснете Ctrl + A за да ги изберете сите.
5. Кликнете на копчето Затвори за да го затворите Најди и замени
6. Притиснете Ctrl и копчето минус истовремено ( Ctrl - ), што е Excelкратенка за Избриши.
7. Во полето за дијалог Избриши , изберете Цел ред и кликнете OK. Готово!

На сликата од екранот подолу, ги бришеме редовите што содржат „dress“:

Ако ќелијата содржи, изберете или копирајте цели редови

Во ситуации кога сакате да изберете или копирате редови со релевантни податоци, користете го Автоматскиот филтер на Excel за да ги филтрирате таквите редови. После тоа, притиснете Ctrl + A за да ги изберете филтрираните податоци, Ctrl+C за да ги копирате и Ctrl+V за да ги залепите податоците на друга локација.

За филтрирање ќелии со два или повеќе критериуми, користете Напреден филтер да пронајдете такви ќелии, а потоа да ги копирате сите редови со резултатите или да извлечете само одредени колони.

Вака манипулирате со ќелиите врз основа на нивната вредност во Excel. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела!

Вежбајте работна книга

Excel If Cell Contains Then - примери (датотека .xlsx)