Մեր նախորդ ձեռնարկում մենք դիտում էինք Excel If-ը, որը պարունակում է բանաձևեր, որոնք որոշակի արժեք են վերադարձնում մեկ այլ սյունակ, եթե թիրախային բջիջը պարունակում է տվյալ արժեք: Բացի դրանից, էլ ի՞նչ կարող եք անել, եթե բջիջը պարունակում է կոնկրետ տեքստ կամ թիվ: Տարբեր բաներ, ինչպիսիք են բջիջների հաշվումը կամ գումարումը, ամբողջ տողերի ընդգծումը, հեռացումը կամ պատճենումը և այլն:

Excel «Հաշվարկեք, եթե բջիջը պարունակում է» բանաձևի օրինակներ

In Microsoft Excel, կան երկու գործառույթ՝ բջիջները հաշվելու համար՝ հիմնված դրանց արժեքների վրա՝ COUNTIF և COUNTIFS: Այս գործառույթներն ընդգրկում են սցենարների մեծ մասը, թեև ոչ բոլորը: Ստորև բերված օրինակները կսովորեցնեն ձեզ, թե ինչպես ընտրել համապատասխան Count, եթե բջիջը պարունակում է բանաձև ձեր կոնկրետ առաջադրանքի համար:

Հաշվե՛ք, եթե բջիջը պարունակում է որևէ տեքստ

Այն իրավիճակներում, երբ ցանկանում եք հաշվել որևէ տեքստ պարունակող բջիջները: , օգտագործեք աստղանիշի նիշը որպես չափանիշ ձեր COUNTIF բանաձևում.

Կամ օգտագործեք SUMPRODUCT ֆունկցիան ISTEXT-ի հետ համատեղ՝

Երկրորդ բանաձեւում ISTEXT ֆունկցիան գնահատում է նշված տիրույթի յուրաքանչյուր բջիջ և վերադարձնում է TRUE (տեքստ) և FALSE (ոչ տեքստ) արժեքների զանգված; Կրկնակի միանման օպերատորը (--) ստիպում է TRUE-ը և FALSE-ը 1-ի և 0-ի մեջ: և SUMPRODUCT-ը գումարում է թվերը:

Ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում, երկու բանաձևերն էլ տալիս են նույն արդյունքը.

=COUNTIF(A2:A10,"*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Դուք նույնպես կարող եք ցանկանալտեսեք, թե ինչպես կարելի է հաշվել ոչ դատարկ բջիջները Excel-ում:

Հաշվե՛ք, եթե բջիջը պարունակում է կոնկրետ տեքստ

Հատուկ տեքստ պարունակող բջիջները հաշվելու համար օգտագործեք պարզ COUNTIF բանաձևը, ինչպես ցույց է տրված ստորև, որտեղ տիրույթը ստուգման ենթակա բջիջներն են, իսկ տեքստը տեքստային տողը, որը պետք է որոնել կամ հղում է դեպի տեքստային տողը պարունակող բջիջը:

Օրինակ, A2:A10 միջակայքում բջիջները հաշվելու համար, որոնք պարունակում են «զգեստ» բառը, օգտագործեք այս բանաձևը.

=COUNTIF(A2:A10, "dress")

Կամ սքրինշոթում ցուցադրվածը.

Դուք կարող եք գտնել ավելի շատ բանաձևերի օրինակներ այստեղ. Ինչպես հաշվել բջիջները տեքստով Excel-ում. ցանկացած, հատուկ, զտված բջիջներ:

Հաշվե՛ք, եթե բջիջը պարունակում է տեքստ (մասնակի համընկնում)

Որոշակի ենթատող պարունակող բջիջները հաշվելու համար օգտագործեք COUNTIF ֆունկցիան աստղանիշի նիշով (*):

Օրինակ՝ հաշվելու համար A սյունակի քանի բջիջ պարունակում է «զգեստ»՝ որպես իրենց բովանդակության մաս, օգտագործեք այս բանաձևը.

=COUNTIF(A2:A10,"*dress*")

Կամ մուտքագրեք ցանկալի տեքստը որոշ բջիջում և միացրեք այն: t բջիջ նիշերով.

=COUNTIF(A2:A10,"*"&D1&"*")

Լրացուցիչ տեղեկությունների համար տե՛ս՝ COUNTIF բանաձևերը մասնակի համընկնումով:

Հաշվի՛ր, եթե բջիջը պարունակում է բազմաթիվ ենթատողեր (ԵՎ տրամաբանություն)

Բազմաթիվ պայմաններով բջիջները հաշվելու համար օգտագործեք COUNTIFS ֆունկցիան: Excel COUNTIFS-ը կարող է մշակել մինչև 127 միջակայք/չափանիշ զույգեր, և միայն բջիջները, որոնք կբավարարեն նշված բոլոր պայմաններին:հաշվել:

Օրինակ, պարզելու համար, թե A սյունակի քանի բջիջ է պարունակում «զգեստ» ԵՎ «կապույտ», օգտագործեք հետևյալ բանաձևերից մեկը.

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Կամ

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Հաշվե՛ք, եթե բջիջը պարունակում է թիվ

Թվերով բջիջները հաշվելու բանաձևը ամենապարզ բանաձևն է, որը կարելի է պատկերացնել.

Խնդրում ենք նկատի ունենալ, որ COUNT ֆունկցիան Excel-ում հաշվում է ցանկացած թվային արժեք պարունակող բջիջներ, ներառյալ թվերը, ամսաթվերը և ժամերը, քանի որ Excel-ի առումով վերջին երկուսը նույնպես թվեր են:

Մեր դեպքում բանաձևը հետևյալն է.

=COUNT(A2:A10)

Թվեր ՉԻ պարունակող բջիջները հաշվելու համար օգտագործեք SUMPRODUCT ֆունկցիան ISNUMBER և NOT-ի հետ միասին.

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Գումարը, եթե բջիջը պարունակում է տեքստ

Եթե փնտրում եք Excel բանաձև՝ որոշակի տեքստ պարունակող բջիջները գտնելու և համապատասխան արժեքները գումարելու համար մեկ այլ սյունակ, օգտագործեք SUMIF ֆունկցիան:

Օրինակ, պարզելու համար, թե քանի զգեստ կա պահեստում, օգտագործեք այս բանաձևը.

=SUMIF(A2:A10,"*dress*",B2:B10)

Որտեղ A2:A10 են տեքստը Ստուգման ենթակա արժեքները և B2:B10 թվերն են, որոնք պետք է գումարվեն:

Կամ, դրեք հետաքրքրության ենթաշարը որոշ բջիջի մեջ (E1) և նշեք այդ բջիջը ձեր բանաձևում, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում.

Բազմաթիվ չափանիշներով գումարելու համար օգտագործեք SUMIFS ֆունկցիան:

Օրինակ, պարզելու համար, թե քանի կապույտ զգեստ կա, գնացեք այս բանաձեւով.

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Կամ օգտագործեք սամեկը՝

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Որտեղ A2:A10-ը ստուգման ենթակա բջիջներն են, իսկ B2:B10-ը` գումարելու բջիջները:

Կատարել տարբեր հաշվարկներ՝ հիմնված բջջի արժեքի վրա

Մեր վերջին ձեռնարկում մենք քննարկեցինք երեք տարբեր բանաձևեր՝ մի քանի պայմաններ փորձարկելու և տարբեր արժեքներ վերադարձնելու համար՝ կախված այդ թեստերի արդյունքներից: Եվ հիմա, եկեք տեսնենք, թե ինչպես կարող եք կատարել տարբեր հաշվարկներ՝ կախված թիրախային բջիջի արժեքից:

Ենթադրենք, որ դուք ունեք վաճառքի համարներ սյունակ B-ում և ցանկանում եք հաշվարկել բոնուսները՝ հիմնվելով այդ թվերի վրա. եթե վաճառքը գերազանցում է $300-ը: , բոնուսը կազմում է 10%; $201-ից մինչև $300 վաճառքի դեպքում բոնուսը կազմում է 7%; $101-ից $200-ի միջև վաճառքի դեպքում բոնուսը կազմում է 5%, և ոչ մի բոնուս 100$-ից ցածր վաճառքի դեպքում:

Այն ավարտելու համար պարզապես բազմապատկեք վաճառքը (B2) համապատասխան տոկոսով: Ինչպե՞ս իմանալ, թե որ տոկոսով բազմապատկել: Փորձարկելով տարբեր պայմաններ ներդրված IF-ներով.

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

Իրական աշխատանքային թերթերում ավելի հարմար կլինի տոկոսներ մուտքագրել առանձին բջիջներում և հղում կատարել այդ բջիջներին ձեր բանաձևում.

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Ամենակարևորը բոնուսային բջիջների հղումներն ամրագրելն է $ նշանով, որպեսզի դրանք չփոխվեն, երբ դուք պատճենում եք բանաձևը սյունակում:

Excel-ի պայմանական ձևաչափում, եթե բջիջը պարունակում է հատուկ տեքստ

Եթե ցանկանում եք ընդգծել բջիջները որոշակի տեքստով, ստեղծեք Excel-ի պայմանական ձևաչափման կանոն՝ հիմնվելով հետևյալներից մեկի վրա:բանաձևեր։

Տառապանին անզգայուն՝

Տառապանին զգայուն.

Օրինակ, նշելու SKU-ները, որոնք պարունակում են "dress" բառերը, ստորև բերված բանաձևով կազմեք պայմանական ձևաչափման կանոն և կիրառեք այն: A սյունակի այնքան բջիջ, որքան անհրաժեշտ է, սկսած A2 բջիջից.

=SEARCH("dress", A2)>0

Excel-ի պայմանական ձևաչափման բանաձև. եթե բջիջը պարունակում է տեքստ (բազմաթիվ պայմաններ)

Երկու կամ ավելի տեքստային տողեր պարունակող բջիջները նշելու համար AND բանաձևի մեջ տեղադրեք որոնման մի քանի գործառույթ: Օրինակ՝ «կապույտ զգեստի» բջիջները ընդգծելու համար ստեղծեք կանոն՝ հիմնվելով այս բանաձևի վրա.

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

Մանրամասն քայլերի համար տե՛ս Ինչպես ստեղծեք պայմանական ձևաչափման կանոն բանաձևով:

Եթե բջիջը պարունակում է որոշակի տեքստ, հեռացրեք ամբողջ տողը

Եթե ցանկանում եք ջնջել որոշակի տեքստ պարունակող տողեր, այս կերպ օգտագործեք Excel-ի «Գտնել և փոխարինել» գործառույթը: :

1. Ընտրեք բոլոր բջիջները, որոնք ցանկանում եք ստուգել:
2. Սեղմեք Ctrl + F՝ Գտնել և փոխարինել երկխոսության տուփը բացելու համար:
3. Մուտքում Գտեք ինչ վանդակը, մուտքագրեք տեքստը կամ համարը, որը փնտրում եք և սեղմեք Գտնել բոլորը
4. Սեղմեք որոնման ցանկացած արդյունքի վրա, այնուհետև սեղմեք Ctrl + A: բոլորն ընտրելու համար:
5. Սեղմեք Փակել կոճակը փակելու համար Գտնել և փոխարինել
6. Սեղմեք Ctrl և մինուս կոճակը միաժամանակ ( Ctrl - ), որը Excel-ն էՋնջել դյուրանցում:
7. Ջնջել երկխոսության վանդակում ընտրեք Ամբողջ տողը և սեղմեք OK: Պատրաստ է:

Սքրինշոթում ներքևում մենք ջնջում ենք «dress» պարունակող տողերը.

Եթե բջիջը պարունակում է, ընտրեք կամ պատճենեք ամբողջ տողերը

Այն իրավիճակներում, երբ ցանկանում եք ընտրել կամ պատճենել համապատասխան տվյալներով տողերը, օգտագործեք Excel-ի AutoFilter-ը՝ նման տողերը զտելու համար: Դրանից հետո սեղմեք Ctrl + A՝ զտված տվյալները ընտրելու համար, Ctrl+C՝ դրանք պատճենելու համար և Ctrl+V՝ տվյալները մեկ այլ վայրում տեղադրելու համար:

Երկու կամ ավելի չափանիշներով բջիջները զտելու համար օգտագործեք Ընդլայնված զտիչը: գտնել այդպիսի բջիջներ, այնուհետև պատճենել ամբողջ տողերը արդյունքներով կամ հանել միայն հատուկ սյունակներ:

Այսպես եք կառավարում բջիջները՝ հիմնվելով Excel-ում դրանց արժեքի վրա: Ես շնորհակալություն եմ հայտնում կարդալու համար և հուսով եմ, որ հաջորդ շաբաթ կտեսնենք ձեզ մեր բլոգում:

Զբաղվեք աշխատանքային գրքույկով

Excel, եթե բջիջը պարունակում է, օրինակներ (.xlsx ֆայլ)