I vår tidigare handledning tittade vi på Excel Om innehåller formler som returnerar ett värde till en annan kolumn om en målcell innehåller ett visst värde. Förutom det, vad kan du göra mer om en cell innehåller specifik text eller ett visst antal? En mängd olika saker som att räkna eller summera celler, markera, ta bort eller kopiera hela rader och mycket mer.

Exempel på Excel-formeln "Räkna om cellen innehåller

I Microsoft Excel finns det två funktioner för att räkna celler baserat på deras värden, COUNTIF och COUNTIFS. Dessa funktioner täcker de flesta, men inte alla, scenarier. I nedanstående exempel får du lära dig hur du väljer en lämplig formel för att räkna om cellen innehåller för just din uppgift.

Räkna om cellen innehåller någon text

I situationer där du vill räkna celler som innehåller text kan du använda jokertecknet asterisk som kriterium i formeln COUNTIF:

Eller använd funktionen SUMPRODUCT i kombination med ISTEXT:

I den andra formeln utvärderar ISTEXT-funktionen varje cell i det angivna intervallet och returnerar en matris med TRUE-värden (text) och FALSE-värden (inte text), den dubbla unära operatorn (--) omvandlar TRUE och FALSE till 1:or och 0:or, och SUMPRODUCT adderar siffrorna.

Som framgår av skärmbilden nedan ger båda formlerna samma resultat:

=COUNTIF(A2:A10, "*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Du kanske också vill titta på hur du räknar icke-tomma celler i Excel.

Räkna om cellen innehåller specifik text

Om du vill räkna celler som innehåller specifik text använder du en enkel COUNTIF-formel som visas nedan, där sortiment är de celler som ska kontrolleras och text är den textsträng som ska sökas eller en referens till cellen som innehåller textsträngen.

Om du till exempel vill räkna celler i intervallet A2:A10 som innehåller ordet "klänning" använder du den här formeln:

=COUNTIF(A2:A10, "klänning")

Eller den som visas i skärmbilden:

Du hittar fler exempel på formler här: Hur du räknar celler med text i Excel: alla, specifika, filtrerade celler.

Räkna om cellen innehåller text (partiell matchning)

Om du vill räkna celler som innehåller en viss delsträng använder du funktionen COUNTIF med jokertecknet asterisk (*).

Om du till exempel vill räkna hur många celler i kolumn A som innehåller "dress" som en del av innehållet använder du den här formeln:

=COUNTIF(A2:A10,"*dress*")

Du kan också skriva den önskade texten i en cell och sammanfoga den cellen med jokertecknen:

=COUNTIF(A2:A10,"*"&D1&"*")

För mer information, se: COUNTIF-formler med partiell matchning.

Räkna om cellen innehåller flera delsträngar (AND-logik)

Om du vill räkna celler med flera villkor använder du funktionen COUNTIFS. Excel COUNTIFS kan hantera upp till 127 intervall/kriteriepar, och endast celler som uppfyller alla angivna villkor räknas.

Om du till exempel vill ta reda på hur många celler i kolumn A som innehåller "klänning" OCH "blå" använder du en av följande formler:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Eller

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Räkna om cellen innehåller ett nummer

Formeln för att räkna celler med siffror är den enklaste formel man kan tänka sig:

Kom ihåg att funktionen COUNT i Excel räknar celler som innehåller alla numeriska värden, inklusive siffror, datum och tider, eftersom de två sistnämnda i Excel också är siffror.

I vårt fall är formeln följande:

=RÄKNING(A2:A10)

Om du vill räkna celler som INTE innehåller siffror använder du funktionen SUMPRODUCT tillsammans med ISNUMBER och NOT:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Summa om cellen innehåller text

Om du letar efter en Excel-formel för att hitta celler som innehåller specifik text och summera motsvarande värden i en annan kolumn, använder du funktionen SUMIF.

För att ta reda på hur många klänningar som finns i lager kan du till exempel använda följande formel:

=SUMIF(A2:A10,"*dress*",B2:B10)

Där A2:A10 är de textvärden som ska kontrolleras och B2:B10 är de siffror som ska summeras.

Du kan också placera den delsträng som du vill ha i en cell (E1) och hänvisa till den cellen i formeln, som visas i skärmdumpen nedan:

Till summa med flera kriterier använder du funktionen SUMIFS.

För att ta reda på hur många blå klänningar som finns tillgängliga kan du till exempel använda följande formel:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Du kan också använda den här:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Där A2:A10 är de celler som ska kontrolleras och B2:B10 är de celler som ska summeras.

Utföra olika beräkningar baserat på cellvärdet

I vår förra handledning diskuterade vi tre olika formler för att testa flera villkor och återge olika värden beroende på resultaten av dessa tester. Nu ska vi se hur du kan utföra olika beräkningar beroende på värdet i en målcell.

Anta att du har försäljningssiffror i kolumn B och vill beräkna bonusar baserat på dessa siffror: om försäljningen överstiger 300 dollar är bonusen 10 %, för försäljning mellan 201 och 300 dollar är bonusen 7 %, för försäljning mellan 101 och 200 dollar är bonusen 5 %, och ingen bonus för försäljning under 100 dollar.

För att få det gjort är det bara att multiplicera försäljningen (B2) med en motsvarande procentsats. Hur vet du vilken procentsats du ska multiplicera med? Genom att testa olika villkor med inbäddade IF:er:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

I riktiga arbetsblad kan det vara bekvämare att ange procenttal i separata celler och hänvisa till dessa celler i formeln:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Det viktigaste är att fixa bonuscellernas referenser med $-tecknet så att de inte ändras när du kopierar formeln ner i kolumnen.

Excel villkorlig formatering om cellen innehåller specifik text

Om du vill markera celler med viss text, skapa en regel för villkorlig formatering i Excel som baseras på en av följande formler.

Det går inte att skilja mellan stora och små bokstäver:

Skiftlägeskänslig:

Om du till exempel vill markera SKU:er som innehåller orden "klänning" skapar du en villkorlig formateringsregel med nedanstående formel och tillämpar den på så många celler i kolumn A som du behöver, med början i cell A2:

=SEARCH("klänning", A2)>0

Excel-formel för villkorlig formatering: om cellen innehåller text (flera villkor)

Om du vill markera celler som innehåller två eller flera textsträngar, kan du kombinera flera sökfunktioner i en AND-formel. Om du till exempel vill markera celler med "blå klänning" skapar du en regel baserad på den här formeln:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

Detaljerade steg finns i Hur man skapar en regel för villkorlig formatering med en formel.

Om cellen innehåller viss text, ta bort hela raden

Om du vill ta bort rader som innehåller specifik text kan du använda Excels funktion Hitta och ersätta på detta sätt:

1. Markera alla celler som du vill kontrollera.
2. Tryck på Ctrl + F för att öppna Hitta och ersätta dialogrutan.
3. I Hitta vad och skriv in den text eller det nummer du letar efter och klicka på knappen Hitta alla
4. Klicka på ett sökresultat och tryck sedan på Ctrl + A för att välja alla.
5. Klicka på Stäng för att stänga Hitta och ersätta
6. Tryck på Ctrl och minusknappen samtidigt ( Ctrl - ), vilket är Excel-genvägen för Delete.
7. I Ta bort dialogrutan, välj Hela raden och klicka på OK. Klart!

I skärmdumpen nedan raderar vi rader som innehåller "dress":

Om cellen innehåller, välj eller kopiera hela rader

Om du vill välja eller kopiera rader med relevanta data använder du Excels AutoFilter för att filtrera sådana rader. Tryck sedan på Ctrl + A för att välja de filtrerade data, Ctrl + C för att kopiera dem och Ctrl + V för att klistra in data på en annan plats.

Om du vill filtrera celler med två eller flera kriterier använder du Avancerat filter för att hitta sådana celler och kopierar sedan hela rader med resultaten eller extraherar endast specifika kolumner.

Så här manipulerar du celler baserat på deras värde i Excel. Tack för att du läste och hoppas att vi ses på vår blogg nästa vecka!

Arbetsbok för övning

Excel Om cellen innehåller - exempel (.xlsx-fil)