У нашому попередньому уроці ми розглядали функцію Excel Якщо, яка містить формули, що повертають деяке значення в інший стовпець, якщо цільова комірка містить задане значення. Крім цього, що ще можна зробити, якщо комірка містить певний текст або число? Різноманітні речі, такі як підрахунок або підсумовування комірок, виділення, видалення або копіювання цілих рядків і багато іншого.

Приклади формул Excel "Обчислити, якщо комірка містить

В Microsoft Excel є дві функції для підрахунку клітинок на основі їх значень, COUNTIF і COUNTIFS. Ці функції охоплюють більшість, хоча і не всі, сценарії. Наведені нижче приклади навчать вас, як вибрати відповідну функцію Count if cell містить формулу для вашої конкретної задачі.

Підрахувати, чи містить комірка текст

У ситуаціях, коли потрібно підрахувати клітинки, що містять будь-який текст, використовуйте символ підстановки зірочки в якості критерію у формулі COUNTIF:

Або використовуйте функцію СУММАРНИЙ ПРОДУКТ у поєднанні з функцією ІСТЕКСТ:

У другій формулі функція ISTEXT обчислює кожну комірку вказаного діапазону і повертає масив значень TRUE (текст) і FALSE (не текст); подвійний унарний оператор (--) перетворює значення TRUE і FALSE в 1 і 0; а SUMPRODUCT підсумовує числа.

Як показано на скріншоті нижче, обидві формули дають однаковий результат:

=COUNTIF(A2:A10, "*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Ви також можете подивитися, як порахувати непорожні клітинки в Excel.

Підрахувати, чи містить комірка певний текст

Для підрахунку комірок, що містять певний текст, використовуйте просту формулу COUNTIF, як показано нижче, де діапазон це клітинки для перевірки та текст текстовий рядок для пошуку або посилання на комірку, що містить текстовий рядок.

Наприклад, для підрахунку комірок діапазону A2:A10, що містять слово "сукня", використовується така формула:

=COUNTIF(A2:A10, "dress")

Або той, що зображений на скріншоті:

Більше прикладів формул можна знайти тут: Як порахувати комірки з текстом в Excel: будь-які, конкретні, відфільтровані комірки.

Вважати, якщо комірка містить текст (частковий збіг)

Для підрахунку комірок, що містять певний підрядок, використовується функція COUNTIF з символом підстановки зірочки (*).

Наприклад, щоб підрахувати, скільки клітинок у стовпчику А містять слово "сукня" як частину свого вмісту, скористайтеся такою формулою:

=COUNTIF(A2:A10,"*dress*")

Або введіть потрібний текст у комірку та об'єднайте цю комірку символами підстановки:

=COUNTIF(A2:A10,"*"&D1&"*")

Для отримання додаткової інформації див.: Формули COUNTIF з частковим збігом.

Підрахунок, якщо комірка містить декілька підрядків (логіка "І")

Для підрахунку клітинок з декількома умовами використовуйте функцію СЧЕТЧИК. Excel СЧЕТЧИК може обробляти до 127 пар діапазонів/критеріїв, і тільки ті клітинки, які задовольняють усім зазначеним умовам, будуть підраховані.

Наприклад, щоб дізнатися, скільки клітинок у стовпчику А містять слова "сукня" І "синій", скористайтеся однією з наступних формул:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Або

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Підрахувати, якщо комірка містить число

Формула для підрахунку клітинок з номерами є найпростішою формулою, яку тільки можна собі уявити:

Будь ласка, майте на увазі, що функція COUNT в Excel підраховує комірки, що містять будь-які числові значення, включаючи числа, дати і час, оскільки з точки зору Excel останні два також є числами.

У нашому випадку формула виглядає наступним чином:

=COUNT(A2:A10)

Для підрахунку комірок, які НЕ містять чисел, використовуйте функцію СУММЕСЛИ разом з функціями ЧИСЛО і НЕ:

=SUMPRODUCT(--NOT(ISUMBER(A2:A10)))

Сума, якщо комірка містить текст

Якщо ви шукаєте формулу Excel для пошуку комірок з певним текстом і підсумовування відповідних значень в іншому стовпчику, скористайтеся функцією СУММЕСЛИ.

Наприклад, щоб дізнатися, скільки суконь є на складі, скористайтеся цією формулою:

=SUMIF(A2:A10,"*dress*",B2:B10)

Де A2:A10 - текстові значення для перевірки, а B2:B10 - числа для підсумовування.

Або помістіть підрядок, який вас цікавить, в якусь комірку (E1) і посилайтеся на цю комірку у своїй формулі, як показано на скріншоті нижче:

До сума з декількома критеріями використовуйте функцію SUMIFS.

Наприклад, щоб дізнатися, скільки синіх суконь є в наявності, скористайтеся цією формулою:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Або скористайтеся цим:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Де A2:A10 - клітинки для перевірки, а B2:B10 - клітинки для підсумовування.

Виконувати різні обчислення на основі значення комірки

У попередньому уроці ми розглянули три різні формули для перевірки декількох умов і повернення різних значень в залежності від результатів цих перевірок. А тепер давайте подивимося, як можна виконувати різні обчислення в залежності від значення в цільовій комірці.

Припустимо, у вас є цифри продажів в колонці B і ви хочете розрахувати бонуси на основі цих цифр: якщо продаж перевищує $300, бонус становить 10%; для продажів від $201 до $300 бонус становить 7%; для продажів від $101 до $200 бонус становить 5%, а для продажів менше $100 бонус не нараховується.

Щоб це зробити, просто помножте продажі (B2) на відповідний відсоток. Як дізнатися, на який відсоток множити? Тестуючи різні умови за допомогою вкладених функцій IF:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

У реальних робочих аркушах може бути зручніше вводити відсотки в окремі клітинки і посилатися на ці клітинки у формулі:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Ключовим моментом є фіксація посилань на бонусні комірки зі знаком $, щоб вони не змінювалися при копіюванні формули вниз по стовпчику.

Умовне форматування Excel, якщо комірка містить певний текст

Якщо ви хочете родзинка клітинок з певним текстом, задайте правило умовного форматування Excel на основі однієї з наведених нижче формул.

Не залежить від регістру:

Делікатна справа:

Наприклад, щоб виділити SKU, які містять слово "сукня", створіть правило умовного форматування з наведеною нижче формулою і застосуйте його до стількох клітинок стовпця А, скільки вам потрібно, починаючи з клітинки А2:

=SEARCH("dress", A2)>0

Формула умовного форматування в Excel: якщо комірка містить текст (кілька умов)

Щоб виділити клітинки, які містять два або більше текстових рядків, вкладіть кілька функцій пошуку у формулу "І". Наприклад, щоб виділити клітинки "синя сукня", створіть правило на основі цієї формули:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

Детальні кроки див. у статті Як створити правило умовного форматування за допомогою формули.

Якщо комірка містить певний текст, видалити весь рядок

Якщо ви хочете видалити рядки, що містять певний текст, скористайтеся функцією "Знайти і замінити" в Excel:

1. Виділіть всі комірки, які ви хочете перевірити.
2. Натисніть Ctrl + F, щоб відкрити вікно Знайти і замінити діалогове вікно.
3. В рамках проекту Знайти що введіть текст або номер, який ви шукаєте, і натисніть кнопку Знайти все
4. Натисніть на будь-який результат пошуку, а потім натисніть Ctrl + A, щоб виділити все.
5. Натисніть на кнопку Закрити кнопку, щоб закрити вікно Знайти і замінити
6. Натисніть клавішу Ctrl і одночасно кнопку мінус ( Ctrl - ), що є комбінацією клавіш Excel для команди Delete (Видалити).
7. В рамках проекту Видалити виберіть у діалоговому вікні Весь ряд і натисніть OK. Готово!

На скріншоті нижче ми видаляємо рядки, що містять слово "dress":

Якщо комірка містить, виділити або скопіювати цілі рядки

У ситуаціях, коли необхідно виділити або скопіювати рядки з відповідними даними, скористайтеся автофільтром Excel для фільтрації таких рядків. Після цього натисніть Ctrl + A, щоб виділити відфільтровані дані, Ctrl+C, щоб скопіювати їх, і Ctrl+V, щоб вставити дані в інше місце.

Щоб відфільтрувати клітинки з двома або більше критеріями, скористайтеся Розширеним фільтром, щоб знайти такі клітинки, а потім скопіюйте всі рядки з результатами або витягніть тільки певні стовпці.

Ось так можна маніпулювати комірками на основі їх значення в Excel. Дякую за прочитання і сподіваюся побачити вас на нашому блозі наступного тижня!

Практичний посібник

Excel Якщо комірка містить Тоді - приклади (файл .xlsx)