V našom predchádzajúcom návode sme sa zaoberali vzorcami programu Excel Ak obsahuje, ktoré vracajú určitú hodnotu do iného stĺpca, ak cieľová bunka obsahuje danú hodnotu. Okrem toho, čo ešte môžete urobiť, ak bunka obsahuje určitý text alebo číslo? Rôzne veci, ako napríklad počítanie alebo sčítanie buniek, zvýrazňovanie, odstraňovanie alebo kopírovanie celých riadkov a ďalšie.

Príklady vzorca Excel 'Count if cell contains'

V programe Microsoft Excel existujú dve funkcie na počítanie buniek na základe ich hodnôt, COUNTIF a COUNTIFS. Tieto funkcie pokrývajú väčšinu scenárov, aj keď nie všetky. V nasledujúcich príkladoch sa dozviete, ako vybrať vhodný vzorec Count if cell contains (Počítať, ak bunka obsahuje) pre vašu konkrétnu úlohu.

Spočítať, či bunka obsahuje nejaký text

V situáciách, keď chcete spočítať bunky obsahujúce akýkoľvek text, použite vo vzorci COUNTIF ako kritérium zástupný znak hviezdička:

Alebo použite funkciu SUMPRODUCT v kombinácii s ISTEXT:

V druhom vzorci funkcia ISTEXT vyhodnotí každú bunku v zadanom rozsahu a vráti pole hodnôt TRUE (text) a FALSE (nie text); dvojitý unárny operátor (--) zmení hodnoty TRUE a FALSE na 1 a 0 a SUMPRODUCT tieto čísla sčíta.

Ako je znázornené na obrázku nižšie, oba vzorce poskytujú rovnaký výsledok:

=COUNTIF(A2:A10, "*")

=SUMPRODUCT(--(ISTEXT(A2:A10))

Možno sa budete chcieť pozrieť aj na spôsob počítania neprázdnych buniek v programe Excel.

Spočítať, či bunka obsahuje konkrétny text

Ak chcete spočítať bunky, ktoré obsahujú určitý text, použite jednoduchý vzorec COUNTIF, ako je znázornené nižšie, kde rozsah sú bunky na kontrolu a text je textový reťazec, ktorý sa má vyhľadať, alebo odkaz na bunku obsahujúcu textový reťazec.

Ak chcete napríklad spočítať bunky v rozsahu A2:A10, ktoré obsahujú slovo "dress", použite tento vzorec:

=COUNTIF(A2:A10, "dress")

Alebo ten, ktorý je zobrazený na snímke:

Ďalšie príklady vzorcov nájdete tu: Ako počítať bunky s textom v programe Excel: ľubovoľné, špecifické, filtrované bunky.

Spočítať, či bunka obsahuje text (čiastočná zhoda)

Ak chcete spočítať bunky, ktoré obsahujú určitý podreťazec, použite funkciu COUNTIF so zástupným znakom hviezdičky (*).

Ak chcete napríklad spočítať, koľko buniek v stĺpci A obsahuje ako súčasť svojho obsahu slovo "šaty", použite tento vzorec:

=COUNTIF(A2:A10,"*dress*")

Alebo zadajte požadovaný text do niektorej bunky a spojte túto bunku so zástupnými znakmi:

=COUNTIF(A2:A10,"*"&D1&"*")

Viac informácií nájdete na stránke: Vzorce COUNTIF s čiastočnou zhodou.

Spočítať, či bunka obsahuje viacero podreťazcov (logika AND)

Ak chcete spočítať bunky s viacerými podmienkami, použite funkciu COUNTIFS. Excel COUNTIFS dokáže spracovať až 127 dvojíc rozsah/kritérium a spočítajú sa len bunky, ktoré spĺňajú všetky zadané podmienky.

Ak chcete napríklad zistiť, koľko buniek v stĺpci A obsahuje "dress" A "blue", použite jeden z nasledujúcich vzorcov:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Alebo

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Spočítajte, či bunka obsahuje číslo

Vzorec na počítanie buniek s číslami je najjednoduchší vzorec, aký si môžete predstaviť:

Nezabudnite, že funkcia COUNT v programe Excel počíta bunky obsahujúce akúkoľvek číselnú hodnotu vrátane čísel, dátumov a časov, pretože posledné dve menované sú z hľadiska programu Excel tiež čísla.

V našom prípade je vzorec nasledovný:

=COUNT(A2:A10)

Ak chcete spočítať bunky, ktoré NEOBSAHUJÚ čísla, použite funkciu SUMPRODUCT spolu s funkciami ISNUMBER a NOT:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10))

Suma, ak bunka obsahuje text

Ak hľadáte vzorec programu Excel na vyhľadanie buniek obsahujúcich určitý text a na sčítanie príslušných hodnôt v inom stĺpci, použite funkciu SUMIF.

Ak chcete napríklad zistiť, koľko šiat je na sklade, použite tento vzorec:

=SUMIF(A2:A10,"*dress*",B2:B10)

Kde A2:A10 sú hodnoty textu, ktoré sa majú skontrolovať, a B2:B10 sú čísla, ktoré sa majú sčítať.

Alebo vložte podreťazec, ktorý vás zaujíma, do niektorej bunky (E1) a odvolajte sa na túto bunku vo vzorci, ako je znázornené na nasledujúcej snímke:

Na súčet s viacerými kritériami , použite funkciu SUMIFS.

Ak chcete napríklad zistiť, koľko modrých šiat je k dispozícii, použite tento vzorec:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Alebo použite tento:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Kde A2:A10 sú bunky na kontrolu a B2:B10 sú bunky na súčet.

Vykonávanie rôznych výpočtov na základe hodnoty bunky

V našom poslednom návode sme prebrali tri rôzne vzorce na testovanie viacerých podmienok a vrátenie rôznych hodnôt v závislosti od výsledkov týchto testov. A teraz sa pozrieme, ako môžete vykonať rôzne výpočty v závislosti od hodnoty v cieľovej bunke.

Predpokladajme, že v stĺpci B máte údaje o predaji a chcete na ich základe vypočítať bonusy: ak je predaj vyšší ako 300 USD, bonus je 10 %; pri predaji od 201 do 300 USD je bonus 7 %; pri predaji od 101 do 200 USD je bonus 5 % a pri predaji pod 100 USD nie je bonus žiadny.

Ak to chcete urobiť, jednoducho vynásobte tržby (B2) príslušným percentom. Ako viete, ktorým percentom násobiť? Testovaním rôznych podmienok pomocou vnorených IF:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

V reálnych pracovných hárkoch môže byť vhodnejšie zadávať percentá do samostatných buniek a odkazovať na tieto bunky vo vzorci:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Kľúčovou vecou je opraviť odkazy na bonusové bunky pomocou znaku $, aby sa zabránilo ich zmene pri kopírovaní vzorca do stĺpca.

Podmienené formátovanie programu Excel, ak bunka obsahuje konkrétny text

Ak chcete zvýraznenie bunky s určitým textom, nastavte pravidlo podmieneného formátovania programu Excel na základe jedného z nasledujúcich vzorcov.

Nezáleží na veľkosti písmen:

Rozlišovanie veľkých a malých písmen:

Ak chcete napríklad zvýrazniť SKU, ktoré obsahujú slová "dress", vytvorte pravidlo podmieneného formátovania s nasledujúcim vzorcom a použite ho na toľko buniek v stĺpci A, koľko potrebujete, počnúc bunkou A2:

=SEARCH("dress", A2)>0

Vzorec podmieneného formátovania programu Excel: ak bunka obsahuje text (viac podmienok)

Ak chcete zvýrazniť bunky, ktoré obsahujú dva alebo viac textových reťazcov, vložte niekoľko funkcií Hľadanie do vzorca AND. Ak chcete napríklad zvýrazniť bunky "modré šaty", vytvorte pravidlo založené na tomto vzorci:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

Podrobný postup nájdete v časti Ako vytvoriť pravidlo podmieneného formátovania pomocou vzorca.

Ak bunka obsahuje určitý text, odstráňte celý riadok

V prípade, že chcete odstrániť riadky obsahujúce konkrétny text, použite týmto spôsobom funkciu programu Excel Nájsť a nahradiť:

1. Vyberte všetky bunky, ktoré chcete skontrolovať.
2. Stlačením klávesovej skratky Ctrl + F otvoríte Nájsť a nahradiť dialógové okno.
3. V Zistite, čo zadajte hľadaný text alebo číslo a kliknite na tlačidlo Nájsť všetko
4. Kliknite na ľubovoľný výsledok vyhľadávania a potom stlačením klávesovej skratky Ctrl + A vyberte všetky.
5. Kliknite na tlačidlo Zatvoriť zatvoriť tlačidlo Nájsť a nahradiť
6. Stlačte súčasne kláves Ctrl a tlačidlo mínus ( Ctrl - ), čo je skratka Excelu pre Delete.
7. V Odstrániť dialógové okno, vyberte Celý riadok a kliknite na tlačidlo OK. Hotovo!

Na nasledujúcom obrázku odstraňujeme riadky obsahujúce slovo "dress":

Ak bunka obsahuje, vyberte alebo skopírujte celé riadky

V situáciách, keď chcete vybrať alebo skopírovať riadky s relevantnými údajmi, použite na filtrovanie takýchto riadkov funkciu AutoFilter programu Excel. Potom stlačte klávesovú skratku Ctrl + A na výber filtrovaných údajov, Ctrl + C na ich skopírovanie a Ctrl + V na vloženie údajov na iné miesto.

Ak chcete filtrovať bunky s dvoma alebo viacerými kritériami, použite Rozšírený filter na vyhľadanie takýchto buniek a potom skopírujte celé riadky s výsledkami alebo vyberte len konkrétne stĺpce.

Takto sa v programe Excel manipuluje s bunkami na základe ich hodnoty. Ďakujem vám za prečítanie a dúfam, že sa na našom blogu uvidíme budúci týždeň!

Cvičný zošit

Excel Ak bunka obsahuje potom - príklady (.xlsx súbor)