在我们之前的教程中，我们正在研究Excel如果包含公式，如果目标单元格包含一个给定的值，就会向另一列返回一些值。 除此之外，如果一个单元格包含特定的文本或数字，你还能做什么？ 各种各样的事情，如计算或求和单元格，突出显示，删除或复制整个行，等等。

Excel中 "如果单元格中包含计数 "公式的例子

在 Microsoft Excel 中，有两个函数可以根据单元格的值进行计数，即 COUNTIF 和 COUNTIFS。 这些函数涵盖了大多数（尽管不是全部）情况。 下面的例子将教你如何为你的特定任务选择合适的计数（如果单元格包含公式）。

计算单元格是否包含任何文本

在你想计算包含任何文本的单元格的情况下，使用星号通配符作为COUNTIF公式的标准。

或者，将SUMPRODUCT函数与ISTEXT结合使用。

在第二个公式中，ISTEXT函数评估指定范围内的每个单元格，并返回一个TRUE（文本）和FALSE（非文本）值的数组；双单数运算符（--）将TRUE和FALSE胁迫成1和0；SUMPRODUCT将这些数字相加。

如下面的截图所示，两个公式的结果是一样的。

=countif(a2:a10, "*")

=sumproduct(--(istext(a2:a10)))

你可能还想看看如何在Excel中计算非空单元格。

计算单元格是否包含特定的文本

要计算包含特定文本的单元格，可使用如下所示的简单COUNTIF公式，其中 范围 是要检查的单元格和 文本 是要搜索的文本字符串或对包含该文本字符串的单元格的引用。

例如，要计算范围A2:A10中包含 "礼服 "一词的单元格，请使用这个公式。

=COUNTIF(A2:A10, "dress")

或者截图中所示的那个。

你可以在这里找到更多的公式例子：如何在Excel中计算带有文本的单元格：任何、特定、过滤的单元格。

计算单元格是否包含文本（部分匹配）。

要计算包含某个子串的单元格，可使用带星号通配符（*）的COUNTIF函数。

例如，要计算A列中有多少单元格的内容中含有 "裙子"，可以使用这个公式。

=COUNTIF(A2:A10,"*dress*")

或者，在某个单元格中输入所需的文本，并将该单元格与通配符连接起来。

=COUNTIF(A2:A10,"*"&D1&"*")

更多信息，请参见：COUNTIF公式与部分匹配。

计算单元格是否包含多个子串（AND逻辑）。

要计算具有多个条件的单元格，请使用COUNTIFS函数。 Excel COUNTIFS可以处理多达127个单元格/标准对，只有满足所有指定条件的单元格才会被计算在内。

例如，要找出A列中有多少单元格包含 "裙子 "和 "蓝色"，请使用以下公式之一。

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

或

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

如果单元格包含数字，则计数

用数字计算单元格的公式是人们可以想象的最简单的公式。

请记住，Excel中的COUNT函数对包含任何数字值的单元格进行计数，包括数字、日期和时间，因为就Excel而言，后两者也是数字。

在我们的案例中，该公式如下。

=COUNT(A2:A10)

要计算不含数字的单元格，请使用SUMPRODUCT函数和ISNUMBER及NOT。

=sumproduct(--not(isnumber(a2:a10)))

如果单元格包含文本，则求和

如果你正在寻找一个Excel公式来寻找包含特定文本的单元格，并将另一列中的相应数值相加，请使用SUMIF函数。

例如，要想知道有多少条裙子的库存，请使用这个公式。

=SUMIF(A2:A10,"*dress*",B2:B10)

其中A2:A10是要检查的文本值，B2:B10是要加的数字。

或者，将感兴趣的子串放在某个单元格（E1）中，并在公式中引用该单元格，如下面的截图所示。

拟 多个标准的总和 ，使用SUMIFS函数。

例如，要想知道有多少件蓝色的衣服，可以用这个公式。

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

或者用这个。

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

其中A2:A10是要检查的单元格，B2:B10是要求和的单元格。

根据单元格值进行不同的计算

在上一篇教程中，我们讨论了三个不同的公式，以测试多个条件，并根据测试结果返回不同的值。 现在，让我们看看如何根据目标单元格中的值进行不同的计算。

假设你在B列有销售数字，并想根据这些数字计算奖金：如果销售超过300美元，奖金为10%；销售在201美元到300美元之间，奖金为7%；销售在101美元到200美元之间，奖金为5%，销售在100美元以下，没有奖金。

要做到这一点，只需将销售额（B2）乘以相应的百分比。 你怎么知道要乘以哪个百分比？ 通过用嵌套的IF测试不同的条件。

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

在现实生活中的工作表中，在单独的单元格中输入百分比并在公式中引用这些单元格可能更方便。

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

最关键的是用$符号固定奖励单元格的引用，以防止在你向下复制公式时它们发生变化。

如果单元格中包含特定的文本，则Excel的条件格式化

如果你想 亮点 如果你想在单元格中加入某些文字，请根据以下公式之一设置Excel条件格式化规则。

不区分大小写。

大小写敏感。

例如，要突出显示含有 "连衣裙 "字样的SKU，用下面的公式制定一个条件格式化规则，并将其应用于A列中从A2单元格开始的所需的多个单元格。

=SEARCH("dress", A2)>0

Excel条件格式化公式：如果单元格中包含文本（多个条件）。

要突出显示包含两个或更多文本字符串的单元格，可以在一个AND公式中嵌套几个搜索函数。 例如，要突出显示 "蓝裙子 "单元格，可以根据这个公式创建一个规则。

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

详细步骤，请看如何用公式创建条件格式化规则。

如果单元格包含某些文本，则删除整个行

如果你想删除包含特定文本的行，可以通过这种方式使用Excel的查找和替换功能。

1. 选择所有你想检查的单元格。
2. 按Ctrl + F打开 查找和替换 对话框。
3. 在 发现什么 框，输入你要找的文本或数字，然后点击 查找所有
4. 点击任何搜索结果，然后按Ctrl + A选择全部。
5. 点击 关闭 按钮来关闭 查找和替换
6. 同时按下Ctrl和减号键（Ctrl - ），这是Excel的删除快捷键。
7. 在 删除 对话框，选择 整行都是 然后点击 "确定"，完成

在下面的截图中，我们正在删除包含 "裙子 "的行。

如果单元格包含，选择或复制整个行

在你想选择或复制有相关数据的行的情况下，使用Excel的自动过滤器来过滤这些行。 之后，按Ctrl+A选择过滤后的数据，按Ctrl+C复制它，按Ctrl+V将数据粘贴到另一个位置。

要用两个或更多的标准来过滤单元格，使用高级过滤器来找到这样的单元格，然后用结果复制整个行，或只提取特定的列。

这就是你如何在Excel中根据单元格的值进行操作。 感谢你的阅读，希望下周在我们的博客上见到你

实践工作手册

Excel If Cell Contains Then - examples (.xlsx file)