Table des matières
Ce tutoriel présente les différentes manières d'utiliser la fonction ISNA dans Excel pour traiter les erreurs #N/A.
Lorsqu'Excel ne trouve pas ce qu'on lui demande, une erreur #N/A apparaît dans une cellule. Pour intercepter et traiter de telles erreurs, vous pouvez utiliser la fonction ISNA. Quelle en est l'utilité pratique ? Essentiellement, elle contribue à rendre vos formules plus conviviales et vos feuilles de calcul plus belles.
Fonction ISNA dans Excel
La fonction Excel ISNA est utilisée pour vérifier la présence d'erreurs #N/A dans les cellules ou les formules. Le résultat est une valeur logique : VRAI si une erreur #N/A est détectée, FAUX sinon.
Cette fonction est disponible dans toutes les versions d'Excel 2000 à 2021 et dans Excel 365.
La syntaxe de la fonction ISNA est aussi simple qu'il est possible de l'être :
ISNA(valeur)Où valeur est la valeur de la cellule ou la formule que vous voulez vérifier pour les erreurs #N/A.
Pour créer une formule ISNA dans sa forme de base, fournissez une référence de cellule comme seul argument :
=ISNA(A2)
Dans le cas où la cellule référencée contient une erreur #N/A, vous obtiendrez TRUE. Dans le cas de toute autre erreur, valeur ou cellule vide, vous obtiendrez FALSE :
Comment utiliser ISNA dans Excel
L'utilisation de la fonction ISNA dans sa forme pure a peu de sens pratique. Le plus souvent, elle est utilisée avec d'autres fonctions pour évaluer le résultat d'une certaine formule. Pour cela, il suffit de placer cette autre formule dans la fonction valeur argument de l'ISNA :
ISNA( votre_formule ())Dans le jeu de données ci-dessous, supposons que vous souhaitiez comparer deux listes (colonnes A et D) et identifier les noms qui sont présents dans les deux listes et ceux qui n'apparaissent que dans la liste 1.
Pour comparer le nom en A3 à chaque nom de la colonne D, la formule est la suivante :
=MATCH(A3, $D$2:$D$9, 0)
Si une valeur de recherche est trouvée, la fonction MATCH renvoie sa position relative dans le tableau de recherche, sinon une erreur #N/A se produit. Pour tester le résultat de MATCH, nous l'imbriquons dans ISNA :
=ISNA(MATCH(A3, $D$2:$D$9, 0))
Cette formule passe en B3, puis est copiée en B14.
Maintenant, vous pouvez clairement voir quels étudiants ont réussi tous les tests (un nom n'est pas disponible dans la colonne D> ; MATCH retourne #N/A> ; ISNA retourne TRUE) et lesquels ont au moins un test échoué (un nom apparaît dans la colonne D> ; pas d'erreur> ; ISNA retourne FALSE).
Conseil : dans Excel 365 et Excel 2021, vous pouvez utiliser la fonction XMATCH, plus moderne, au lieu de MATCH.
Formule IF ISNA dans Excel
Par conception, la fonction ISNA ne peut renvoyer que deux valeurs booléennes. Pour afficher vos messages personnalisés, utilisez-la en combinaison avec la fonction IF :
IF(ISNA(...), " texte_si_erreur ", " texte_si_no_erreur ")En affinant un peu plus notre exemple, nous allons déterminer quels étudiants du groupe A n'ont échoué à aucun test et renvoyer "Aucun test échoué" pour eux. Pour les autres étudiants, nous renverrons "Échoué". Pour ce faire, nous intégrons la formule ISNA MATCH dans le test logique de IF, de sorte que IF devienne la fonction la plus extérieure :
=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "No failed tests", "Failed")
Les résultats semblent bien meilleurs et plus intuitifs maintenant, d'accord ?
Comment utiliser ISNA dans Excel avec VLOOKUP
La combinaison IF ISNA est une solution universelle qui peut être utilisée avec n'importe quelle fonction qui recherche quelque chose dans un ensemble de données et renvoie une erreur #N/A lorsqu'une valeur de recherche n'est pas trouvée.
La syntaxe de la fonction ISNA avec VLOOKUP est la suivante :
IF(ISNA(VLOOKUP(...), " texte personnalisé ", VLOOKUP(...))Traduit en langage humain, il dit : si VLOOKUP résulte en une erreur #N/A, retourner le texte personnalisé, sinon retourner le résultat de VLOOKUP.
Dans notre exemple de tableau, supposons que vous souhaitiez afficher les matières dans lesquelles les étudiants ont échoué aux tests. Pour ceux qui ont passé tous les tests avec succès, "Aucun test échoué" sera affiché.
Pour rechercher les sujets, nous construisons cette formule classique de VLOOKUP :
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
Et ensuite le nicher dans la formule générique IF ISNA discutée ci-dessus :
=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No failed tests", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
Dans Excel 2013 et les versions ultérieures, vous pouvez utiliser la fonction IFNA pour attraper et traiter les erreurs #N/A. Cela rend votre formule plus courte et plus facile à lire.
À titre d'exemple, nous remplaçons les erreurs #N/A par des tirets ("-") et obtenons cette solution élégante :
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")
Les utilisateurs d'Excel 365 et 2021 n'ont pas besoin de fonction wrapper car le successeur moderne de VLOOKUP, la fonction XLOOKUP, peut gérer les erreurs #N/A de manière native :
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")
Le résultat sera exactement le même que celui montré dans la capture d'écran ci-dessus.
Formule ISNA SUMPRODUCT pour compter les erreurs #N/A
Pour compter les erreurs #N/A dans une certaine plage, utilisez la fonction ISNA avec SUMPRODUCT de cette manière :
SUMPRODUCT(--ISNA( gamme ))Ici, ISNA renvoie un tableau de valeurs VRAIES et FAUX, la double négation (--) transforme les valeurs logiques en 1 et 0, et SUMPRODUCT additionne le résultat.
Par exemple, pour savoir combien d'étudiants ont réussi tous les tests, modifiez la formule MATCH pour une plage de valeurs de consultation (A3:A14) et immergez-la dans ISNA :
=SUMPRODUCT(--ISNA(MATCH(A3:A14, D2:D9, 0)))
La formule détermine que 9 étudiants n'ont pas échoué aux tests, c'est-à-dire que la fonction MATCH renvoie 9 erreurs #N/A :
Voilà comment créer et utiliser les formules ISNA dans Excel. Je vous remercie de votre lecture et j'ai hâte de vous retrouver sur notre blog la semaine prochaine !
Téléchargements disponibles
Exemples de formules ISNA (fichier .xlsx)
