"Concatenate" zwykle oznacza łączenie czegoś w serię lub łańcuch. Ta operacja jest używana zawsze, gdy trzeba połączyć tekst z wielu komórek Google Sheets. Ten artykuł zbiera najpopularniejsze i najłatwiejsze rozwiązania, które pomogą Ci rozwiązać zagadkę konkatenacji.

Niezależnie od tego, jak duży jest Twój zbiór danych, możesz natknąć się na zadanie połączenia wielu komórek w Google Sheets razem. I nie mam wątpliwości, że będziesz chciał nie tylko zachować wszystkie wartości od utraty, ale także dodać kilka przecinków, spacji lub innych znaków, a nawet oddzielić te rekordy innym tekstem.

Cóż, arkusze kalkulacyjne oferują kilka narzędzi do tego zadania.

Arkusze Google Funkcja CONCAT

Funkcja CONCAT jest uproszczoną wersją Google Sheets CONCATENATE:

Aby połączyć komórki za pomocą tej funkcji, musisz wymienić wymagane wartości:

• wartość1 - rekord, do którego ma być dołączona wartość2.
• wartość2 - wartość do połączenia.

Aby uzyskać jeden ciąg z 2 jednostek tekstowych lub numerycznych, formuła będzie wyglądać jak poniżej, z każdym rekordem w podwójnych cudzysłowach:

=CONCAT("2019:", "The Lion King")

W rzeczywistości twoje dane najprawdopodobniej są już w komórkach. Możesz odwoływać się do tych komórek bezpośrednio, zamiast odkładać każdą liczbę lub tekst jako argument. Więc formuła z prawdziwymi danymi będzie wyglądać tak:

=CONCAT(A2,B2)

Wskazówka. Aby skopiować formułę do całej kolumny, zaznacz komórkę z formułą i kliknij dwukrotnie mały kwadrat w prawym dolnym rogu komórki. Cała kolumna zostanie automatycznie wypełniona formułą, aż do samego końca tabeli.

Jak widać, funkcja jest super prosta, ale ma duże znaczenie słabe punkty :

• łączy tylko dwie komórki w Google Sheets w tym samym czasie.
• nie może łączyć kolumn, wierszy lub innych dużych zakresów danych, przyjmuje tylko pojedyncze komórki. Jeśli spróbujesz dołączyć do wielu komórek, otrzymasz błąd lub tylko dwie pierwsze wartości zostaną połączone, tak jak to:

  =CONCAT(A2:A11,B2:B11)

  

CONCAT alternatywa: operator konkatenacji ampersand (&)

W formułach istnieje wiele różnych operatorów służących do różnych celów. Konkatenacja nie jest wyjątkiem. Użycie znaku ampersand (&) w formułach zamiast funkcji CONCAT da ten sam rezultat:

=A2&B2

Ale mało kto wie, że ten operator konkatenacji jest bardziej elastyczny, oto co może zrobić:

1. Połącz więcej niż dwie wartości jednocześnie:

   =A2&B2&C2

   

2. Nie tylko łączenie komórek w Google Sheets, ale także rozdzielanie ich różnymi znakami:

   =A2&" "&B2&" "&C2

   

Jeśli nadal nie uzyskasz pożądanego rezultatu za pomocą tych opcji, jest jeszcze jedna funkcja do wypróbowania.

Jak używać CONCATENATE w Arkuszach Google

Uważam, że funkcja Google Sheets CONCATENATE jest pierwszą, z której należy korzystać, jeśli chodzi o dołączanie kilku rekordów razem.

CONCATENATE ciągów tekstowych i liczb w Arkuszach Google

Wzorzec formuły składa się z następujących argumentów:

• ciąg1 jest pierwszym łańcuchem, do którego chcesz dołączyć inne wartości. Ten argument jest wymagany.
• string2, ... oznacza wszystkie inne łańcuchy, które chcesz dołączyć. Ten argument jest opcjonalny.

Uwaga. Zapis wyniku będzie składał się z ciągów w kolejności ich występowania w formule.

Jeśli dostosuję wzór do moich danych, otrzymam to:

=CONCATENATE(A2,B2,C2)

Lub, ponieważ funkcja akceptuje zakresy:

=CONCATENATE(A2:D2)

Od razu można zauważyć pierwszą zaletę Google Sheets CONCATENATE: łatwo łączy ponad dwie komórki zawierające zarówno tekst, jak i liczby.

Arkusze Google: konkatenacja ciągów znaków z separatorami

Łączenie komórek w Google Sheets to połowa roboty. Ale żeby wynik wyglądał ładnie i był czytelny, należy dodać kilka dodatkowych znaków.

Jeśli zachowasz formułę taką, jaka jest, to po prostu sklei wszystko razem: BonnieJacksonCA , BonnieJacksonIN , itd. Ale Google Sheets CONCATENATE przyjmuje również znaki jako argumenty.

Tak więc, aby dodać niektóre separatory dla czytelności, wymień je w podwójnych cudzysłowach w formule:

=CONCATENATE(A2," ",B2,", ",C2)

Tutaj chcę konkatenować A2 & B2 ze spacją i oddzielić B2 od C2 z przecinkiem i spacją:

Możesz swobodnie używać prawie dowolnego znaku w funkcji w ten sposób, jednak przerwanie linii wymaga innego podejścia.

Wskazówka. w przypadku, gdy w niektórych kolumnach, które scalasz, są puste komórki, jest jeszcze jedna funkcja, którą możesz być zainteresowany. TEXTJOIN nie tylko łączy komórki w Google Sheets, ale ignoruje puste miejsca:

=TEXTJOIN(" ",TRUE,A2:C2)

Oto jak to działa:

1. Jako pierwszy argument wskaż pożądany delimiter -. przestrzeń (" ") dla mnie.
2. Umieść TRUE jako drugi argument, aby pominąć puste komórki lub FALSE aby uwzględnić je w wyniku.
3. Wprowadzić zakres, który ma zostać połączony.

Konkatenacja z przerwaniem linii w Arkuszach Google

O ile oczywiste jest, jak wprowadzić większość delimitatorów do funkcji, o tyle nie można tam wpisać łamania linii w ten sam sposób. Ale na szczęście Google pozwala grać wieloma różnymi kartami.

Istnieje funkcja, która pomaga uzyskać znaki specjalne - nazywa się CHAR. Widzisz, każdy znak ma swoje miejsce w tabeli Unicode. Wystarczy podać numer porządkowy znaku z tej tabeli do funkcji, a ta zwróci sam znak.

Oto wzór, aby uzyskać przerwę w linii:

=CHAR(10)

Dodaj go do formuły, aby konkatenować z przerwą w linii w Google Sheets:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

Łączenie daty i godziny w arkuszach Google

Jeśli spróbujesz połączyć datę i godzinę w Google Sheets za pomocą jednej z powyższych metod, to nie zadziała. Twój arkusz kalkulacyjny zwróci liczby:

Aby poprawnie połączyć datę i godzinę w Google Sheets, należy użyć funkcji TEKST:

• gdzie numer jest dowolną liczbą, datą lub godziną, którą chcesz uzyskać w pożądanym formacie
• oraz format to wzór, który chciałbyś zobaczyć jako wynik.

Wskazówka. W moim przykładzie będę odwoływał się do komórek z datami i godzinami, ale możesz swobodnie używać jednostek daty/czasu, a nawet takich funkcji jak DATE czy TIME bezpośrednio w formule.

1. Używam pierwszej formuły TEXT, aby zmienić format daty z 7/9/2019 do 9 lipca 2019 r. :

   =TEXT(B2, "D MMM RRRR")

2. Drugi TEKST zwraca godzinę:

   =TEXT(C2, "HH:MM:SS")

   Zobacz też: Sumy częściowe w Excelu: jak wstawiać, używać i usuwać
3. Używając ich w CONCATENATE, Google Sheets pozwala mi połączyć datę i godzinę w żądanym formacie z innymi znakami lub tekstem:

   =CONCATENATE(TEXT(B2, "D MMM YYY"),", ",TEXT(C2, "HH:MM:SS"))

Łączenie kolumn w arkuszach Google

Z niewielkimi poprawkami, wszystkie wymienione przeze mnie sposoby są w stanie scalić kolumny w Google Sheets.

Przykład 1. Google Sheets CONCAT

Aby połączyć całe kolumny w Google Sheets za pomocą CONCAT, wybierz cały zakres, który powinien zawierać wynik (C2:C11 w moim przypadku) i wprowadź swoją formułę zawijającą ją w ARRAYFORMULA:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

Uwaga. Mogłeś użyć funkcji CONCATENATE, ale połączy ona wszystkie rekordy w obrębie jednej komórki, ponieważ łatwo łączy wiele komórek i zakresów danych.

Przykład 2. Operator konkatenacji

Tworzenie formuł tablicowych do łączenia kolumn w Google Sheets za pomocą ampersanda i jednoczesnego dodawania separatorów:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

Wygląda to dobrze, ale muszę wskazać kilka poważnych minusów.

Jeśli masz zbyt wiele kolumn, wyliczanie ich wszystkich może stać się bólem w szyi, zwłaszcza jeśli przypadkowo pominiesz / powielisz / wymieszasz dowolne znaki.

Ponadto, jeśli zdecydujesz się dodać więcej kolumn do formuły później, będziesz musiał ręcznie edytować każdy istniejący zakres w formule.

Następny przykład rozwiązuje te problemy.

Przykład 3. zapytanie do arkusza Google

Funkcja Google Sheets QUERY nadaje się również do łączenia kilku kolumn w Google Sheets, spójrz:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

Możesz myśleć, że ta dziwna formuła jest poza twoim zasięgiem, ale pozwól mi położyć jego wszystkie kawałki dla ciebie:

1. =TRANSPOSE(A2:D10) zamienia wiersze danych na kolumny.
2. =QUERY(TRANSPOSE(A2:D10),,9^9) łączy rekordy w każdej kolumnie do górnych komórek.

   Wskazówka. Kiedy umieszczam 9^9 do formuły, upewniam się, że wszystkie wiersze ze wszystkich kolumn zostaną wciągnięte do pierwszego wiersza, tak jakby były nagłówkami.Jest to 9^9 ponieważ to wyrażenie obejmuje wszystkie możliwe komórki w arkuszu kalkulacyjnym (pamiętasz limit dla 10M komórek?) i jest łatwe do zapamiętania :)

3. =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9)) bierze ten wiersz nagłówka z QUERY i zamienia go w kolumnę taką, jaką mam.

Oto atuty scalania kolumn w Google Sheets za pomocą QUERY:

• nie trzeba zaznaczać całej kolumny, jak to ma miejsce w przypadku formuł tablicowych
• nie musisz wymieniać każdej kolumny w formule, chyba że nie są one sąsiadujące. W tym przypadku, oto jak będzie wyglądać formuła:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

Konkatenacja i dodawanie tekstu według pozycji

Wiesz już, że możesz dodawać do swoich łańcuchów brakujący tekst, liczby i znaki za pomocą funkcji CONCATENATE.

Wskazówka. zobacz więcej formuł na ten temat w tym tutorialu.

Ale jeśli istnieje zbyt wiele rekordów do połączenia, wszelkie dodatkowe znaki mogą rozszerzyć twoją formułę znacznie poza to, co zaplanowałeś. W przypadkach takich jak ten, lepiej jest scalić komórki w Arkuszach Google tak jak są lub użyć prostych delimitatorów, takich jak spacja i dodać tekst po tym. Pomoże ci w tym specjalne narzędzie naszego autorstwa.

Dodaj tekst według pozycji wstawia dowolne znaki i ciągi znaków według pozycji, którą określisz, nie są potrzebne żadne formuły. Pozwól, że pokażę Ci jak to działa.

W poprzednim przykładzie QUERY połączył dla mnie nazwiska i numery telefonów, ale chciałbym dodać skróty krajów: (USA/CA) przed numerami telefonów, które zaczynają się od +1 oraz UK przed +44 :

Dzielenie komórek w arkuszach Google

Jeśli łączysz komórki w Google Sheets, są szanse, że w pewnym momencie będziesz musiał podzielić je z powrotem. Istnieją trzy sposoby, aby to zrobić:

1. Zbudowanie formuły z wykorzystaniem funkcji SPLIT z Google Sheets.
2. Wykorzystaj standardowe narzędzie arkusza kalkulacyjnego - Podziel tekst na kolumny.
3. Albo wypróbuj ulepszoną wersję wbudowanego narzędzia - Podziel tekst na kolumny dla Google Sheets:

Pozwala podzielić komórki według dowolnego delimitera lub nawet zestawów separatorów, traktując je jako jeden i włączając spójniki w razie potrzeby. Oferuje również opcję dzielenia komórek w Google Sheets według pozycji.

Wskazówka. Istnieje opcja wyodrębnienia danych z komórek Google Sheets zamiast dzielenia ich zawartości.

Jak scalić komórki w Arkuszach Google bez formuł

Jeśli opanowanie różnych formuł nie jest częścią twojego planu, skorzystasz z naszego dodatku Merge Values. Dodatek ten szybko łączy rekordy w wierszach, kolumnach lub całym zakresie komórek. Jego opcje są krystalicznie czyste, a wszystko, co masz zrobić, to wybrać zakres i zdecydować, jak powinien wyglądać wynik.

1. Możesz wybrać łączyć kolumny w Google Sheets - nawet nie sąsiadujące ze sobą, oddziel je przecinkami i spacjami, a wynik umieść po prawej stronie oryginalnych rekordów:

Jeśli zainteresowało Cię to narzędzie, możesz przejrzeć wszystko, co robi na tej specjalnej stronie lub w tym krótkim tutorialu wideo:

Dowiedz się, jak używać Combine Duplicate Rows w tym filmie:

Mam nadzieję, że do tej pory zdecydowaliście już, który ze sposobów najbardziej pasuje do Waszego przypadku. Jeśli macie na myśli jakieś inne metody, podzielcie się z nami w sekcji komentarzy poniżej :)