Spis treści
Ten samouczek zagłębia się w różne sposoby wykorzystania funkcji ISNA w Excelu do obsługi błędów #N/A.
Kiedy Excel nie może znaleźć tego, o co jest pytany, w komórce pojawia się błąd #N/A. Aby przechwycić i obsłużyć takie błędy, możesz użyć funkcji ISNA. Jakie jest jej praktyczne zastosowanie? Zasadniczo pomaga uczynić Twoje formuły bardziej przyjaznymi dla użytkownika, a arkusze lepiej wyglądającymi.
Funkcja ISNA w programie Excel
Funkcja Excel ISNA służy do sprawdzania komórek lub formuł pod kątem błędów #N/A. Wynikiem jest wartość logiczna: TRUE w przypadku wykrycia błędu #N/A, FALSE w przeciwnym wypadku.
Funkcja jest dostępna we wszystkich wersjach Excela od 2000 do 2021 oraz w Excelu 365.
Składnia funkcji ISNA jest tak prosta, jak tylko może być:
ISNA(wartość)Gdzie wartość to wartość komórki lub formuły, którą chcesz sprawdzić pod kątem błędów #N/A.
Aby utworzyć formułę ISNA w jej podstawowej postaci, należy dostarczyć odwołanie do komórki jako jej jedyny argument:
=ISNA(A2)
W przypadku, gdy komórka, do której się odwołujemy, zawiera błąd #N/A, otrzymamy TRUE. W przypadku jakiegokolwiek innego błędu, wartości lub pustej komórki otrzymamy FALSE:
Jak korzystać z ISNA w programie Excel
Używanie funkcji ISNA w czystej postaci ma niewielki sens praktyczny. Częściej używa się jej wraz z innymi funkcjami do oceny wyniku pewnej formuły. W tym celu wystarczy umieścić tę inną formułę w polu wartość argument ISNA:
W poniższym zbiorze danych załóżmy, że chcesz porównać dwie listy (kolumny A i D) i zidentyfikować nazwiska, które występują na obu listach oraz te, które pojawiają się tylko na liście 1.
Aby porównać nazwę w A3 z każdą nazwą w kolumnie D, wzór to:
=MATCH(A3, $D$2:$D$9, 0)
W przypadku znalezienia wartości lookup, funkcja MATCH zwraca jej względną pozycję w tablicy lookup, w przeciwnym razie pojawia się błąd #N/A. Aby przetestować wynik działania MATCH, zagnieżdżamy ją w ISNA:
=ISNA(MATCH(A3, $D$2:$D$9, 0))
Wzór ten trafia do B3, a następnie jest kopiowany przez B14.
Teraz widać wyraźnie, którzy uczniowie zaliczyli wszystkie testy (w kolumnie D> nie ma nazwiska; MATCH zwraca #N/A> ISNA zwraca TRUE), a którzy mają przynajmniej jeden nieudany test (w kolumnie D> pojawia się nazwisko; brak błędu> ISNA zwraca FALSE).
Wskazówka. W Excelu 365 i Excelu 2021 zamiast funkcji MATCH można użyć nowocześniejszej funkcji XMATCH.
Formuła IF ISNA w programie Excel
Z założenia funkcja ISNA może zwrócić tylko dwie wartości logiczne. Aby wyświetlić niestandardowe komunikaty, użyj jej w połączeniu z funkcją IF:
IF(ISNA(...), " text_if_error ", " text_if_no_error ")Doprecyzowując nieco nasz przykład, dowiedzmy się, którzy studenci z grupy A nie oblali żadnego testu i zwróćmy dla nich "No failed tests". Dla pozostałych studentów zwrócimy "Failed". Aby to zrobić, osadzamy formułę ISNA MATCH w teście logicznym IF, tak że IF staje się funkcją zewnętrzną:
=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "No failed tests", "Failed")
Wyniki wyglądają teraz znacznie lepiej i bardziej intuicyjnie, zgadzasz się?
Jak używać ISNA w Excelu za pomocą VLOOKUP
Kombinacja IF ISNA jest uniwersalnym rozwiązaniem, które może być stosowane z każdą funkcją, która szuka czegoś w zestawie danych i zwraca błąd #N/A, gdy wartość lookup nie zostanie znaleziona.
Składnia funkcji ISNA z VLOOKUP jest następująca:
IF(ISNA(VLOOKUP(...), " niestandardowy_tekst ", VLOOKUP(...))Przetłumaczone na ludzki język, mówi: jeśli VLOOKUP skutkuje błędem #N/A, zwróć tekst niestandardowy, w przeciwnym razie zwróć wynik VLOOKUP.
W naszej przykładowej tabeli załóżmy, że chcesz zwrócić przedmioty, z których studenci nie zaliczyli testów. Dla tych, którzy zaliczyli wszystkie testy z sukcesem, zostanie wyświetlony komunikat "Brak nieudanych testów".
Aby wyszukać podmioty, konstruujemy taką klasyczną formułę VLOOKUP:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
A następnie zagnieździć ją w omówionej powyżej ogólnej formule IF ISNA:
=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Brak nieudanych testów", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
W programie Excel 2013 i nowszych wersjach możesz wykorzystać funkcję IFNA do wyłapywania i obsługi błędów #N/A. Dzięki temu Twoja formuła będzie krótsza i łatwiejsza do odczytania.
Jako przykład, zastępujemy błędy #N/A kreskami ("-") i otrzymujemy to eleganckie rozwiązanie:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")
Użytkownicy Excela 365 i 2021 nie potrzebują w ogóle żadnej funkcji wrappera, ponieważ nowoczesny następca VLOOKUP, funkcja XLOOKUP, potrafi natywnie obsługiwać błędy #N/A:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")
Wynik będzie dokładnie taki sam, jak pokazano na powyższym zrzucie ekranu.
SUMPRODUCT ISNA wzór do liczenia błędów #N/A
Aby policzyć błędy #N/A w pewnym przedziale, należy użyć funkcji ISNA wraz z SUMPRODUCT w ten sposób:
SUMPRODUKT(--ISNA( zakres ))Tutaj ISNA zwraca tablicę wartości TRUE i FALSE, podwójna negacja (--) zamienia wartości logiczne na 1 i 0, a SUMPRODUCT sumuje wynik.
Na przykład, aby dowiedzieć się, ilu studentów odniosło sukces we wszystkich testach, należy zmodyfikować formułę MATCH dla zakresu wartości lookup (A3:A14) i zagnieździć ją w ISNA:
=SUMPRODUKT(--ISNA(MATCH(A3:A14, D2:D9, 0))
Formuła określa, że 9 studentów nie ma niezaliczonych testów, czyli funkcja MATCH zwraca 9 błędów #N/A:
Oto jak tworzyć i używać formuł ISNA w Excelu. Dziękuję za lekturę i czekam na Ciebie na naszym blogu za tydzień!
Dostępne pliki do pobrania
Przykłady formuł ISNA (plik .xlsx)
