I den forrige opplæringen vår så vi på Excel If inneholder formler som returnerer en verdi til en annen kolonne hvis en målcelle inneholder en gitt verdi. Bortsett fra det, hva annet kan du gjøre hvis en celle inneholder spesifikk tekst eller tall? En rekke ting som å telle eller summere celler, utheve, fjerne eller kopiere hele rader og mer.

Excel 'Tell hvis cellen inneholder' formeleksempler

I Microsoft Excel, det er to funksjoner for å telle celler basert på verdiene deres, COUNTIF og COUNTIFS. Disse funksjonene dekker de fleste, men ikke alle, scenarier. Eksemplene nedenfor vil lære deg hvordan du velger en passende telling hvis celle inneholder formel for din spesifikke oppgave.

Tell hvis cellen inneholder tekst

I situasjoner når du ønsker å telle celler som inneholder hvilken som helst tekst , bruk stjerne-jokertegnet som kriteriet i COUNTIF-formelen:

Eller bruk SUMPRODUCT-funksjonen i kombinasjon med ISTEXT:

I den andre formelen evaluerer ISTEXT-funksjonen hver celle i det angitte området og returnerer en matrise med TRUE (tekst) og FALSE (ikke tekst) verdier; den doble unære operatoren (--) tvinger SANN og USANN til 1-er og 0-er; og SUMPRODUCT legger sammen tallene.

Som vist på skjermbildet nedenfor, gir begge formlene det samme resultatet:

=COUNTIF(A2:A10,"*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Du vil kanskje ogsåse på hvordan du teller ikke-tomme celler i Excel.

Tell hvis cellen inneholder spesifikk tekst

For å telle celler som inneholder spesifikk tekst, bruk en enkel COUNTIF-formel som vist nedenfor, hvor område er cellene som skal sjekkes og tekst er tekststrengen det skal søkes etter eller en referanse til cellen som inneholder tekststrengen.

For for eksempel å telle celler i området A2:A10 som inneholder ordet "kjole", bruk denne formelen:

=COUNTIF(A2:A10, "dress")

Eller den som vises på skjermbildet:

Du kan finne flere formlereksempler her: Hvordan telle celler med tekst i Excel: alle spesifikke, filtrerte celler.

Tell hvis cellen inneholder tekst (delvis samsvar)

For å telle celler som inneholder en bestemt delstreng, bruk COUNTIF-funksjonen med jokertegnet (*).

For å telle for eksempel hvor mange celler i kolonne A inneholder "kjole" som en del av innholdet, bruk denne formelen:

=COUNTIF(A2:A10,"*dress*")

Eller skriv inn ønsket tekst i en celle og sett sammen t-celle med jokertegn:

=COUNTIF(A2:A10,"*"&D1&"*")

For mer informasjon, se: COUNTIF-formler med delvis samsvar.

Tell hvis celle inneholder flere understrenger (AND logic)

For å telle celler med flere betingelser, bruk COUNTIFS-funksjonen. Excel COUNTIFS kan håndtere opptil 127 rekkevidde/kriteriepar, og bare celler som oppfyller alle de spesifiserte betingelsene vil blitelles.

For å finne ut hvor mange celler i kolonne A som inneholder «kjole» OG «blå», bruk en av følgende formler:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Eller

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Tell hvis cellen inneholder tall

Formelen for å telle celler med tall er den enkleste formelen man kan tenke seg:

Husk at COUNT-funksjonen i Excel teller celler som inneholder en hvilken som helst numerisk verdi, inkludert tall, datoer og klokkeslett, fordi i Excel er de to siste også tall.

I vårt tilfelle går formelen som følger:

=COUNT(A2:A10)

For å telle celler som IKKE inneholder tall, bruk SUMPRODUKT-funksjonen sammen med ISNUMBER og NOT:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Summer hvis celle inneholder tekst

Hvis du leter etter en Excel-formel for å finne celler som inneholder spesifikk tekst og summere de tilsvarende verdiene i en annen kolonne, bruk SUMIF-funksjonen.

For å finne ut hvor mange kjoler som er på lager, bruk denne formelen:

=SUMIF(A2:A10,"*dress*",B2:B10)

Hvor A2:A10 er tekst verdier som skal sjekkes og B2:B10 er tallene som skal summeres.

Eller plasser understrengen av interesse i en celle (E1), og referer til den cellen i formelen din, som vist på skjermbildet nedenfor:

For å summere med flere kriterier , bruk SUMIFS-funksjonen.

For å finne ut hvor mange blå kjoler som er tilgjengelige, gå for eksempel med denne formelen:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Eller bruk denneen:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Hvor A2:A10 er cellene som skal kontrolleres og B2:B10 er cellene som skal summeres.

Utfør forskjellige beregninger basert på celleverdi

I vår siste veiledning diskuterte vi tre forskjellige formler for å teste flere forhold og returnere forskjellige verdier avhengig av resultatene av disse testene. Og nå, la oss se hvordan du kan utføre forskjellige beregninger avhengig av verdien i en målcelle.

Anta at du har salgstall i kolonne B og ønsker å beregne bonuser basert på disse tallene: hvis et salg er over $300 , bonusen er 10%; for salg mellom $201 og $300 er bonusen 7%; for salg mellom $101 og $200 er bonusen 5 %, og ingen bonus for salg under $100.

For å få det gjort, multipliser bare salget (B2) med en tilsvarende prosentandel. Hvordan vet du hvilken prosent du skal gange med? Ved å teste forskjellige forhold med nestede IF-er:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

I virkelige regneark kan det være mer praktisk å legge inn prosenter i separate celler og referere til disse cellene i formelen din:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Nøkkelen er å fikse bonuscellenes referanser med $-tegnet for å forhindre at de endres når du kopierer formelen nedover kolonnen.

Excel betinget formatering hvis celle inneholder spesifikk tekst

Hvis du vil utheve celler med bestemt tekst, sett opp en Excel betinget formateringsregel basert på ett av følgendeformler.

Skiller ikke mellom store og små bokstaver:

Skiller mellom store og små bokstaver:

For å fremheve SKU-er som inneholder ordene "dress", lag en betinget formateringsregel med formelen nedenfor og bruk den til så mange celler i kolonne A som du trenger begynner med celle A2:

=SEARCH("dress", A2)>0

Excel betinget formateringsformel: hvis cellen inneholder tekst (flere betingelser)

For å fremheve celler som inneholder to eller flere tekststrenger, kan du legge inn flere søkefunksjoner i en OG-formel. For å fremheve "blå kjole"-celler, lag for eksempel en regel basert på denne formelen:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

For detaljerte trinn, se Hvordan lag en betinget formateringsregel med en formel.

Hvis cellen inneholder bestemt tekst, fjern hele raden

Hvis du ønsker å slette rader som inneholder spesifikk tekst, bruk Excels Finn og erstatt-funksjon på denne måten :

1. Velg alle cellene du vil sjekke.
2. Trykk Ctrl + F for å åpne dialogboksen Finn og erstatt .
3. I boksen Finn hva , skriv inn teksten eller nummeret du leter etter, og klikk Finn alle
4. Klikk på et søkeresultat, og trykk deretter Ctrl + A for å velge alle.
5. Klikk Lukk -knappen for å lukke Finn og erstatt
6. Trykk på Ctrl og minusknappen samtidig ( Ctrl - ), som er Excelsnarvei for Slett.
7. I dialogboksen Slett velger du Hele rad og klikker OK. Ferdig!

I skjermbildet nedenfor sletter vi rader som inneholder "kjole":

Hvis cellen inneholder, velg eller kopier hele rader

I situasjoner der du ønsker å velge eller kopiere rader med relevante data, bruk Excels AutoFilter for å filtrere slike rader. Deretter trykker du på Ctrl + A for å velge de filtrerte dataene, Ctrl+C for å kopiere dem, og Ctrl+V for å lime inn dataene til et annet sted.

For å filtrere celler med to eller flere kriterier, bruk Avansert filter for å finne slike celler, og deretter kopiere hele radene med resultatene eller trekke ut bare spesifikke kolonner.

Dette er hvordan du manipulerer celler basert på verdien i Excel. Jeg takker for at du leser og håper å se deg på bloggen vår neste uke!

Øvningsarbeidsbok

Excel hvis celle inneholder deretter - eksempler (.xlsx-fil)