I de siste artiklene har vi diskutert forskjellige tekstfunksjoner - de som brukes til å manipulere tekststrenger. I dag er fokuset vårt på HØYRE-funksjonen, som er designet for å returnere et spesifisert antall tegn fra den høyre siden av en streng. I likhet med andre Excel-tekstfunksjoner er RIGHT veldig enkel og grei, men den har noen få uopplagte bruksområder som kan være nyttige i arbeidet ditt.

Excel RIGHT-funksjonens syntaks

HØYRE-funksjonen i Excel returnerer det angitte antallet tegn fra slutten av en tekststreng.

Syntaksen til HØYRE-funksjonen er som følger:

Hvor :

• Tekst (obligatorisk) - tekststrengen du vil trekke ut tegn fra.
• Antall_tegn (valgfritt) - antall tegn som skal trekkes ut, fra tegnet lengst til høyre.
  • Hvis antall_tegn er utelatt, returneres 1 siste tegn i strengen (standard).
  • Hvis antall_tegn er større enn det totale antallet av tegn tegn i strengen, returneres alle tegn.
  • Hvis antall_tegn er et negativt tall, returnerer en Høyre-formel #VERDI! feil.

For å trekke ut de siste 3 tegnene fra strengen i celle A2, bruk denne formelen:

=RIGHT(A2, 3)

Resultatet kan se noe lignende ut:

Viktig merknad! Excel HØYRE-funksjonen returnerer alltid en tekststreng , selv om den opprinnelige verdien er et tall. For å tvinge en Høyre formel til å skrive ut et tall, bruk den i kombinasjon med VERDI-funksjonen som vist i dette eksemplet.

Hvordan bruke HØYRE-funksjonen i Excel - formeleksempler

I det virkelige liv regneark, brukes Excel RIGHT-funksjonen sjelden alene. I de fleste tilfeller vil du bruke den sammen med andre Excel-funksjoner som en del av mer komplekse formler.

Hvordan få en delstreng som kommer etter et bestemt tegn

Hvis du vil trekke ut en delstreng som følger et spesifikt tegn, bruk enten SØK- eller FINN-funksjonen for å bestemme posisjonen til det tegnet, trekk posisjonen fra den totale strenglengden som returneres av LEN-funksjonen, og trekk så mange tegn fra den høyre siden av den opprinnelige strengen.

La oss si celle A2 inneholder for- og etternavnet atskilt med et mellomrom, og du tar sikte på å trekke etternavnet til en annen celle. Bare ta den generiske formelen ovenfor, og du setter A2 i stedet for streng , og " " (mellomrom) i takt med tegn:

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2))

Formelen vil gi følgende resultat:

På lignende måte kan du få en delstreng som følger et hvilket som helst annet tegn, f.eks. et komma, semikolon, bindestrek osv. For å trekke ut en delstreng som kommer etter en bindestrek,bruk denne formelen:

=RIGHT(A2,LEN(A2)-SEARCH("-",A2))

Resultatet vil se ut som dette:

Hvordan trekke ut en delstreng etter siste forekomst av skilletegnet

Når håndtere komplekse strenger som inneholder flere forekomster av samme skilletegn, kan det hende at du ofte må hente teksten til høyre for den siste skilletegnet. For å gjøre ting lettere å forstå, ta en titt på følgende kildedata og ønsket resultat:

Som du kan se på skjermbildet ovenfor, inneholder kolonne A en liste over feil. Målet ditt er å trekke feilbeskrivelsen som kommer etter siste kolon i hver streng. En ekstra komplikasjon er at de originale strengene kan inneholde forskjellig antall avgrensningsforekomster, f.eks. A3 inneholder 3 kolon mens A5 bare ett.

Nøkkelen til å finne en løsning er å bestemme posisjonen til siste skilletegn i kildestrengen (siste forekomst av et kolon i dette eksemplet). For å gjøre dette må du bruke en håndfull forskjellige funksjoner:

1. Få antall skilletegn i den opprinnelige strengen. Det er en enkel del:
   • For det første beregner du den totale lengden på strengen ved å bruke LEN-funksjonen: LEN(A2)
   • For det andre beregner du lengden på strengen uten skilletegn ved å bruke SUBSTITUTE-funksjon som erstatter alle forekomster av et kolon med ingenting: LEN(SUBSTITUTE(A2,":",""))
   • Til slutt trekker du fra lengden på den opprinnelige strengenuten skilletegn fra den totale strenglengden: LEN(A2)-LEN(SUBSTITUTE(A2,":",""))

   For å være sikker på at formelen fungerer riktig, kan du skrive den inn i en separat celle, og resultatet blir 2, som er antall kolon i celle A2.

2. Erstatt det siste skilletegnet med et unikt tegn. For å trekke ut teksten som kommer etter det siste skilletegnet i strengen, må vi "merke" den siste forekomsten av skilletegnet på en eller annen måte. For dette, la oss erstatte den siste forekomsten av et kolon med et tegn som ikke vises noe sted i de originale strengene, for eksempel med et pundtegn (#).

   Hvis du er kjent med syntaksen til Excel ERSTATT-funksjonen, kan du huske at den har det fjerde valgfrie argumentet (instance_num) som tillater å erstatte bare en spesifikk forekomst av det angitte tegnet. Og siden vi allerede har beregnet antall skilletegn i strengen, oppgi funksjonen ovenfor i det fjerde argumentet til en annen ERSTATT-funksjon:

   =SUBSTITUTE(A2,":","#",LEN(A2)-LEN(SUBSTITUTE(A2,":","")))

   Se også: Hvordan fjerne mellomrom i Excel - førende, etterfølgende, ikke-brytende

   Hvis du legger denne formelen i en egen celle , ville den returnere denne strengen: FEIL:432#Forbindelsen ble tidsavbrutt

3. Få posisjonen til siste skilletegn i strengen. Avhengig av hvilket tegn du erstattet det siste skilletegnet med, bruk enten SEARCH som skiller mellom store og små bokstaver eller FIND for å bestemme plasseringen av det tegnet i strengen. Vi erstattet den siste kolonmed #-tegnet, så vi bruker følgende formel for å finne posisjonen:

   =SEARCH("#", SUBSTITUTE(A2,":","#",LEN(A2)-LEN(SUBSTITUTE(A2,":",""))))

   I dette eksemplet returnerer formelen 10, som er posisjonen til # i den erstattede strengen.

4. Returner en delstreng til høyre for siste skilletegn. Nå som du vet posisjonen til siste skilletegn i en streng, er alt du trenger å gjøre å trekke dette tallet fra den totale strenglengden, og få RIGHT-funksjonen for å returnere så mange tegn fra slutten av den opprinnelige strengen:

   =RIGHT(A2,LEN(A2)-SEARCH("$",SUBSTITUTE(A2,":","$",LEN(A2)-LEN(SUBSTITUTE(A2,":","")))))

Som vist på skjermbildet nedenfor, fungerer formelen perfekt:

Hvis du jobber med et stort datasett der ulike celler kan inneholde ulike skilletegn, vil du kanskje for å omslutte formelen ovenfor i IFERROR-funksjonen for å forhindre mulige feil:

=IFERROR(RIGHT(A2,LEN(A2)-SEARCH("$",SUBSTITUTE(A2,":","$",LEN(A2)-LEN(SUBSTITUTE(A2,":",""))))), A2)

Hvis en bestemt streng ikke inneholder en enkelt forekomst av det spesifiserte skilletegn, vil den opprinnelige strengen bli returnert, som i rad 6 i skjermbildet nedenfor:

Hvordan fjerne de første N tegnene fra en streng

Bortsett fra å trekke ut en delstreng fra slutten av en streng, kommer Excel HØYRE-funksjonen godt med i situasjoner når du ønsker å fjerne et visst antall tegn fra begynnelsen av strengen.

I datasettet som ble brukt i forrige I et eksempel kan det være lurt å fjerne ordet "FEIL" som vises i starten av hver streng og bare la feilnummeret og beskrivelsen være igjen. Å ha detgjort, trekk antall tegn som skal fjernes fra den totale strenglengden, og oppgi dette tallet til antall_tegn -argumentet til Excel HØYRE-funksjonen:

I dette eksemplet fjerner vi de første 6 tegnene (5 bokstaver og et kolon) fra tekststrengen i A2, så formelen vår går som følger:

=RIGHT(A2, LEN(A2)-6)

Kan Excel HØYRE-funksjonen returnere et tall?

Som nevnt i begynnelsen av denne opplæringen, returnerer HØYRE-funksjonen i Excel alltid en tekststreng selv hvis den opprinnelige verdien er et tall. Men hva om du jobber med et numerisk datasett og vil at utdataene også skal være numeriske? En enkel løsning er å legge en riktig formel i VERDI-funksjonen, som er spesielt utviklet for å konvertere en streng som representerer et tall til et tall.

For eksempel å trekke de siste 5 tegnene (postnummer) fra strengen i A2 og konverter de utpakkede tegnene til et tall, bruk denne formelen:

=VALUE(RIGHT(A2, 5))

Skjermbildet nedenfor viser resultatet - vær oppmerksom på de høyrejusterende tallene i kolonne B, i motsetning til venstre -justerte tekststrenger i kolonne A:

Hvorfor fungerer ikke HØYRE-funksjonen med datoer?

Siden HØYRE-funksjonen i Excel er designet for å fungere med tekststrenger, mens datoer er representert med tall i det interne Excel-systemet, er en riktig formel ikke i stand til å hente en persondel av en dato, for eksempel en dag, måned eller år. Hvis du prøver å gjøre dette, får du bare noen siste sifre i tallet som representerer en dato.

Anta at du har datoen 18-jan-2017 i celle A1. Hvis du prøver å trekke ut året med formelen HØYRE(A1,4), vil resultatet bli 2753, som er de 4 siste sifrene i nummer 42753 som representerer 18. januar 2017 i Excel-systemet.

"Så, hvordan henter jeg en viss del av en date?", kan du spørre meg. Ved å bruke en av følgende funksjoner:

• DAY-funksjonen for å trekke ut en dag: =DAY(A1)
• MONTH-funksjonen for å få en måned: =MONTH(A1)
• ÅR-funksjon for å trekke et år: =ÅR(A1)

Følgende skjermbilde viser resultatene:

Hvis datoer er representert med tekststrenger , som ofte er tilfellet når du eksporterer data fra en ekstern kilde, ingenting hindrer deg i å bruke HØYRE-funksjonen til å trekke de siste tegnene i strengen som representerer en viss del av datoen:

Excel HØYRE funksjonen fungerer ikke - årsaker og løsninger

Hvis en riktig formel ikke fungerer riktig i regnearket ditt, er det mest sannsynlig på grunn av en av følgende årsaker:

1. Det er en eller flere etterliggende mellomrom i de originale dataene. For raskt å fjerne ekstra mellomrom i celler, bruk enten Excel TRIM-funksjonen eller Cell Cleaner-tillegget.
2. Argumentet antall_tegn er mindre enn null . Avselvfølgelig vil du neppe sette et negativt tall i formelen din med vilje, men hvis antall_tegn -argumentet beregnes av en annen Excel-funksjon eller en kombinasjon av forskjellige funksjoner og høyre formel returnerer #VERDI! feil, sørg for å sjekke de nestede funksjonene for feil.
3. Den opprinnelige verdien er en dato . Hvis du har fulgt denne opplæringen nøye, vet du allerede hvorfor RIGHT-funksjonen ikke kan fungere med datoer. Hvis noen hoppet over forrige avsnitt, kan du finne alle detaljer i Hvorfor Excel HØYRE-funksjonen ikke fungerer med datoer.

Slik bruker du HØYRE-funksjonen i Excel. For å se nærmere på formlene som er diskutert i denne opplæringen, er du hjertelig velkommen til å laste ned vår eksempelarbeidsbok nedenfor. Jeg takker for at du leser og håper å se deg på bloggen vår neste uke.

Tilgjengelige nedlastinger

Excel RIGHT-funksjon - eksempler (.xlsx-fil)