Tartalomjegyzék
Ez a bemutató az ISNA függvény Excelben történő használatának különböző módjait mutatja be az #N/A hibák kezelésére.
Amikor az Excel nem találja meg, amit kérnek tőle, egy cellában #N/A hiba jelenik meg. Az ilyen hibák elfogására és kezelésére használhatja az ISNA függvényt. Mi ennek a gyakorlati haszna? Lényegében segít felhasználóbarátabbá tenni a képleteket és szebbé tenni a munkalapokat.
ISNA funkció Excelben
Az Excel ISNA funkciója a cellák vagy képletek #N/A hibák ellenőrzésére szolgál. Az eredmény egy logikai érték: TRUE, ha #N/A hibát észlel, egyébként FALSE.
A funkció az Excel 2000-től 2021-ig és az Excel 365 összes verziójában elérhető.
Az ISNA függvény szintaxisa a lehető legegyszerűbb:
ISNA(érték)Hol érték az a cellaérték vagy képlet, amelyet #N/A hibák szempontjából ellenőrizni szeretne.
Az ISNA-képlet alapformájának létrehozásához egyetlen argumentumként adjon meg egy cellahivatkozást:
=ISNA(A2)
Ha a hivatkozott cella #N/A hibát tartalmaz, akkor TRUE-t kapunk. Bármilyen más hiba, érték vagy üres cella esetén FALSE-t kapunk:
Az ISNA használata Excelben
Az ISNA függvény használatának tiszta formájában kevés gyakorlati értelme van. Gyakrabban használják más függvényekkel együtt egy bizonyos képlet eredményének kiértékelésére. Ehhez csak tegyük be a másik képletet a érték az ISNA érvelése:
ISNA( your_formula ())Tegyük fel, hogy az alábbi adatkészletben két listát (A és D oszlop) szeretnénk összehasonlítani, és azonosítani azokat a neveket, amelyek mindkét listában szerepelnek, illetve azokat, amelyek csak az 1. listában szerepelnek.
Az A3-ban szereplő nevet a D oszlopban szereplő nevekkel kell összehasonlítani, a képlet a következő:
=MATCH(A3, $D$2:$D$9, 0)
Ha találunk keresési értéket, a MATCH függvény visszaadja annak relatív pozícióját a keresési tömbben, ellenkező esetben #N/A hiba lép fel. A MATCH eredményének teszteléséhez beágyazzuk azt az ISNA-ba:
=ISNA(MATCH(A3, $D$2:$D$9, 0))
Ez a képlet a B3-ba kerül, majd a B14-en keresztül másolódik.
Most már világosan láthatjuk, hogy mely diákok mentek át az összes teszten (a D oszlopban nem szerepel név> a MATCH #N/A-t ad vissza> az ISNA TRUE-t ad vissza), és melyeknek van legalább egy sikertelen tesztjük (a D oszlopban megjelenik egy név> nincs hiba> az ISNA FALSE-t ad vissza).
Tipp. Az Excel 365 és az Excel 2021 programban a MATCH helyett a korszerűbb XMATCH függvényt használhatja.
IF ISNA képlet Excelben
Az ISNA függvény eleve csak két Boolean értéket tud visszaadni. Egyéni üzenetek megjelenítéséhez használja az IF függvénnyel együtt:
IF(ISNA(...), " text_if_error ", " text_if_no_error ")Kicsit tovább finomítva a példánkat, derítsük ki, hogy az A csoportból melyik diák nem bukott meg egyetlen tesztet sem, és adjuk vissza számukra a "Nincs bukott teszt" értéket. A többi diák esetében a "Nem sikerült" értéket adjuk vissza. Ehhez ágyazzuk be az ISNA MATCH formulát az IF logikai tesztjébe, így az IF lesz a legkülső függvény:
=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "Nincs sikertelen teszt", "Sikertelen")
Az eredmények sokkal jobbnak és intuitívabbnak tűnnek, egyetértesz?
Az ISNA használata Excelben a VLOOKUP segítségével
Az IF ISNA kombináció egy univerzális megoldás, amely bármilyen olyan függvényhez használható, amely keres valamit egy adathalmazban, és #N/A hibát ad vissza, ha a keresési értéket nem találja.
Az ISNA funkció szintaxisa a VLOOKUP funkcióval a következő:
IF(ISNA(VLOOKUP(...), " custom_text ", VLOOKUP(....))Emberi nyelvre lefordítva azt mondja: ha a VLOOKUP #N/A hibát eredményez, adjon vissza egyéni szöveget, egyébként adja vissza a VLOOKUP eredményét.
Tegyük fel, hogy a mintatáblánkban azokat a tantárgyakat szeretné visszaadni, amelyekből a diákok megbuktak a vizsgán. Azok esetében, akik minden vizsgán sikeresen megfeleltek, a "Nincs bukott vizsga" fog megjelenni.
Az alanyok megkereséséhez ezt a klasszikus VLOOKUP képletet állítjuk össze:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
Majd fészkelje be a fentebb tárgyalt általános IF ISNA képletbe:
=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Nincs sikertelen teszt", VLOOKUP(A3, $D$3:$E$9, 2, FALSE)))
Az Excel 2013 és újabb verziókban az IFNA függvényt használhatja a #N/A hibák elkapására és kezelésére. Ezáltal a képlet rövidebbé és könnyebben olvashatóvá válik.
Példaként az #N/A hibákat kötőjelekkel ("-") helyettesítjük, és ezt az elegáns megoldást kapjuk:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")
Az Excel 365 és 2021 felhasználóinak egyáltalán nincs szükségük semmilyen wrapperfüggvényre, mivel a VLOOKUP modern utódja, az XLOOKUP függvény natívan képes kezelni az #N/A hibákat:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")
Az eredmény pontosan ugyanaz lesz, mint a fenti képernyőképen látható.
SUMPRODUCT ISNA formula az #N/A hibák számolásához
Ha egy bizonyos tartományban az #N/A hibákat szeretné megszámolni, használja az ISNA függvényt a SUMPRODUCT függvénnyel együtt:
SUMPRODUCT(--ISNA( tartomány ))Itt az ISNA egy TRUE és FALSE értékekből álló tömböt ad vissza, a kettős negáció (--) a logikai értékeket 1-es és 0-s értékekre kényszeríti, a SUMPRODUCT pedig összeadja az eredményt.
Ha például azt szeretné megtudni, hogy hány diák sikeresen teljesítette az összes tesztet, módosítsa a MATCH képletet egy keresési értéktartományra (A3:A14), és fészkelje be az ISNA-ba:
=SUMPRODUCT(--ISNA(MATCH(A3:A14, D2:D9, 0)))
A képlet megállapítja, hogy 9 diáknak nincs sikertelen tesztje, azaz a MATCH függvény 9 #N/A hibát ad vissza:
Így hozhatunk létre és használhatunk ISNA képleteket az Excelben. Köszönöm, hogy elolvastad, és várom a jövő heti blogunkon!
Elérhető letöltések
ISNA képlet példák (.xlsx fájl)
