V učbeniku je prikazano, kako uporabiti formulo VLOOKUP v Excelu za primerjavo dveh stolpcev, da bi dobili skupne vrednosti (ujemanje) ali našli manjkajoče podatke (razlike).

Kadar imate podatke na dveh različnih seznamih, jih boste morda morali pogosto primerjati, da bi ugotovili, katere informacije manjkajo na enem od seznamov ali kateri podatki so prisotni na obeh. Primerjavo lahko izvedete na več različnih načinov - kateri način boste uporabili, je odvisno od tega, kaj točno želite od tega.

Kako primerjati dva stolpca v Excelu z uporabo VLOOKUP

Kadar imate dva stolpca podatkov in želite ugotoviti, katere podatkovne točke iz enega seznama obstajajo v drugem seznamu, lahko s funkcijo VLOOKUP primerjate sezname za iskanje skupnih vrednosti.

Če želite sestaviti formulo VLOOKUP v osnovni obliki, morate narediti naslednje:

• Za lookup_value (1. argument), uporabite najvišjo celico s seznama 1.
• Za table_array (2. argument), navedite celoten seznam 2.
• Za col_index_num (3. argument), uporabite 1, ker je v polju samo en stolpec.
• Za range_lookup (4. argument), nastavite FALSE - natančno ujemanje.

Recimo, da imate imena udeležencev v stolpcu A (seznam 1) in imena udeležencev, ki so se uvrstili v kvalifikacijske kroge, v stolpcu B (seznam 2). Želite primerjati ta dva seznama in ugotoviti, kateri udeleženci iz skupine A so se uvrstili na glavni dogodek. To storite z naslednjo formulo.

=VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

Formula je v celici E2, nato pa jo povlečete navzdol po toliko celicah, kolikor je elementov v seznamu 1.

Upoštevajte, da table_array je zaklenjena z absolutnimi referencami ($C$2:$C$9), tako da ostane nespremenjena, ko kopirate formulo v spodnje celice.

Kot lahko vidite, so imena kvalificiranih športnikov prikazana v stolpcu E. Za preostale udeležence se pojavi napaka #N/A, ki pomeni, da njihova imena niso na voljo na seznamu 2.

Prikrivanje #N/A napake

Zgoraj obravnavana formula VLOOKUP odlično izpolnjuje svoj glavni cilj - vrača skupne vrednosti in prepoznava manjkajoče podatkovne točke. Vendar pa prinaša več napak #N/A, ki lahko neizkušene uporabnike zmedejo, zato mislijo, da je s formulo nekaj narobe.

Zamenjava napak z prazne celice , uporabite VLOOKUP v kombinaciji s funkcijo IFNA ali IFERROR na ta način:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Naša izboljšana formula namesto #N/A vrne prazen niz (""). besedilo po meri kot so "Ni na seznamu 2", "Ni prisoten" ali "Ni na voljo". Na primer:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "Ni na seznamu 2")

To je osnovna formula VLOOKUP za primerjavo dveh stolpcev v Excelu. Glede na vašo konkretno nalogo jo lahko spremenite, kot je prikazano v nadaljnjih primerih.

Primerjanje dveh stolpcev v različnih Excelovih listih z uporabo VLOOKUP

V resničnem življenju stolpci, ki jih morate primerjati, niso vedno na istem listu. V majhnem naboru podatkov lahko razlike opazite ročno, tako da si ogledate dva lista drug ob drugem.

Za iskanje v drugem delovnem listu ali delovnem zvezku s formulami morate uporabiti zunanji sklic. Najboljša praksa je, da začnete vnašati formulo v glavni list, nato preklopite na drugi delovni list in z miško izberete seznam - ustrezen sklic na območje bo formuli dodan samodejno.

Ob predpostavki, da je seznam 1 v stolpcu A na List1 seznam 2 pa je v stolpcu A na List2 , lahko primerjate dva stolpca in poiščete ujemanje s to formulo:

=IFNA(VLOOKUP(A2, List2!$A$2:$A$9, 1, FALSE), "")

Za več informacij glejte:

• VLOOKUP iz drugega lista
• VLOOKUP iz drugega delovnega zvezka

primerja dva stolpca in vrne skupne vrednosti (ujemanja)

V prejšnjih primerih smo obravnavali formulo VLOOKUP v njeni najpreprostejši obliki:

=IFNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE), "")

Rezultat te formule je seznam vrednosti, ki obstajajo v obeh stolpcih, in prazne celice namesto vrednosti, ki niso na voljo v drugem stolpcu.

Če želite dobiti seznam skupnih vrednosti brez vrzeli, v dobljeni stolpec dodajte samodejni filter in izločite prazna mesta.

V Excelu za Microsoft 365 in Excelu 2021, ki podpirata dinamične razpredelnice, lahko uporabite funkcijo FILTER za dinamično izločanje praznih mest. V ta namen uporabite formulo IFNA VLOOKUP kot merilo za FILTER:

=FILTER(A2:A14, IFNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE), "")")

Bodite pozorni, da v tem primeru celoten seznam 1 (A2:A14) posredujemo lookup_value Funkcija primerja vsako vrednost iskanja s seznamom 2 (C2:C9) in vrne polje ujemanj in napak #N/A, ki predstavljajo manjkajoče vrednosti. Funkcija IFNA nadomesti napake s praznimi nizi in rezultate posreduje funkciji FILTER, ki filtrira prazna mesta ("") in kot končni rezultat izpiše polje ujemanj.

Druga možnost je, da s funkcijo ISNA preverite rezultat VLOOKUP in filtrirate elemente z vrednostjo FALSE, tj. vrednosti, ki niso napake #N/A:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE))=FALSE)

Enak rezultat lahko dosežemo s funkcijo XLOOKUP, zaradi česar je formula še preprostejša. Zaradi sposobnosti funkcije XLOOKUP, da interno obravnava napake #N/A (neobvezno if_not_found argument), lahko opravimo brez ovitka IFNA ali ISNA:

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")"")

Primerjajte dva stolpca in poiščite manjkajoče vrednosti (razlike)

Če želite v Excelu primerjati dva stolpca in poiskati razlike, lahko to storite na naslednji način:

1. Napišite osnovno formulo za iskanje prve vrednosti s seznama 1 (A2) na seznamu 2 ($C$2:$C$9):

   VLOOKUP(A2, $C$2:$C$9, 1, FALSE)

2. Zgornjo formulo vnesite v funkcijo ISNA, da preverite izhod VLOOKUP za napake #N/A. V primeru napake ISNA da TRUE, sicer FALSE:

   ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE))

3. Za logični preizkus funkcije IF uporabite formulo ISNA VLOOKUP. Če je rezultat preizkusa TRUE (napaka #N/A), vrnite vrednost iz seznama 1 v isti vrstici. Če je rezultat preizkusa FALSE (najdeno je ujemanje v seznamu 2), vrnite prazen niz.

Celotna formula ima naslednjo obliko:

=IF(ISNA(VLOOKUP(A2, $C$2:$C$9, 1, FALSE)), A2, "")

Če se želite znebiti praznih mest, uporabite Excelov filter, kot je prikazano v zgornjem primeru.

V Excelu 365 in Excelu 2021 lahko seznam rezultatov filtrirate dinamično. V ta namen preprosto postavite formulo ISNA VLOOKUP v vključiti argumenta funkcije FILTER:

=FILTER(A2:A14, ISNA(VLOOKUP(A2:A14, C2:C9, 1, FALSE)))

Drug način je uporaba funkcije XLOOKUP za merila - funkcija vrne prazne nize ("") za manjkajoče podatkovne točke, vi pa filtrirate vrednosti v seznamu 1, za katere je funkcija XLOOKUP vrnila prazne nize (=""):

=FILTER(A2:A14, XLOOKUP(A2:A14, C2:C9, C2:C9,"")="")

Formula VLOOKUP za ugotavljanje ujemanj in razlik med dvema stolpcema

Če želite na prvi seznam dodati besedilne oznake, ki označujejo, katere vrednosti so na voljo na drugem seznamu in katere ne, uporabite formulo VLOOKUP skupaj s funkcijama IF in ISNA/ISERROR.

Na primer, za prepoznavanje imen, ki so v stolpcih A in D, ter imen, ki so samo v stolpcu A, je formula naslednja:

=IF(ISNA(VLOOKUP(A2, $D$2:$D$9, 1, FALSE)), "Ni kvalificiran", "Kvalificiran")

Funkcija ISNA zajame napake #N/A, ki jih ustvari funkcija VLOOKUP, in ta vmesni rezultat posreduje funkciji IF, ki vrne določeno besedilo za napake in drugo besedilo za uspešna iskanja.

V tem primeru smo uporabili oznake "Not qualified"/"Qualified", ki so primerne za naš nabor podatkov. Lahko jih nadomestite z oznakami "Not in List 2"/"In List 2", "Not available"/"Available" ali drugimi oznakami, ki se vam zdijo primerne.

To formulo je najbolje vstaviti v sosednji stolpec seznama 1 in jo kopirati v toliko celic, kolikor je elementov na seznamu.

Še en način za ugotavljanje ujemanj in razlik v dveh stolpcih je uporaba funkcije MATCH:

=IF(ISNA(MATCH(A2, $D$2:$D$9, 0)), "Ni na seznamu 2", "Na seznamu 2")

Primerjaj 2 stolpca in vrni vrednost iz tretjega stolpca

Pri delu s tabelami, ki vsebujejo povezane podatke, boste včasih morali primerjati dva stolpca v dveh različnih tabelah in vrniti ustrezno vrednost iz drugega stolpca. To je pravzaprav glavna uporaba funkcije VLOOKUP in namen, za katerega je bila zasnovana.

Če želite na primer primerjati imena v stolpcih A in D v spodnjih dveh tabelah in vrniti čas iz stolpca E, je formula naslednja:

=VLOOKUP(A3, $D$3:$E$10, 2, FALSE)

Če želite skriti napake #N/A, uporabite preverjeno rešitev - funkcijo IFNA:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "")

Namesto praznih mest lahko za manjkajoče podatkovne točke vrnete poljubno besedilo - vnesite ga v zadnji argument:

=IFNA(VLOOKUP(A3, $D$3:$E$10, 2, FALSE), "Ni na voljo")

Poleg funkcije VLOOKUP lahko to nalogo opravite z nekaj drugimi funkcijami iskanja.

Osebno bi se zanesel na bolj prilagodljivo formulo INDEX MATCH:

=IFNA(INDEX($E$3:$E$10, MATCH(A3, $D$3:$D$10, 0)), "")

Lahko pa uporabite sodobno naslednico funkcije VLOOKUP - funkcijo XLOOKUP, ki je na voljo v Excelu 365 in Excelu 2021:

=XLOOKUP(A3, $D$3:$D$10, $E$3:$E$10, "")

Če želite dobiti imena kvalificiranih udeležencev iz skupine A in njihove rezultate, preprosto filtrirajte prazna polja v stolpcu B:

=FILTER(A3:B15, B3:B15"")

Orodja za primerjavo

Če v Excelu pogosto primerjate datoteke ali podatke, vam lahko ta pametna orodja, ki so vključena v naš komplet Ultimate Suite, zelo prihranijo čas!

Primerjava tabel - hiter način za iskanje podvojitev (ujemanj) in edinstvenih vrednosti (razlik) v dveh podatkovnih nizih, kot so stolpci, seznam ali tabele.

Primerjaj dva lista - poiščite in poudarite razlike med dvema delovnima listoma.

Primerjajte več listov - poiščite in poudarite razlike v več listih hkrati.

Praktični delovni zvezek za prenos

VLOOKUP v Excelu za primerjavo stolpcev - primeri (.xlsx datoteka)