Tutorialul arată cum se realizează reguli personalizate de validare a datelor în Excel. Veți găsi câteva exemple de E Formule de validare a datelor xcel pentru a permite doar numere sau valori text în anumite celule, sau doar text care începe cu anumite caractere, permite date unice care previn dublurile și multe altele.

În tutorialul de ieri am început să analizăm validarea datelor în Excel - care este scopul său, cum funcționează și cum să folosim regulile încorporate pentru a valida datele din foile de lucru. Astăzi, vom face un pas înainte și vom vorbi despre aspectele esențiale ale validării personalizate a datelor în Excel, precum și vom experimenta cu o mână de formule de validare diferite.

Cum se creează validarea datelor personalizate cu formula

Microsoft Excel are mai multe reguli de validare a datelor încorporate pentru numere, date și text, dar acestea acoperă doar cele mai elementare scenarii. Dacă doriți să validați celulele cu propriile criterii, creați o regulă de validare personalizată bazată pe o formulă. Iată cum:

1. Selectați una sau mai multe celule care urmează să fie validate.
2. Deschideți caseta de dialog Data Validation (Validare date). Pentru aceasta, faceți clic pe butonul Validarea datelor de pe butonul Date în fila Instrumente de date grup sau apăsați secvența de taste Alt> D> L (fiecare tastă trebuie apăsată separat).
3. Pe Setări din fila Validarea datelor fereastra de dialog, selectați Personalizat în Permiteți și introduceți formula de validare a datelor în caseta Formula cutie.
4. Faceți clic pe OK .

Opțional, puteți adăuga un mesaj de intrare personalizat și o alertă de eroare care se vor afișa atunci când utilizatorul selectează celula validată sau, respectiv, introduce date invalide.

Mai jos veți găsi câteva exemple de reguli de validare personalizate pentru diferite tipuri de date.

Notă. Toate regulile de validare a datelor din Excel, încorporate și personalizate, verifică numai datele noi care sunt introduse într-o celulă după crearea regulii. Datele copiate nu sunt validate și nici datele introduse în celulă înainte de crearea regulii. Pentru a fixa intrările existente care nu îndeplinesc criteriile de validare a datelor, utilizați funcția Cercul Date invalide așa cum se arată în Cum să găsiți date invalide în Excel.

Validarea datelor din Excel pentru a permite doar numere

În mod surprinzător, niciuna dintre regulile de validare a datelor încorporate în Excel nu se adresează unei situații foarte tipice în care trebuie să restricționați utilizatorii să introducă numai numere în anumite celule. Dar acest lucru se poate face cu ușurință cu o formulă de validare a datelor personalizată bazată pe funcția ISNUMBER, ca aceasta:

=ISNUMBER(C2)

Unde C2 este cea mai de sus celulă din intervalul pe care doriți să îl validați.

Notă. Funcția ISNUMBER permite orice valori numerice în celulele validate, inclusiv numere întregi, zecimale, fracții, precum și date și ore, care sunt, de asemenea, numere în termeni de Excel.

Validarea datelor din Excel pentru a permite doar text

Dacă doriți opusul - să permiteți numai intrări de text într-un anumit interval de celule, atunci construiți o regulă personalizată cu funcția ISTEXT, de exemplu:

=ISTEXT(D2)

Unde D2 este cea mai înaltă celulă din intervalul selectat.

Permiterea textului care începe cu un anumit caracter (caractere)

Dacă toate valorile dintr-un anumit interval ar trebui să înceapă cu un anumit caracter sau subșir, atunci validați datele din Excel pe baza funcției COUNTIF cu un caracter joker:

De exemplu, pentru a vă asigura că toate ID-urile de comandă din coloana A încep cu prefixul "AA-", "aa-", "Aa-" sau "aA-" (fără a ține cont de majuscule și minuscule), definiți o regulă personalizată cu această formulă de validare a datelor:

=COUNTIF(A2, "aa-*")

Formula de validare cu logica OR (criterii multiple)

În cazul în care există 2 sau mai multe prefixe valide, adăugați mai multe funcții COUNTIF, astfel încât regula de validare a datelor Excel să funcționeze cu logica OR:

=COUNTIF(A2,"aa-*")+COUNTIF(A2,"bb-*")

Formula de validare sensibilă la majuscule și minuscule

În cazul în care contează cazul caracterelor, utilizați EXACT în combinație cu funcția LEFT pentru a crea o formulă de validare sensibilă la majuscule și minuscule pentru intrările care încep cu un anumit text:

De exemplu, pentru a permite numai acele id-uri de comandă care încep cu "AA-" (nu este permis nici "aa-", nici "Aa-"), utilizați această formulă:

=EXACT(LEFT(A2,3), "AA-")

În formula de mai sus, funcția LEFT extrage primele 3 caractere din celula A2, iar funcția EXACT efectuează o comparație în funcție de majuscule și minuscule cu subșirul codificat ("AA-" în acest exemplu). Dacă cele două subșiruri corespund exact, formula returnează TRUE și validarea trece; în caz contrar, se returnează FALSE și validarea eșuează.

Permiterea intrărilor care conțin un anumit text

Pentru a permite intrări care conțin un text specific oriunde într-o celulă (la început, la mijloc sau la sfârșit), utilizați funcția ISNUMBER în combinație cu FIND sau SEARCH, în funcție de dacă doriți o potrivire sensibilă sau insensibilă la majuscule și minuscule:

• Validare insensibilă la majuscule și minuscule: ISNUMBER(SEARCH( text , celulă ))
• Validare în funcție de majuscule și minuscule: ISNUMBER(FIND( text , celulă ))

În setul nostru de date de exemplu, pentru a permite numai intrările care conțin textul "AA" în celulele A2:A6, utilizați una dintre aceste formule:

Nu ține cont de majuscule și minuscule:

=ISNUMBER(SEARCH("AA", A2))

Sensibil la majuscule și minuscule:

=ISNUMBER(FIND("AA", A2))

Formulele funcționează după următoarea logică:

Căutați subșirul "AA" în celula A2 folosind FIND sau SEARCH, iar ambele returnează o poziție a primului caracter din subșir. Dacă textul nu este găsit, se returnează o eroare. Pentru orice valoare numerică returnată ca rezultat al căutării, funcția ISNUMBER produce TRUE, iar validarea datelor este reușită. În cazul unei erori, ISNUMBER returnează FALSE, iar intrarea nu va fi permisă într-o celulă.

Validarea datelor pentru a permite doar intrările unice și a refuza dublurile

În situațiile în care o anumită coloană sau un interval de celule nu trebuie să conțină duplicate, configurați o regulă de validare a datelor personalizată pentru a permite numai intrări unice. Pentru aceasta, vom utiliza formula clasică COUNTIF pentru a identifica duplicatele:

De exemplu, pentru a vă asigura că numai ID-urile unice ale comenzilor sunt introduse în celulele A2 - A6, creați o regulă personalizată cu această formulă de validare a datelor:

=COUNTIF($A$2:$A$6, A2)<=1

Atunci când se introduce o valoare unică, formula returnează TRUE și validarea reușește. Dacă aceeași valoare există deja în intervalul specificat (număr mai mare de 1), COUNTIF returnează FALSE și validarea nu reușește.

Vă rugăm să fiți atenți la faptul că blocăm intervalul cu referințe de celule absolute (A$2:$A$6) și folosim o referință relativă pentru celula de sus (A2) pentru ca formula să se ajusteze corect pentru fiecare celulă din intervalul validat.

Notă. Această formulă de validare a datelor este nu ține cont de majuscule și minuscule , nu face distincția între majuscule și minuscule.

Formule de validare pentru date și ore

Validarea încorporată a datei oferă o mulțime de criterii predefinite pentru a restricționa utilizatorii să introducă doar date cuprinse între cele două date pe care le specificați, mai mari, mai mici sau egale cu o anumită dată.

Dacă doriți mai mult control asupra validării datelor din foile de lucru, puteți replica funcționalitatea încorporată cu o regulă personalizată sau puteți scrie propria formulă care depășește capacitățile încorporate ale validării datelor Excel.

Permiteți date între două date

Pentru a limita intrarea la o dată cuprinsă într-un interval specificat, puteți utiliza regula predefinită Data cu criteriul "între" sau puteți crea o regulă de validare personalizată cu această formulă generică:

Unde:

• celulă este cea mai de sus celulă din intervalul validat, iar
• start și sfârșitul datele sunt date valide furnizate prin intermediul funcției DATE sau referințe la celulele care conțin datele.

De exemplu, pentru a permite numai datele din luna iulie a anului 2017, utilizați următoarea formulă:

=AND(C2>=DATE(2017,7,1),C2<=DATE(2017,7,31))

Sau, introduceți data de început și data de sfârșit în anumite celule (F1 și F2 în acest exemplu) și faceți referire la aceste celule în formula dvs:

=AND(C2>=$F$1, C2<=$F$2)

Vă rugăm să observați că datele limită sunt blocate cu referințe de celule absolute.

Permiteți doar în timpul săptămânii sau în weekend

Pentru a restricționa un utilizator să introducă doar zilele săptămânii sau weekend-urile, configurați o regulă de validare personalizată bazată pe funcția WEEKDAY.

Cu ajutorul tip_retur setat la 2, WEEKDAY returnează un număr întreg cuprins între 1 (luni) și 7 (duminică). Astfel, pentru zilele săptămânii (de luni până vineri), rezultatul formulei ar trebui să fie mai mic de 6, iar pentru weekend-uri (sâmbătă și duminică) mai mare de 5.

Permiteți numai zile lucrătoare :

Permiteți numai weekenduri :

De exemplu, pentru a permite introducerea numai a zilelor lucrătoare în celulele C2:C6, utilizați această formulă:

=WEEKDAY(C2,2)<6

Validarea datelor pe baza datei de astăzi

În multe situații, este posibil să doriți să utilizați data de astăzi ca dată de început a intervalului de date permis. Pentru a obține data curentă, utilizați funcția TODAY, apoi adăugați-i numărul de zile dorit pentru a calcula data de sfârșit.

De exemplu, pentru a limita introducerea de date la 6 zile de acum înainte (7 zile, inclusiv ziua de astăzi), vom utiliza regula Data încorporată cu criterii bazate pe formule:

1. Selectați Data în Permiteți
2. Selectați între în Date
3. În Data de începere introduceți =TODAY()
4. În Data de încheiere introduceți =TODAY() + 6

În mod similar, puteți restricționa utilizatorii să introducă date înainte sau după data de astăzi. Pentru aceasta, selectați fie mai puțin de sau mai mare decât în Date și apoi introduceți =TODAY() în Sfârșitul data sau Start respectiv caseta cu data.

Validarea orelor pe baza orei curente

Pentru a valida datele pe baza orei curente, utilizați regula Time predefinită cu propria dumneavoastră formulă de validare a datelor:

1. În Permiteți caseta, selectați Timp .
2. În Date caseta, alegeți fie mai puțin de pentru a permite numai orele anterioare orei curente sau mai mare decât pentru a permite orele ulterioare orei curente.
3. În Ora de sfârșit sau Ora de începere (în funcție de criteriul pe care l-ați selectat la pasul anterior), introduceți una dintre următoarele formule:
   • Pentru a valida date și ore pe baza datei și orei curente:

     =NOW()

   • Pentru a valida ori pe baza orei curente:

     =TIME( HOUR(NOW()), MINUTE(NOW()), SECOND(NOW())))

     Vezi si: Îmbinarea celulelor din Google Sheets din mai multe rânduri într-un singur rând pe baza valorii coloanei

Captura de ecran de mai jos arată o regulă care permite numai orele mai mari decât ora curentă:

Regula personalizată de validare a datelor Excel nu funcționează

Dacă regula de validare a datelor pe bază de formule nu funcționează conform așteptărilor, există 3 puncte principale care trebuie verificate:

• Formula de validare a datelor este corectă
• Formula de validare nu se referă la o celulă goală
• Se utilizează referințe corespunzătoare ale celulelor

Verificați corectitudinea formulei de validare a datelor din Excel

Pentru început, copiați formula de validare într-o celulă pentru a vă asigura că nu returnează o eroare precum #N/A, #VALUE sau #DIV/0!.

Dacă creați un regulă personalizată , formula ar trebui să returneze valorile logice TRUE și FALSE sau valorile 1 și, respectiv, 0 care le echivalează.

Dacă folosiți un criteriu bazat pe o formulă într-un regulă încorporată (așa cum am făcut pentru a valida orele pe baza orei curente), poate, de asemenea, să returneze o altă valoare numerică.

Formula de validare a datelor Excel nu trebuie să se refere la o celulă goală

În multe situații, dacă selectați Ignoră spațiul gol atunci când definiți regula (de obicei, selectată în mod implicit) și una sau mai multe celule la care se face referire în formula dvs. este goală, orice valoare va fi permisă în celula validată.

Iată un exemplu în forma cea mai simplă:

Referințe absolute și relative la celule în formulele de validare a datelor

Atunci când configurați o regulă de validare Excel bazată pe o formulă, rețineți că toate referințele de celule din formula dvs. sunt în raport cu celula din stânga sus în intervalul selectat.

Dacă creați o regulă pentru mai mult de o celulă și criteriile de validare depind de celule specifice , asigurați-vă că folosiți referințe absolute la celule (cu semnul $, cum ar fi $A$1), altfel regula dvs. va funcționa corect numai pentru prima celulă. Pentru a ilustra mai bine acest lucru, vă rugăm să luați în considerare următorul exemplu.

Să presupunem că doriți să restricționați introducerea de date în celulele D2-D5 la numere întregi cuprinse între 1 (valoarea minimă) și rezultatul împărțirii lui A2 la B2. Deci, calculați valoarea maximă cu această formulă simplă =A2/B2 , așa cum se arată în captura de ecran de mai jos:

Problema este că această formulă aparent corectă nu va funcționa pentru celulele D3 - D5, deoarece referințele relative se schimbă pe baza poziției relative a rândurilor și coloanelor. Astfel, pentru celula D3 formula se va schimba în =A3/B3 , iar pentru D4 va deveni =A4/B4 , făcând validarea datelor în mod greșit!

Pentru a repara formula, tastați "$" înaintea referințelor coloanelor și rândurilor pentru a le bloca: =$A$2/$B$2 Sau apăsați F4 pentru a comuta între diferite tipuri de referință.

În situațiile în care doriți să validați fiecare celulă pe baza propriilor criterii, utilizați referințe relative la celule fără semnul $ pentru a obține formula de ajustare pentru fiecare rând și/sau coloană:

După cum vedeți, nu există un "adevăr absolut", aceeași formulă ar putea fi corectă sau greșită în funcție de situație și de sarcina dvs. particulară.

Acesta este modul de utilizare a validării datelor în Excel cu propriile formule. Pentru a înțelege mai bine, nu ezitați să descărcați exemplul nostru de registru de lucru de mai jos și să examinați setările regulilor. Vă mulțumesc pentru lectură și sper să ne vedem pe blogul nostru săptămâna viitoare!

Caietul de practică pentru descărcare

Exemple de validare a datelor Excel (fișier .xlsx)