El tutorial muestra cómo crear reglas de validación de datos personalizadas en Excel. Encontrará algunos ejemplos de E Fórmulas de validación de datos xcel para permitir sólo números o valores de texto en celdas específicas, o sólo texto que empiece por caracteres específicos, permitir datos únicos evitando duplicados, y mucho más.

En el tutorial de ayer empezamos a ver la Validación de Datos en Excel - cuál es su propósito, cómo funciona, y cómo utilizar las reglas incorporadas para validar los datos en sus hojas de cálculo. Hoy, vamos a dar un paso más y hablar de los aspectos esenciales de la validación de datos personalizados en Excel, así como experimentar con un puñado de diferentes fórmulas de validación.

Cómo crear una validación de datos personalizada con fórmula

Microsoft Excel dispone de varias reglas de validación de datos incorporadas para números, fechas y texto, pero sólo cubren las situaciones más básicas. Si desea validar celdas con sus propios criterios, cree una regla de validación personalizada basada en una fórmula. A continuación se explica cómo hacerlo:

1. Seleccione una o más celdas para validar.
2. Abra el cuadro de diálogo Validación de datos. Para ello, haga clic en el botón Validación de datos en el botón Datos en la pestaña Herramientas de datos o pulse la secuencia de teclas Alt> D> L (cada tecla debe pulsarse por separado).
3. En el Ajustes de la pestaña Validación de datos seleccione A medida en el Permitir e introduzca la fórmula de validación de datos en el campo Fórmula caja.
4. Haga clic en OK .

Opcionalmente, puede añadir un mensaje de entrada personalizado y una alerta de Error que se mostrarán cuando el usuario seleccione la celda validada o introduzca datos no válidos, respectivamente.

A continuación encontrará algunos ejemplos de reglas de validación personalizadas para distintos tipos de datos.

Nota. Todas las reglas de validación de datos de Excel, incorporadas y personalizadas, verifican sólo los datos nuevos que se escriben en una celda después de crear la regla. Los datos copiados no se validan, ni tampoco los datos introducidos en la celda antes de crear la regla. Para identificar las entradas existentes que no cumplen los criterios de validación de datos, utilice la función Rodea los datos no válidos como se muestra en Cómo encontrar datos no válidos en Excel.

Validación de datos de Excel para permitir sólo números

Sorprendentemente, ninguna de las reglas de validación de datos incorporadas en Excel contempla una situación muy típica en la que es necesario restringir a los usuarios la introducción de números en celdas específicas. Pero esto se puede hacer fácilmente con una fórmula de validación de datos personalizada basada en la función ISNUMBER, como ésta:

=ISNUMBER(C2)

Donde C2 es la celda superior del rango que desea validar.

Nota. La función ISNUMBER permite cualquier valor numérico en celdas validadas, incluyendo enteros, decimales, fracciones así como fechas y horas, que también son números en términos de Excel.

Validación de datos de Excel para permitir sólo texto

Si lo que busca es lo contrario, es decir, permitir sólo entradas de texto en un rango determinado de celdas, cree una regla personalizada con la función ISTEXT, por ejemplo:

=ISTEXT(D2)

Donde D2 es la celda superior del rango seleccionado.

Permitir que el texto empiece por un carácter específico

Si todos los valores de un determinado rango deben empezar por un carácter o subcadena en particular, realice la validación de datos de Excel basándose en la función COUNTIF con un carácter comodín:

Por ejemplo, para asegurarse de que todos los identificadores de pedido de la columna A empiezan por el prefijo "AA-", "aa-", "Aa-" o "aA-" (sin distinguir mayúsculas de minúsculas), defina una regla personalizada con esta fórmula de validación de datos:

=COUNTIF(A2, "aa-*")

Fórmula de validación con la lógica OR (criterios múltiples)

En caso de que haya 2 o más prefijos válidos, sume varias funciones COUNTIF, para que su regla de validación de datos de Excel funcione con la lógica OR:

=COUNTIF(A2,"aa-*")+COUNTIF(A2,"bb-*")

Fórmula de validación que distingue mayúsculas de minúsculas

Si las mayúsculas y minúsculas son importantes, utilice EXACT en combinación con la función IZQUIERDA para crear una fórmula de validación que distinga entre mayúsculas y minúsculas para las entradas que empiecen por un texto específico:

Por ejemplo, para permitir sólo los identificadores de pedido que empiecen por "AA-" (no se permite ni "aa-" ni "Aa-"), utilice esta fórmula:

=EXACT(LEFT(A2,3), "AA-")

En la fórmula anterior, la función IZQUIERDA extrae los 3 primeros caracteres de la celda A2, y EXACTO realiza una comparación entre mayúsculas y minúsculas con la subcadena codificada ("AA-" en este ejemplo). Si las dos subcadenas coinciden exactamente, la fórmula devuelve VERDADERO y la validación pasa; en caso contrario, se devuelve FALSO y la validación falla.

Permitir entradas que contengan cierto texto

Para permitir entradas que contengan un texto específico en cualquier parte de una celda (al principio, en medio o al final), utilice la función ISNUMBER en combinación con FIND o SEARCH, dependiendo de si desea una coincidencia que distinga entre mayúsculas y minúsculas o entre mayúsculas y minúsculas:

• Validación sin distinción entre mayúsculas y minúsculas: ISNUMBER(SEARCH( texto , célula ))
• Validación sensible a mayúsculas y minúsculas: ISNUMBER(FIND( texto , célula ))

En nuestro conjunto de datos de muestra, para permitir sólo las entradas que contengan el texto "AA" en las celdas A2:A6, utilice una de estas fórmulas:

No distingue entre mayúsculas y minúsculas:

=ISNUMBER(SEARCH("AA", A2))

Se distingue entre mayúsculas y minúsculas:

=ISNUMBER(FIND("AA", A2))

Las fórmulas funcionan con la siguiente lógica:

Se busca la subcadena "AA" en la celda A2 utilizando FIND o SEARCH, y ambos devuelven la posición del primer carácter de la subcadena. Si no se encuentra el texto, se devuelve un error. Para cualquier valor numérico devuelto como resultado de la búsqueda, la función ISNUMBER devuelve TRUE, y la validación de datos se realiza correctamente. En caso de error, ISNUMBER devuelve FALSE, y la entrada no se permitirá en una celda.

Validación de datos para permitir sólo entradas únicas y rechazar duplicados

En situaciones en las que una determinada columna o un rango de celdas no debe contener duplicados, configure una regla de validación de datos personalizada para permitir sólo entradas únicas. Para ello, vamos a utilizar la clásica fórmula COUNTIF para identificar duplicados:

Por ejemplo, para asegurarse de que sólo se introducen identificadores de pedido únicos en las celdas A2 a A6, cree una regla personalizada con esta fórmula de validación de datos:

=COUNTIF($A$2:$A$6, A2)<=1

Cuando se introduce un valor único, la fórmula devuelve TRUE y la validación tiene éxito. Si el mismo valor ya existe en el rango especificado (recuento mayor que 1), COUNTIF devuelve FALSE y la entrada falla la validación.

Preste atención a que bloqueamos el rango con referencias de celda absolutas (A$2:$A$6) y utilizamos una referencia relativa para la celda superior (A2) para conseguir que la fórmula se ajuste correctamente a cada celda del rango validado.

Nota. Estas fórmulas de validación de datos son distingue entre mayúsculas y minúsculas no distingue entre mayúsculas y minúsculas.

Fórmulas de validación de fechas y horas

La validación de fechas incorporada ofrece bastantes criterios predefinidos para restringir a los usuarios la introducción de fechas comprendidas entre las dos fechas especificadas, mayores, menores o iguales a una fecha determinada.

Si desea un mayor control sobre la validación de datos en sus hojas de cálculo, puede replicar la funcionalidad incorporada con una regla personalizada o escribir su propia fórmula que vaya más allá de las capacidades incorporadas de la validación de datos de Excel.

Permitir fechas entre dos fechas

Para limitar la entrada a una fecha dentro de un intervalo especificado, puede utilizar la regla predefinida Fecha con el criterio "entre" o crear una regla de validación personalizada con esta fórmula genérica:

Dónde:

• célula es la celda superior del rango validado, y
• iniciar y fin las fechas son fechas válidas suministradas mediante la función DATE o referencias a celdas que contienen las fechas.

Por ejemplo, para permitir sólo fechas en el mes de julio del año 2017, utilice la siguiente fórmula:

=AND(C2>=DATE(2017,7,1),C2<=DATE(2017,7,31))

O bien, introduzca la fecha de inicio y la fecha final en algunas celdas (F1 y F2 en este ejemplo), y haga referencia a esas celdas en su fórmula:

=AND(C2>=$F$1, C2<=$F$2)

Observe que las fechas límite están bloqueadas con referencias de celda absolutas.

Permitir sólo días laborables o fines de semana

Para restringir que un usuario introduzca sólo días laborables o fines de semana, configure una regla de validación personalizada basada en la función WEEKDAY.

Con el tipo_de_retorno a 2, WEEKDAY devuelve un número entero comprendido entre 1 (lunes) y 7 (domingo). Por lo tanto, para los días laborables (de lunes a viernes) el resultado de la fórmula debe ser inferior a 6, y para los fines de semana (sábados y domingos) superior a 5.

Permitir sólo días laborables :

Permitir sólo fines de semana :

Por ejemplo, para permitir introducir sólo días laborables en las celdas C2:C6, utilice esta fórmula:

=WEEKDAY(C2,2)<6

Validar fechas basándose en la fecha de hoy

En muchas situaciones, es posible que desee utilizar la fecha de hoy como fecha de inicio del intervalo de fechas permitido. Para obtener la fecha actual, utilice la función HOY y, a continuación, añádale el número de días que desee para calcular la fecha final.

Por ejemplo, para limitar la entrada de datos a 6 días a partir de ahora (7 días incluyendo el día de hoy), vamos a utilizar la regla Fecha incorporada con los criterios basados en fórmulas:

1. Seleccione Fecha en el Permitir
2. Seleccione entre en el Datos
3. En el Fecha de inicio introduzca =HOY()
4. En el Fecha final introduzca =HOY() + 6

De forma similar, puede restringir a los usuarios la introducción de fechas anteriores o posteriores a la fecha de hoy. Para ello, seleccione una de las siguientes opciones menos de o superior a en el Datos y, a continuación, introduzca =HOY() en el Fin fecha o Inicio respectivamente.

Validar las horas en función de la hora actual

Para validar los datos en función de la hora actual, utilice la regla predefinida Hora con su propia fórmula de validación de datos:

1. En el Permitir seleccione Tiempo .
2. En el Datos elija menos de para permitir sólo las horas anteriores a la hora actual, o superior a para permitir horas posteriores a la hora actual.
3. En el Hora de finalización o Hora de inicio (dependiendo de los criterios que haya seleccionado en el paso anterior), introduzca una de las fórmulas siguientes:
   • Para validar fechas y horarios en función de la fecha y hora actuales:

     =NOW()

   • Para validar veces en función de la hora actual:

     =TIME( HORA(AHORA()), MINUTO(AHORA()), SEGUNDO(AHORA()))

La siguiente captura de pantalla muestra una regla que sólo permite horas superiores a la hora actual:

La regla de validación de datos personalizada de Excel no funciona

Si su regla de validación de datos basada en fórmulas no funciona como esperaba, hay 3 puntos principales que debe comprobar:

• La fórmula de validación de datos es correcta
• La fórmula de validación no hace referencia a una celda vacía
• Se utilizan las referencias de celda adecuadas

Compruebe si la fórmula de validación de datos de Excel es correcta

Para empezar, copia tu fórmula de validación en alguna celda para asegurarte de que no devuelve un error como #N/A, #VALOR o #DIV/0.

Si está creando un norma personalizada , la fórmula debe devolver los valores lógicos de VERDADERO y FALSO o los valores de 1 y 0 equivalentes a ellos, respectivamente.

Si utiliza un criterio basado en una fórmula en un regla incorporada (como hicimos para validar las horas en función de la hora actual), también puede devolver otro valor numérico.

La fórmula de validación de datos de Excel no debe hacer referencia a una celda vacía

En muchas situaciones, si selecciona la opción Ignorar el espacio en blanco al definir la regla (normalmente seleccionada por defecto) y una o más celdas referenciadas en su fórmula están en blanco, se permitirá cualquier valor en la celda validada.

He aquí un ejemplo de la forma más sencilla:

Referencias absolutas y relativas de celdas en fórmulas de validación de datos

Al configurar una regla de validación de Excel basada en fórmulas, tenga en cuenta que todas las referencias de celda de la fórmula son respecto a la celda superior izquierda en el rango seleccionado.

Si está creando una regla para más de una celda y sus criterios de validación dependen de células específicas Asegúrese de utilizar referencias de celda absolutas (con el signo $ como $A$1), de lo contrario su regla funcionará correctamente sólo para la primera celda. Para ilustrar mejor el punto, por favor considere el siguiente ejemplo.

Supongamos que desea restringir la entrada de datos en las celdas D2 a D5 a números enteros comprendidos entre 1 (valor mínimo) y el resultado de dividir A2 entre B2. Para ello, calcule el valor máximo con esta sencilla fórmula =A2/B2 como se muestra en la siguiente captura de pantalla:

El problema es que esta fórmula aparentemente correcta no funcionará para las celdas D3 a D5 porque las referencias relativas cambian basándose en una posición relativa de filas y columnas. Así, para la celda D3 la fórmula cambiará a =A3/B3 y para D4 será =A4/B4 ...¡haciendo mal la validación de datos!

Para arreglar la fórmula, basta con escribir "$" antes de las referencias de columna y fila para bloquearlas: =$A$2/$B$2 O pulse F4 para alternar entre los distintos tipos de referencia.

En situaciones en las que desee validar cada celda en función de sus propios criterios, utilice referencias de celda relativas sin el signo $ para que la fórmula se ajuste a cada fila y/o columna:

Como ves, no hay una "verdad absoluta", la misma fórmula puede ser correcta o incorrecta dependiendo de la situación y de tu tarea particular.

Así es como se utiliza la validación de datos en Excel con tus propias fórmulas. Para comprenderlo mejor, no dudes en descargar nuestro libro de trabajo de ejemplo que aparece a continuación y examinar la configuración de las reglas. Te doy las gracias por leer y ¡espero verte en nuestro blog la semana que viene!

Cuaderno de prácticas para descargar

Ejemplos de validación de datos en Excel (archivo .xlsx)