Во упатството се гледа како да се користат функциите ISTEXT и ISNONTEXT во Excel за да се провери дали ќелијата содржи текстуална вредност или не.

Секогаш кога ќе треба да добиете информации за содржината на некоја ќелија во Excel, вообичаено би ги користеле таканаречените функции на информации. И ISTEXT и ISNONTEXT припаѓаат на оваа категорија. Функцијата ISTEXT проверува дали вредноста е текст и ISNONTEXT тестира дали вредноста не е текст. Колку и да е едноставен концептот, функциите се неверојатно корисни за решавање на различни задачи во Excel.

Excel ISTEXT функција

Функцијата ISTEXT во Excel проверува е наведената вредност е текст или не. Ако вредноста е текстуална, функцијата враќа TRUE. За сите други типови податоци (како што се броеви, датуми, празни ќелии, грешки итн.) враќа FALSE.

Синтаксата е следнава:

ISTEXT(value)

Каде вредноста е вредност, референца на ќелијата, израз или друга функција чиј резултат сакате да го тестирате.

На пример, за да дознаете дали вредноста во А2 е текст или не, користете ја оваа едноставна формула:

=ISTEXT(A2)

Excel ISNONTEXT функција

Функцијата ISNONTEXT враќа TRUE за која било вредност што не е текстуална, вклучувајќи броеви, датуми и времиња , празни места и други формули кои враќаат нетекстуални резултати или грешки. За вредностите на текстот, враќа FALSE.

Синтаксата е иста како онаа на функцијата ISTEXT:

ISTEXT(value)

На пример, да се провери даливредноста во A2 не е текст, користете ја оваа формула:

=ISNONTEXT(A2)

Како што е прикажано на сликата подолу, формулите ISTEXT и ISNONTEXT ги враќаат спротивните резултати:

ISTEXT и ISNONTEXT функции во Excel - белешки за употреба

ISTEXT и ISNONTEXT се многу јасни и лесни за користење функции и веројатно нема да наидете на какви било тешкотии со нив. Сепак, постојат неколку клучни точки на кои треба да се забележи:

• Двете функции се дел од групата на функции IS кои ги враќаат логичките (булова) вредности на TRUE или FALSE.
• Во конкретен случај кога броевите се зачувани како текст , ISTEXT враќа TRUE, а ISNONTEXT враќа FALSE.
• Двете функции се достапни во сите верзии на Excel за Office 365, Excel 2019, Excel 2016 , Excel 2013, Excel 2010, Excel 2007, Excel 2003, Excel XP и Excel 2000.

Користење ISTEXT и ISNONTEXT во Excel - примери на формула

Подолу ќе најдете примери за практична употреба на функциите ISTEXT и ISNONTEXT во Excel кои се надеваме дека ќе ви помогнат да ги направите вашите работни листови поефикасни.

Проверете дали вредноста е текст

Понекогаш кога работите со куп вредности, може да се изненадите кога ќе забележите дека за некои бројки вашите формули даваат погрешни резултати или дури и грешки. Најочигледната причина е што проблематичните броеви се зачувуваат како текст. Формулите подолу ќе ви кажат со сигурност од кои вредности се текстотгледна точка на Excel.

ISTEXT формула:

Враќа TRUE за која било вредност што Excel ја смета text .

=ISTEXT(B2)

ISNONTEXT формула:

Враќа TRUE за која било вредност што Excel ја смета нетекст .

=ISNONTEXT(B2)

ISTEXT за валидација на податоци : дозволи само текст

Во некои ситуации, можеби ќе сакате да им дозволите на корисниците да внесуваат само текстуални вредности во одредени ќелии. За да го постигнете ова, креирајте правило за валидација на податоци засновано на формула ISTEXT. Еве како:

1. Изберете една или повеќе ќелии што сакате да ги потврдите.
2. На картичката Податоци , во Алатки за податоци група, кликнете на копчето Потврда на податоци .
3. На табулаторот Поставки на полето за дијалог Потврда на податоци , изберете Прилагодено за критериумите за валидација и внесете ја вашата формула ISTEXT во соодветното поле.
4. Кликнете OK за да го зачувате правилото.

За овој пример, ги потврдуваме одговорите на прашалникот во ќелиите B2 преку B4 со помош на оваа формула:

=ISTEXT(B2:B4)

Дополнително, можете да ја конфигурирате вашата сопствена порака Предупредување за грешка за да ја објасните вашите корисници какви податоци се прифаќаат:

Како резултат на тоа, кога корисникот ќе се обиде да внесе број или датум во која било од потврдените ќелии, ќе го види следново предупредување:

За повеќе информации, видете Користење на валидација на податоци во Excel.

Excel IF ISTEXT формула

Во пракса, ISTEXTи ISNONTEXT често се користат заедно со функцијата IF за да се добие резултат попријатен за корисникот од стандардните TRUE и FALSE.

Формула 1. Ако е текст, тогаш

Го земајќи го нашиот прв пример малку подалеку, претпоставувајќи дека сакате да вратите „Да“ за вредностите на текстот и „Не“ за било што друго. За да го направите тоа, едноставно вметнете ја функцијата ISTEXT во логичкиот тест на IF и користете „Да“ и „Не“ за аргументите value_if_true и value_if_false , соодветно:

=IF(ISTEXT(A2), "Yes", "No")

Формула 2. Проверете го влезот на ќелијата

Во еден од претходните примери, разговаравме како да обезбедиме валиден внес на корисникот со користење на валидација на податоци . Ова може да се направи и во „поблага“ форма со помош на формулата Excel IF ISTEXT.

Во прашалникот, да претпоставиме дека сакате да одредите кои одговори се валидни (текст) а кои не (не- текст). За ова, користете ги вгнездените изјави IF со следнава логика:

• Ако тестираната ќелија е празна, не враќајте ништо, т.е. празна низа ("").
• Ако ќелијата е текст, врати „Валиден одговор“.
• Ако ниту едно од горенаведените, вратете „Невалиден одговор - ве молиме внесете текст."

Со сето ова заедно, ја добиваме следната формула , каде што B2 е ќелијата што треба да се провери:

=IF(B2="", "", IF(ISTEXT(B2), "Valid answer", "Invalid answer - please enter text."))

Проверете дали опсегот содржи текст

Досега имаме ја тестираше секоја клетка поединечно. Но, што ако треба да знаете дали некоја ќелија во опсегсодржи текст?

За да го тестирате целиот опсег, комбинирајте ја функцијата ISTEXT со SUMPRODUCT на овој начин:

Како пример, да го провериме секој ред во долунаведената група податоци за вредности на текст, што може да се направи со следните формули:

=SUMPRODUCT(ISTEXT(A2:C2)*1)>0

=SUMPRODUCT(--ISTEXT(A2:C2))>0

Една од горенаведените формули оди во ќелијата D2, а потоа ја влечете надолу низ ќелијата D5.

Значи, сега имате јасно разбирање кои редови содржат една или повеќе текстуални низи (TRUE) и кои содржат само броеви (FALSE).

Ако сакате да вратите различни резултати, кажете „Да“ или „Не“ за разлика од TRUE и FALSE, приложете ја горната формула во изјавата IF:

=IF(SUMPRODUCT(--ISTEXT(A2:C2))>0, "Yes", "No")

Како функционира оваа формула

Формулата се заснова на способноста на SUMPRODUCT да се справува со низи природно. Работејќи од внатре кон надвор, еве што прави:

• Функцијата ISTEXT враќа низа од TRUE и FALSE вредности. За A2:C2, ја добиваме оваа низа:

  {TRUE,TRUE,FALSE}

• Следно, го множиме секој елемент од горната низа со 1 за да ги конвертираме логичките вредности на TRUE и FALSE во 1 и 0, соодветно . За истата цел може да се користи двоен унарен оператор (--). По трансформацијата, формулата ја добива оваа форма:

  SUMPRODUCT({1,1,0})>0

• Функцијата SUMPRODUCT собира 1 и 0, а вие проверувате дали резултатот е поголем од нула. Ако е, опсеготсодржи најмалку една текстуална вредност и формулата враќа TRUE, ако не FALSE.

Проверете дали ќелијата содржи специфичен текст

Функцијата Excel ISTEXT може само да одреди дали ќелијата содржи текст , што значи апсолутно секој текст. За да дознаете дали ќелијата содржи специфична текстуална низа, користете ја формулата ISNUMBER SEARCH или COUNTIF со џокери.

На пример, за да видите дали ID на ставка во A2 го содржи внесувањето на текстуалната низа во ќелијата D2, користете формулата подолу (ве молиме имајте ја апсолутната референца $D$2 што спречува промена на адресата на ќелијата кога формулата се копира во други ќелии):

=ISNUMBER(SEARCH($D$2, A2))

Заради погодност, ние' Ќе го завиткам во функцијата IF:

=IF(ISNUMBER(SEARCH($D$2, A2)), "Yes", "No")

И ќе ги добиете следните резултати:

Истиот резултат може да се постигне со COUNTIF :

=IF(COUNTIF(A2, "*"&$D$2&"*")>0, "Yes", "No")

За повеќе примери, видете Excel Ако ќелијата содржи формули.

Означете ги ќелиите што содржат текст

Функцијата ISTEXT може да се користи и со условно форматирање на Excel за да се означат ќелиите што содржат текстуални вредности. Еве како:

1. Изберете ги сите ќелии што сакате да ги проверите и означите (A2:C5 во овој пример).
2. На картичката Дома , во групата Стилови , кликнете Ново правило > Користете формула за да одредите кои ќелии да се форматираат .
3. Во Вредностите за форматирање каде што оваа формула е вистинита полето, внесете ја формулата подолу:

   =ISTEXT(A2)

   Каде што A2 енајлевата ќелија од избраниот опсег.

4. Кликнете на копчето Формат и изберете го саканото форматирање.
5. Кликнете ОК двапати за да ги затворите двата дијалога и да го зачувате правилото.

За подетално објаснување за секој чекор, погледнете: Користење формули за условно форматирање на Excel.

Како резултат, Excel ги истакнува сите ќелии со која било низа текст:

Така се користат функциите ISTEXT и ISNONTEXT во Excel. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела!

Достапни преземања

Примери на формулата Excel ISTEXT и ISNONTEXT