Содржина
Овој туторијал опфаќа различни начини на користење на функцијата ISNA во Excel за справување со #N/A грешки.
Кога Excel не може да го пронајде она што го бара, #N/ Се појавува грешка во ќелија. За пресретнување и справување со такви грешки, можете да ја користите функцијата ISNA. Која е практичната употреба од тоа? Во суштина, помага да ги направите вашите формули попријателски за корисникот и вашите работни листови да изгледаат поубав.
ISNA функција во Excel
Функцијата Excel ISNA се користи за проверка на ќелиите или формули за #N/A грешки. Резултатот е логичка вредност: ТОЧНО ако се открие грешка #N/A, во спротивно FALSE.
Функцијата е достапна во сите верзии на Excel 2000 до 2021 и Excel 365.
The синтаксата на функцијата ISNA е едноставна како што може да биде:
ISNA(вредност)Каде што вредност е вредноста на ќелијата или формулата што сакате да ја проверите за #N/A грешки.
За да креирате формула ISNA во нејзината основна форма, наведете референца на ќелија како нејзин единствен аргумент:
=ISNA(A2)
Во случај референтната ќелија да содржи грешка #N/A, ќе добиеш ВИСТИНА. Во случај на која било друга грешка, вредност или празна ќелија, ќе добиете FALSE:
Како да користите ISNA во Excel
Користејќи ја функцијата ISNA во својата чиста форма има малку практична смисла. Почесто, се користи заедно со други функции за да се оцени резултатот од одредена формула. За ова, само ставете ја таа друга формула во аргументот вредност на ISNA:
ISNA( your_formula())Во долунаведената база на податоци, да претпоставиме дека сакате да споредите две списоци (колони A и D) и да ги идентификувате имињата што се присутни во двете списоци и оние што се појавуваат само во списокот 1.
За да се спореди името во А3 со секое име во колоната D, формулата е:
=MATCH(A3, $D$2:$D$9, 0)
Ако се најде вредност за пребарување, функцијата MATCH ја враќа својата релативна позиција во низата за пребарување, инаку се појавува грешка #N/A. За да го тестираме резултатот од MATCH, го вгнездуваме во ISNA:
=ISNA(MATCH(A3, $D$2:$D$9, 0))
Оваа формула оди во B3, а потоа се копира преку B14.
Сега, можете јасно види кои ученици ги положиле сите тестови (името не е достапно во колоната D > MATCH враќа #N/A > ISNA враќа TRUE) и кои имаат најмалку еден неуспешен тест (име се појавува во колоната D > нема грешка > ISNA враќа FALSE).
Совет. Во Excel 365 и Excel 2021, можете да користите помодерна функција XMATCH. наместо MATCH.
АКО формулата ISNA во Excel
Според дизајнот, функцијата ISNA може да врати само две Булови вредности. За да ги прикажете вашите сопствени пораки, користете го во комбинација со функцијата IF:
IF(ISNA(…), „ text_if_error“, „ text_if_no_error“)Рафинирање на нашата пример малку понатаму, да дознаеме кои ученици од групата А не паднале на ниту еден тест и да им вратиме „Нема неуспешни тестови“. За останатите студенти, ќе го вратиме „Неуспешно“. За да го направите ова, вметнете ја формулата ISNA MATCH вологичкиот тест на IF, така што IF станува најоддалечената функција:
=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "No failed tests", "Failed")
Резултатите сега изгледаат многу подобри и поинтуитивни, се согласувате?
Како да се користи ISNA во Excel со VLOOKUP
Комбинацијата IF ISNA е универзално решение што може да се користи со која било функција која бара нешто во збир на податоци и враќа грешка #N/A кога не е пронајдена вредност за пребарување.
Синтаксата на функцијата ISNA со VLOOKUP е следна:
IF(ISNA(VLOOKUP(…), " прилагоден_текст", VLOOKUP( …))Преведено на човечки јазик, вели: ако VLOOKUP резултира со грешка #N/A, вратете го приспособениот текст, инаку вратете го резултатот од VLOOKUP.
Во нашата табела примерок, претпоставете дека сакате да вратете ги предметите во кои учениците не успеале. 3>
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
И потоа вгнездувајте го во генеричката формула IF ISNA дискутирана погоре:
75 67
Во Excel 2013 и понова верзија, можете да ја користите функцијата IFNA за фаќање и справување со #N/A грешки. Ова ја прави вашата формула пократка и полесна за читање.
Како пример, ги заменуваме #N/A грешките со цртички ("-") и го добиваме ова елегантно решение:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")
На корисниците на Excel 365 и 2021 воопшто не им е потребна никаква функција на обвивка како модерен наследник на VLOOKUP,Функцијата XLOOKUP, може природно да се справи со #N/A грешки:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")
Резултатот ќе биде потполно ист како што е прикажан на сликата погоре.
SUMPRODUCT ISNA формула за броење #N/A errors
За броење #N/A грешки во одреден опсег, користете ја функцијата ISNA заедно со SUMPRODUCT на овој начин:
SUMPRODUCT(--ISNA( опсег ))Овде, ISNA враќа низа од TRUE и FALSE вредности, двојната негација (--) ги принудува логичките вредности во 1 и 0, а SUMPRODUCT го собира резултатот.
На пример, на дознајте колку студенти успеале во сите тестови, изменете ја формулата MATCH за опсег на вредности за пребарување (A3:A14) и вгнездувајте ја во ISNA:
=SUMPRODUCT(--ISNA(MATCH(A3:A14, D2:D9, 0)))
Формулата одредува дека 9 ученици немате неуспешни тестови, односно функцијата MATCH враќа 9 #N/A грешки:
Така се креираат и користат формули ISNA во Excel. Ви благодарам што прочитавте и со нетрпение очекувам да се видиме на нашиот блог следната недела!
Достапни преземања
Примери на формула ISNA (датотека .xlsx)
