Kennslan sýnir hvernig á að nota IF ásamt AND fallinu í Excel til að athuga mörg skilyrði í einni formúlu.

Sumt í heiminum er endanlegt. Aðrir eru óendanlegir og IF-fallið virðist vera eitt af slíkum hlutum. Á blogginu okkar erum við nú þegar með handfylli af Excel IF kennsluefni og uppgötvum enn nýja notkun á hverjum degi. Í dag ætlum við að skoða hvernig þú getur notað IF ásamt AND fallinu til að meta tvö eða fleiri skilyrði á sama tíma.

IF AND staðhæfing í Excel

Til þess að búa til IF AND setninguna þarftu augljóslega að sameina IF og AND föllin í einni formúlu. Svona:

Þýtt á venjulega ensku, formúlan hljóðar sem hér segir: IF ástand 1 er satt OG skilyrði 2 er satt, gerðu eitt, annars gerðu eitthvað annað.

Sem dæmi skulum við búa til formúlu sem athugar hvort B2 sé "afhent" og C2 sé ekki tómt, og allt eftir niðurstöðum , gerir eitt af eftirfarandi:

• Ef bæði skilyrðin eru TRUE, merktu pöntunina sem "Lokað".
• Ef annað hvort skilyrðið er FALSE eða bæði FALSE, þá skilaðu auðu streng ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

Skjámyndin hér að neðan sýnir EF OG aðgerðina í Excel:

Ef þú langar að skila einhverju gildi ef rökrétta prófið metur á FALSE, gefðu upp gildið í value_if_false rök. Til dæmis:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

Breytta formúlan gefur út „Lokað“ ef dálkur B er „afhentur“ og C hefur einhverja dagsetningu í sér (ekki auð). Í öllum öðrum tilvikum skilar það „Opið“:

Athugið. Þegar þú notar EF OG formúlu í Excel til að meta textaskilyrði, vinsamlegast hafðu í huga að litið er á lágstafi og hástafi sem sama staf. Ef þú ert að leita að IF AND formúlu sem er há- og hástöfumnæm skaltu setja eina eða fleiri rök fyrir AND inn í EXACT fallið eins og það er gert í tengda dæminu.

Nú þegar þú veist setningafræði Excel IF AND setningarinnar, leyfðu mér að sýna þér hvers konar verkefni hún getur leyst.

Excel IF: stærra en OG minna en

Í fyrra dæmi, við vorum að prófa tvær aðstæður í tveimur mismunandi frumum. En stundum gætir þú þurft að keyra tvö eða fleiri próf á sama reitnum. Dæmigerð dæmi er að athuga hvort hólfsgildi sé á milli tveggja talna . Excel EF OG aðgerðin getur auðveldlega gert það líka!

Segjum að þú hafir einhverjar sölutölur í dálki B og þú ert beðinn um að merkja upphæðir sem eru hærri en $50 en minna en $100. Til að gera það, settu þessa formúlu inn í C2 og afritaðu hana síðan niður í dálkinn:

=IF(AND(B2>50, B2<100), "x", "")

Ef þú þarft að taka með mörkin gildi (50 og 100), notaðu minna en eða jafnt og (<=) og stærri en eða jafnt og (>=) rekstraraðila:

=IF(AND(B2>=50, B2<=100), "x", "")

Til að vinna úr einhverju öðrumörk gildi án þess að breyta formúlunni, sláðu inn lágmarks- og hámarkstölur í tveimur aðskildum hólfum og vísaðu til þeirra hólfa í formúlunni þinni. Til að formúlan virki rétt í öllum línum, vertu viss um að nota algjörar tilvísanir fyrir afmörkunarhólf ($F$1 og $F$2 í okkar tilfelli):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Með því að nota svipaða formúlu geturðu athugað hvort dagsetning sé innan tiltekins bils .

Til dæmis skulum við flagga dagsetningar á milli 10 -sep-2018 og 30-sep-2018, að meðtöldum. Lítil hindrun er sú að ekki er hægt að láta dagsetningar beint í rökrænu prófin. Til þess að Excel skilji dagsetningarnar ættu þær að vera innifaldar í DATEVALUE fallinu, svona:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Eða einfaldlega sláðu inn Frá og Til dagsetningar í tveimur hólfum ($F$1 og $F$2 í þessu dæmi) og „dragið“ þær úr þeim hólfum með því að nota þegar kunnuglega IF AND formúluna:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Nánari upplýsingar er að finna í Excel IF yfirlýsingu á milli tveggja talna eða dagsetninga.

EF þetta OG hitt, þá reiknaðu eitthvað

Fyrir utan að skila fyrirframskilgreindum gildum, Excel IF AND aðgerð getur einnig framkvæmt mismunandi útreikninga eftir því hvort tilgreind skilyrði eru SÖNN eða FALSK.

Til að sýna fram á nálgunina munum við reikna út 5% bónus fyrir "Lokað" sölu með upphæð sem er hærri en eða jöfn í $100.

Að því gefnu að upphæðin sé í dálki B og pöntunarstaðan í dálki C,formúlan er sem hér segir:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

Oftangreind formúla gefur restinni af skipunum núll ( value_if_false = 0) . Ef þú ert tilbúinn að gefa smá örvandi bónus, segjum 3%, fyrir pantanir sem uppfylla ekki skilyrðin skaltu setja samsvarandi jöfnu í gildi_ef_false röksemdin:

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

Margar EF OG staðhæfingar í Excel

Eins og þú hefur kannski tekið eftir höfum við aðeins metið tvö viðmið í öllum ofangreindum dæmum. En það er ekkert sem hindrar þig í að setja þrjú og fleiri próf inn í EF OG formúlurnar þínar svo framarlega sem þær eru í samræmi við þessar almennu takmarkanir Excel:

• Í Excel 2007 og hærri, allt að 255 rök hægt að nota í formúlu, með heildarlengd formúlu ekki yfir 8.192 stafi.
• Í Excel 2003 og lægri eru ekki fleiri en 30 rök leyfð, með heildarlengd ekki yfir 1.024 stafi.

Sem dæmi um mörg OG skilyrði skaltu íhuga þessi:

• Upphæð (B2) ætti að vera hærri en eða jafnt og $100
• Pöntunarstaða (C2) er "Lokað"
• Afhendingardagur (D2) er innan yfirstandandi mánaðar

Nú þurfum við EF OG yfirlýsingu til að auðkenna pantanir þar sem öll 3 skilyrðin eru SÖNN. Og hér er það:

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

Í ljósi þess að „núverandi mánuður“ þegar þetta var skrifað var október, skilar formúlan eftirfarandi niðurstöðum:

Hreiður EF OGstaðhæfingar

Þegar unnið er með stór vinnublöð eru líkurnar á því að þú þurfir að athuga nokkur sett af mismunandi OG viðmiðum í einu. Fyrir þetta tekur þú klassíska Excel-hreiðra IF formúlu og útvíkkar rökrétt próf hennar með OG setningum, svona:

Til að fá almenna hugmynd, vinsamlegast skoðaðu eftirfarandi dæmi.

Segjum sem svo að þú viljir meta þjónustu þína út frá sendingarkostnaði og áætluðum afhendingartíma (ETD):

• Frábært : sendingarkostnaður undir $20 og ETD undir 3 dögum
• Slæmt : sendingarkostnaður yfir $30 og ETD á 5 dögum
• Meðaltal : allt þar á milli

Til klára það, þú skrifar tvær einstakar EF OG staðhæfingar:

IF(AND(B2<20, C2<3), "Excellent", …)

IF(AND(B2>30, C2>5), "Poor", …)

...og hreiður hverja inn í aðra:

=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

Niðurstaðan mun líta svipað út og þessi:

Fleiri formúludæmi er að finna í Excel hreiðrum EF OG setningum.

Látahá og hástöfum EF OG virka í Excel

Eins og getið er um í upphafi þessarar kennslu, þá gera Excel EF OG formúlur ekki greinarmun á hástöfum og lágstöfum vegna þess að AND fallið er eðli málsins samkvæmt.

Ef þú ert að vinna með hástafanæm gögn og vilt meta AND aðstæður með hliðsjón af stórum og hástöfum, gerðu hvert einstakt rökrétt próf inni í EXACT fallinu og hreiðurþessar aðgerðir inn í AND setninguna þína:

Í þessu dæmi ætlum við að flagga pantanir tiltekins viðskiptavinar (t.d. fyrirtækis sem heitir Cyberspace ) með upphæð sem fer yfir ákveðinn fjölda, td. $100.

Eins og þú sérð á skjámyndinni hér að neðan, líta sum fyrirtækjanöfn í dálki B út eins útdráttur og stafirnir, og engu að síður eru þetta mismunandi fyrirtæki, svo við verðum að athuga nöfnin nákvæmlega . Upphæðirnar í dálki C eru tölur og við keyrum reglulegt „stærra en“ próf fyrir þær:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Til að gera formúluna sveigjanlegri geturðu sett inn nafn viðskiptavinar og upphæð í tveimur aðskildum frumum og vísa til þeirra fruma. Mundu bara að læsa frumutilvísunum með $ merki ($G$1 og $G$2 í okkar tilfelli) svo þær breytist ekki þegar þú afritar formúluna í aðrar raðir:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Nú geturðu slegið inn hvaða nafn og upphæð sem er í reitunum sem vísað er til og formúlan mun flagga samsvarandi pöntunum í töflunni þinni:

EF EÐA OG formúla í Excel

Í Excel IF formúlum ertu ekki takmörkuð við að nota aðeins eina rökræna aðgerð. Til að athuga ýmsar samsetningar margra skilyrða, er þér frjálst að sameina EF, OG, EÐA og aðrar aðgerðir til að keyra nauðsynleg rökfræðileg próf. Hér er dæmi um EF OG EÐA formúlu sem prófar nokkraOR skilyrði innan OG. Og nú mun ég sýna þér hvernig þú getur gert tvær eða fleiri OG prófanir innan OR fallsins.

Svo sem þú vilt merkja pantanir tveggja viðskiptavina með upphæð sem er hærri en ákveðin tala, segjum $100.

Í Excel tungumálinu eru skilyrði okkar sett fram á þennan hátt:

OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

Að því gefnu að nöfn viðskiptavina séu í dálki B, upphæðir í dálki C, 2 marknöfnin eru í G1 og G2, og markupphæðin er í G3, notarðu þessa formúlu til að merkja samsvarandi pantanir með "x":

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Sama árangri er hægt að ná með meiri samningur setningafræði:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

Ertu ekki viss um að þú skiljir alveg rökfræði formúlunnar? Frekari upplýsingar er að finna í Excel EF með mörgum OG/EÐA skilyrðum.

Þannig notarðu EF og OG aðgerðirnar saman í Excel. Takk fyrir að lesa og sjáumst í næstu viku!

Æfingabók

IF OG Excel – formúludæmi (.xlsx skrá)