Падручнік паказвае, як выкарыстоўваць IF разам з функцыяй AND у Excel для праверкі некалькіх умоў у адной формуле.

Некаторыя рэчы ў свеце канечныя. Іншыя бясконцыя, і функцыя IF, здаецца, адна з такіх рэчаў. У нашым блогу ў нас ужо ёсць некалькі падручнікаў па Excel IF, і мы кожны дзень адкрываем для сябе новыя спосабы выкарыстання. Сёння мы разгледзім, як вы можаце выкарыстоўваць КАЛІ разам з функцыяй І для адначасовай ацэнкі дзвюх або больш умоў.

Аператар КАЛІ І ў Excel

Каб пабудаваць аператар КАЛІ І, вам, відавочна, трэба аб'яднаць функцыі КАЛІ і І ў адну формулу. Вось як:

У перакладзе на простую англійскую мову формула гучыць наступным чынам: IF ўмова 1 праўдзіва І ўмова 2 праўдзівая, зрабіце адно, інакш зрабіце што-небудзь іншае.

У якасці прыкладу давайце створым формулу, якая правярае, ці "дастаўлены" B2, а C2 не пусты, і ў залежнасці ад вынікаў , выконвае адно з наступнага:

• Калі абедзве ўмовы ПРАЎДНЫЯ, пазначце заказ як "Закрыты".
• Калі адно з умоў ХЛУСНЯ або абодва ХЛУСНЯ, вяртае пусты радок ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

На скрыншоце ніжэй паказана функцыя КАЛІ І ў Excel:

Калі вы Хацеў бы вярнуць нейкае значэнне ў выпадку, калі лагічны тэст дае ацэнку FALSE, увядзіце гэта значэнне ў value_if_false аргумент. Напрыклад:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

Змененая формула выводзіць «Закрыта», калі слупок B «дастаўлены», а ў C ёсць любая дата (не пустая). Ва ўсіх астатніх выпадках ён вяртае "Адкрыць":

Заўвага. Пры выкарыстанні формулы КАЛІ І ў Excel для ацэнкі ўмоў тэксту майце на ўвазе, што малыя і вялікія літары разглядаюцца як адзін і той жа сімвал. Калі вы шукаеце формулу IF AND з улікам рэгістра, перанясіце адзін або некалькі аргументаў AND у функцыю EXACT, як гэта зроблена ў прыкладзе па спасылцы.

Цяпер, калі вы ведаеце сінтаксіс аператара Excel IF AND, дазвольце мне паказаць вам, якія задачы ён можа вырашаць.

Excel IF: больш І менш

У у папярэднім прыкладзе мы тэставалі два ўмовы ў двух розных вочках. Але часам вам можа спатрэбіцца выканаць два або больш тэстаў на адной ячэйцы. Тыповы прыклад - праверка таго, ці знаходзіцца значэнне ячэйкі паміж дзвюма лічбамі . Функцыя Excel IF AND таксама можа лёгка зрабіць гэта!

Дапусцім, у вас ёсць некаторыя лічбы продажаў у слупку B, і вас просяць пазначыць сумы, большыя за 50 долараў, але меншыя за 100 долараў. Каб зрабіць гэта, устаўце гэту формулу ў C2, а потым скапіруйце яе ў слупок:

=IF(AND(B2>50, B2<100), "x", "")

Калі вам трэба ўключыць мяжу значэнні (50 і 100), выкарыстоўвайце аператар менш або роўна (<=) і больш або роўна (>=):

=IF(AND(B2>=50, B2<=100), "x", "")

Апрацаваць некаторыя іншыямежавыя значэнні, не змяняючы формулу, увядзіце мінімальныя і максімальныя лічбы ў дзве асобныя ячэйкі і спасылайцеся на гэтыя ячэйкі ў сваёй формуле. Каб формула карэктна працавала ва ўсіх радках, абавязкова выкарыстоўвайце абсалютныя спасылкі для межавых вочак ($F$1 і $F$2 у нашым выпадку):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Выкарыстоўваючы падобную формулу, вы можаце праверыць, ці трапляе дата у вызначаны дыяпазон .

Напрыклад, давайце пазначым даты паміж 10 -вер-2018 і 30-вер-2018, уключна. Невялікай перашкодай з'яўляецца тое, што даты не могуць быць пастаўлены непасрэдна ў лагічныя тэсты. Каб Excel мог разумець даты, яны павінны быць заключаны ў функцыю DATEVALUE, напрыклад:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Або проста ўвядзіце Ад і Да даты ў дзвюх ячэйках ($F$1 і $F$2 у гэтым прыкладзе) і "выцягнуць" іх з гэтых ячэек, выкарыстоўваючы ўжо знаёмую формулу КАЛІ І:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Для атрымання дадатковай інфармацыі, калі ласка, глядзіце аператар Excel IF паміж дзвюма лічбамі або датамі.

КАЛІ гэта І гэта, то нешта вылічыць

Акрамя вяртання загадзя вызначаных значэнняў, Excel IF Функцыя AND таксама можа выконваць розныя вылічэнні ў залежнасці ад таго, ці з'яўляюцца ўказаныя ўмовы TRUE або FALSE.

Каб прадэманстраваць гэты падыход, мы будзем разлічваць бонус у памеры 5% для "Закрытых" продажаў з сумай большай або роўнай да $100.

Калі выказаць здагадку, што сума знаходзіцца ў слупку B, а статус заказу - у слупку C,формула выглядае наступным чынам:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

Прыведзеная вышэй формула прысвойвае нуль астатнім парадкам ( value_if_false = 0) . Калі вы жадаеце даць невялікі стымулюючы бонус, скажам, 3%, заказам, якія не адпавядаюць умовам, уключыце адпаведнае ўраўненне ў аргумент value_if_false :

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

Некалькі аператараў IF AND у Excel

Як вы маглі заўважыць, ва ўсіх прыведзеных вышэй прыкладах мы ацанілі толькі два крытэрыі. Але няма нічога, што перашкодзіла б вам уключыць тры і больш тэстаў у свае формулы КАЛІ І, калі яны адпавядаюць гэтым агульным абмежаванням Excel:

• У Excel 2007 і вышэй, да 255 аргументаў можа быць выкарыстаны ў формуле з агульнай даўжынёй формулы, якая не перавышае 8192 сімвалаў.
• У Excel 2003 і ніжэйшых версіях дазваляецца не больш за 30 аргументаў, агульная даўжыня якіх не перавышае 1024 сімвалы.

У якасці прыкладу некалькіх умоў І, калі ласка, разгледзьце наступныя:

• Сума (B2) павінна быць большай або роўнай $100
• Статус замовы (C2) "Закрыта"
• Дата дастаўкі (D2) знаходзіцца ў межах бягучага месяца

Цяпер нам патрэбны аператар IF AND для ідэнтыфікацыі заказаў, для якіх усе 3 умовы праўдзівыя. І вось яно:

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

Улічваючы, што «бягучым месяцам» на момант напісання артыкула быў кастрычнік, формула дае наступныя вынікі:

Укладзенае КАЛІ Ізаявы

Пры працы з вялікімі аркушамі вялікая верагоднасць таго, што вам можа спатрэбіцца праверыць некалькі набораў розных крытэраў І адначасова. Для гэтага вы возьмеце класічную ўкладзеную формулу Excel IF і пашырыце яе лагічныя тэсты з дапамогай оператораў І, напрыклад:

Каб атрымаць агульнае ўяўленне, паглядзіце наступны прыклад.

Выкажам здагадку, што вы жадаеце ацаніць сваю паслугу на аснове кошту дастаўкі і разліковага часу дастаўкі (ETD):

• Выдатна : кошт дастаўкі менш за 20 долараў і ETD менш за 3 дні
• Дрэнна : кошт дастаўкі перавышае 30 долараў ЗША і ETD за 5 дзён
• Сярэдняе : усё паміж

Да каб зрабіць гэта, вы пішаце два асобных аператара IF AND:

IF(AND(B2<20, C2<3), "Excellent", …)

IF(AND(B2>30, C2>5), "Poor", …)

…і ўкладваеце адзін у другі:

=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

Вынік будзе выглядаць прыкладна так:

Больш прыкладаў формул можна знайсці ва ўкладзеных аператарах IF І Excel.

Калі І з улікам рэгістра функцыя ў Excel

Як згадвалася ў пачатку гэтага падручніка, формулы Excel IF AND не адрозніваюць сімвалы ў верхнім і малым рэгістры таму што функцыя І па сваёй прыродзе неадчувальная да рэгістра.

Калі вы працуеце з дадзенымі адчувальнымі да рэгістра і жадаеце ацаніць умовы І з улікам рэгістра тэксту, выканайце кожны асобны лагічны тэст ўнутры функцыі EXACT і гняздагэтыя функцыі ў ваш оператор AND:

У гэтым прыкладзе мы будзем пазначаць заказы канкрэтнага кліента (напрыклад, кампаніі пад назвай Cyberspace ) з сумай, якая перавышае пэўную лічбу, скажам $100.

Як вы бачыце на скрыншоце ніжэй, некаторыя назвы кампаній у слупку B выглядаюць аднолькава, урыўкі з рэгістрам сімвалаў, і, тым не менш, гэта розныя кампаніі, таму мы павінны праверыць назвы дакладна . Сумы ў слупку C з'яўляюцца лічбамі, і мы праводзім рэгулярны тэст "больш за" для іх:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Каб зрабіць формулу больш гнуткай, вы можаце ўвесці імя мэтавага кліента і суму у дзвюх асобных клетках і спасылацца на гэтыя клеткі. Толькі не забудзьце зафіксаваць спасылкі на ячэйкі знакам $ ($G$1 і $G$2 у нашым выпадку), каб яны не змяніліся пры капіраванні формулы ў іншыя радкі:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Цяпер вы можаце ўвесці любое імя і суму ў ячэйкі, на якія спасылаюцца, і формула пазначыць адпаведныя парадкі ў вашай табліцы:

Формула КАЛІ АБО І ў Excel

У формулах Excel IF вы не абмежаваныя выкарыстаннем толькі адной лагічнай функцыі. Каб праверыць розныя камбінацыі некалькіх умоў, вы можаце камбінаваць IF, AND, OR і іншыя функцыі для выканання неабходных лагічных тэстаў. Вось прыклад формулы КАЛІ І АБО, якая правярае паруАБО ўмовы ў І. А зараз я пакажу вам, як вы можаце выканаць два або больш тэстаў І ў межах функцыі АБО.

Выкажам здагадку, што вы жадаеце пазначыць заказы двух кліентаў сумай, большай за пэўную лічбу, скажам, 100 долараў.

На мове Excel нашы ўмовы выражаюцца наступным чынам:

OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

Калі выказаць здагадку, што імёны кліентаў знаходзяцца ў слупку B, сумы ў слупку C, 2 мэтавыя імёны знаходзяцца ў G1 і G2, а мэтавая сума знаходзіцца ў G3, вы выкарыстоўваеце гэтую формулу, каб пазначыць адпаведныя заказы знакам "x":

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Тых жа вынікаў можна дасягнуць з больш кампактны сінтаксіс:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

Не ўпэўнены, што вы цалкам разумееце логіку формулы? Дадатковую інфармацыю можна знайсці ў Excel IF з некалькімі ўмовамі І/АБО.

Вось як вы разам выкарыстоўваеце функцыі IF і AND у Excel. Дзякуй за чытанне і да сустрэчы на ​​наступным тыдні!

Практычны сшытак

IF AND Excel – прыклады формул (.xlsx файл)