Jedwali la yaliyomo
Mafunzo yanaonyesha jinsi ya kutumia IF pamoja na kitendakazi cha AND katika Excel ili kuangalia hali nyingi katika fomula moja.
Baadhi ya vitu duniani vina ukomo. Nyingine hazina kikomo, na kazi ya IF inaonekana kuwa moja ya vitu kama hivyo. Kwenye blogu yetu, tayari tuna mafunzo machache ya Excel IF na bado tunagundua matumizi mapya kila siku. Leo, tutaangalia jinsi unavyoweza kutumia IF pamoja na kitendakazi cha AND kutathmini hali mbili au zaidi kwa wakati mmoja.
IF AND statement in Excel
Ili kuunda IF AND taarifa, ni wazi unahitaji kuchanganya IF na AND kazi katika fomula moja. Hivi ndivyo jinsi:
IF(AND( condition1, condition2,…), value_if_true, value_if_false)Ikitafsiriwa kwa Kiingereza cha kawaida, fomula inasomeka hivi: IF sharti 1 ni kweli NA sharti la 2 ni kweli, fanya jambo moja, la sivyo fanya jambo lingine.
Kwa mfano, hebu tutengeneze fomula inayoangalia ikiwa B2 "imewasilishwa" na C2 haina tupu, na kulingana na matokeo. , hufanya mojawapo ya yafuatayo:
- Ikiwa masharti yote mawili ni KWELI, weka alama kwenye mpangilio kama "Imefungwa".
- Ikiwa sharti mojawapo ni UONGO au zote mbili ni UONGO, basi rudisha tupu. mfuatano ("").
=IF(AND(B2="delivered", C2""), "Closed", "")
Picha ya skrini iliyo hapa chini inaonyesha IF AND kazi katika Excel:
Ikiwa Ningependa kurudisha thamani fulani endapo jaribio la kimantiki litatathmini kwa FALSE, toa thamani hiyo katika value_if_false hoja. Kwa mfano:
=IF(AND(B2="delivered", C2""), "Closed", "Open")
Mfumo wa matokeo uliobadilishwa "Imefungwa" ikiwa safu wima B "imewasilishwa" na C ina tarehe yoyote ndani yake (isiyo wazi). Katika visa vingine vyote, inarudisha "Fungua":
Kumbuka. Unapotumia fomula ya IF AND katika Excel kutathmini hali ya maandishi, tafadhali kumbuka kuwa herufi ndogo na kubwa huchukuliwa kama herufi sawa. Ikiwa unatafuta fomula nyeti ya kesi IF AND, funga hoja moja au zaidi ya NA kwenye kitendakazi EXACT kama inavyofanywa katika mfano uliounganishwa.
Kwa kuwa sasa unajua sintaksia ya Excel IF AND statement, hebu nikuonyeshe ni aina gani ya kazi inaweza kutatua.
Excel IF: great than AND less than
Katika mfano uliopita, tulikuwa tukijaribu hali mbili katika seli mbili tofauti. Lakini wakati mwingine unaweza kuhitaji kufanya majaribio mawili au zaidi kwenye seli moja. Mfano wa kawaida ni kuangalia kama thamani ya seli ni kati ya nambari mbili . Chaguo la kukokotoa la Excel IF AND linaweza kufanya hivyo pia kwa urahisi!
Tuseme una baadhi ya nambari za mauzo katika safu wima B na unaombwa kuripoti kiasi kikubwa zaidi ya $50 lakini chini ya $100. Ili kuifanya, weka fomula hii katika C2 na kisha unakili chini ya safu wima:
=IF(AND(B2>50, B2<100), "x", "")
Ikiwa unahitaji kujumuisha mpaka thamani (50 na 100), tumia chini ya au sawa na opereta (<=) na kubwa kuliko au sawa na (>=) opereta:
=IF(AND(B2>=50, B2<=100), "x", "")
Ili kuchakata zinginethamani za mipaka bila kubadilisha fomula, weka nambari za chini na za juu zaidi katika seli mbili tofauti na urejelee visanduku hivyo katika fomula yako. Ili fomula ifanye kazi ipasavyo katika safu mlalo zote, hakikisha unatumia marejeleo kamili kwa visanduku vya mpaka ($F$1 na $F$2 kwa upande wetu):
=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")
Kwa kutumia fomula sawa, unaweza kuangalia kama tarehe iko ndani ya masafa maalum .
Kwa mfano, hebu turipoti tarehe kati ya 10 -Sep-2018 na 30-Sep-2018, pamoja. Kikwazo kidogo ni kwamba tarehe haziwezi kutolewa kwa majaribio ya kimantiki moja kwa moja. Ili Excel kuelewa tarehe, zinapaswa kuambatanishwa katika chaguo la kukokotoa la DATEVALUE, kama hii:
=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")
Au ingiza tu Kutoka na Hadi tarehe katika visanduku viwili ($F$1 na $F$2 katika mfano huu) na "kuzivuta" kutoka kwa visanduku hivyo kwa kutumia IF AND formula ambayo tayari inajulikana:
=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")
Kwa maelezo zaidi, tafadhali angalia taarifa ya Excel IF kati ya nambari mbili au tarehe.
IKIWA hii na ile, basi hesabu kitu
Mbali na kurejesha thamani zilizoainishwa awali, Excel IF Utendakazi wa AND unaweza pia kufanya hesabu tofauti kulingana na masharti yaliyobainishwa ni KWELI au SIYO.
Ili kuonyesha mbinu, tutakuwa tukikokotoa bonasi ya 5% ya mauzo "Yaliyofungwa" yenye kiasi kikubwa kuliko au sawa. hadi $100.
Ikizingatiwa kuwa kiasi kiko kwenye safu wima B na hali ya mpangilio katika safu wima C,fomula inakwenda kama ifuatavyo:
=IF(AND(B2>=100, C2="closed"), B2*10%, 0)
Mfumo ulio hapa juu unaweka sifuri kwa maagizo mengine ( thamani_if_false = 0) . Ikiwa uko tayari kutoa bonasi ndogo ya kusisimua, sema 3%, kwa maagizo ambayo hayatimizi masharti, jumuisha mlingano unaolingana katika hoja ya value_if_false :
=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)
Ikiwa na kauli nyingi katika Excel
Kama unavyoweza kuwa umeona, tumetathmini vigezo viwili pekee katika mifano yote iliyo hapo juu. Lakini hakuna kitu ambacho kingekuzuia kujumuisha majaribio matatu na zaidi katika IF AND formula yako mradi tu yanatii vikwazo hivi vya jumla vya Excel:
- Katika Excel 2007 na zaidi, hadi hoja 255. inaweza kutumika katika fomula, yenye urefu wa jumla wa fomula isiyozidi vibambo 8,192.
- Katika Excel 2003 na chini, si zaidi ya hoja 30 zinazoruhusiwa, zenye urefu wa jumla usiozidi vibambo 1,024. 5>
- Kiasi (B2) kinapaswa kuwa kikubwa kuliko au sawa na $100
- Hali ya agizo (C2) ni "Imefungwa"
- Tarehe ya uwasilishaji (D2) iko ndani ya mwezi wa sasa
- Nzuri zaidi : gharama ya usafirishaji chini ya $20 na ETD chini ya siku 3
- Maskini : usafirishaji unagharimu zaidi ya $30 na ETD kwa siku 5
- Wastani : chochote kati ya
Kama mfano wa nyingi NA masharti, tafadhali zingatia haya:
Sasa, tunahitaji taarifa ya IF NA ili kutambua maagizo ambayo masharti yote 3 ni KWELI. Na hii hapa:
=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")
Kwa kuzingatia kwamba 'mwezi wa sasa' wakati wa kuandika ulikuwa Oktoba, fomula inatoa matokeo hapa chini:
Imewekwa IF NAkauli
Unapofanya kazi na lahakazi kubwa, kuna uwezekano kwamba utahitajika kuangalia seti chache za NA vigezo tofauti kwa wakati mmoja. Kwa hili, unachukua fomula ya kawaida ya Excel iliyoorodheshwa ya IF na kupanua majaribio yake ya kimantiki kwa AND taarifa, kama hii:
IF(AND(…), output1 , IF(AND(…), output2 , IF(AND(…), output3 , output4 )))Ili kupata wazo la jumla, tafadhali angalia mfano ufuatao.
Tuseme unataka kukadiria huduma yako kulingana na gharama ya usafirishaji na makadirio ya muda wa kujifungua (ETD):
Kwa kamilisha, unaandika taarifa mbili za IF NA taarifa:
IF(AND(B2<20, C2<3), "Excellent", …)
IF(AND(B2>30, C2>5), "Poor", …)
...na kuweka moja kwenye nyingine:
=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))
Matokeo yatafanana na haya:
Mifano zaidi ya fomula inaweza kupatikana katika Excel iliyoorodheshwa IF NA kauli.
Inajali kesi IF NA kazi katika Excel
Kama ilivyotajwa mwanzoni mwa mafunzo haya, Excel IF NA fomula hazitofautishi kati ya herufi kubwa na ndogo. kwa sababu kitendakazi cha AND hakijali kisa kwa asili.
Ikiwa unafanya kazi na data nyeti na unataka kutathmini NA masharti kwa kuzingatia kisa cha maandishi, fanya kila jaribio la kimantiki. ndani ya kitendakazi EXACT na kiotakazi hizo kwenye NA taarifa yako:
Kwa mfano huu, tutaripoti maagizo ya mteja mahususi (k.m. kampuni inayoitwa Cyberspace ) na kiasi kinachozidi idadi fulani, sema. $100.
Kama unavyoona katika picha ya skrini iliyo hapa chini, baadhi ya majina ya kampuni katika safu wima B yanafanana na dondoo la herufi, na hata hivyo ni makampuni tofauti, kwa hivyo inabidi tuangalie majina haswa . Kiasi katika safu wima C ni nambari, na tunazifanyia jaribio la kawaida "kubwa kuliko":
=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")
Ili kufanya fomula inyumbulike zaidi, unaweza kuweka jina na kiasi cha mteja lengwa. katika seli mbili tofauti na kurejelea seli hizo. Kumbuka tu kufunga marejeleo ya seli kwa ishara ya $ ($G$1 na $G$2 katika kesi yetu) ili yasibadilike unaponakili fomula kwenye safu mlalo nyingine:
=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")
Sasa, unaweza kuandika jina na kiasi chochote katika visanduku vilivyorejelewa, na fomula itaalamisha maagizo yanayolingana katika jedwali lako:
IF AU NA fomula katika Excel
Katika fomula za Excel IF, hauzuiliwi kutumia tu chaguo za kukokotoa za kimantiki. Ili kuangalia michanganyiko mbalimbali ya hali nyingi, uko huru kuchanganya IF, NA, AU na vitendaji vingine ili kuendesha majaribio ya kimantiki yanayohitajika. Huu hapa ni mfano wa IF NA AU fomula inayojaribu michacheAU hali ndani ya NA. Na sasa, nitakuonyesha jinsi unavyoweza kufanya majaribio mawili au zaidi NA majaribio ndani ya kitendakazi cha AU.
Tuseme, ungependa kutia alama kwenye maagizo ya wateja wawili kwa kiasi kikubwa kuliko nambari fulani, tuseme $100.
Katika lugha ya Excel, masharti yetu yameonyeshwa kwa njia hii:
OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)
Tukichukulia kuwa majina ya wateja yako kwenye safu wima B, kiasi katika safu wima C, majina 2 lengwa. ziko katika G1 na G2, na kiasi kinacholengwa kiko katika G3, unatumia fomula hii kutia alama kwenye maagizo yanayolingana na "x":
=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")
Matokeo sawa yanaweza kupatikana kwa zaidi. sintaksia fupi:
=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")
Je, huna uhakika kuwa unaelewa kabisa mantiki ya fomula? Maelezo zaidi yanaweza kupatikana katika Excel IF yenye masharti mengi NA/AU.
Hivyo ndivyo unavyotumia IF na AND hufanya kazi pamoja katika Excel. Asante kwa kusoma na kukuona wiki ijayo!
Kitabu cha mazoezi
IF AND Excel – mifano ya fomula (.xlsx file)
