V učbeniku je prikazano, kako v Excelu uporabite funkcijo IF skupaj s funkcijo AND za preverjanje več pogojev v eni formuli.

Nekatere stvari na svetu so končne, druge pa neskončne, in zdi se, da je funkcija IF ena od takih stvari. Na našem blogu imamo že nekaj Excelovih učnih gradiv za IF in še vedno vsak dan odkrivamo nove načine uporabe. Danes si bomo ogledali, kako lahko uporabite IF skupaj s funkcijo AND za vrednotenje dveh ali več pogojev hkrati.

Izjava IF IN v Excelu

Za sestavo izjave IF AND morate združiti funkciji IF in AND v eno formulo:

Prevedeno v preprosto angleščino se formula glasi: ČE je pogoj 1 resničen IN če je pogoj 2 resničen, stori eno stvar, sicer stori nekaj drugega.

Kot primer naredimo formulo, ki preveri, ali je B2 "dostavljeno" in C2 ni prazna, ter glede na rezultate naredi eno od naslednjega:

• Če sta oba pogoja TRUE, označite naročilo kot "zaprto".
• Če je eden od pogojev FALSE ali sta oba FALSE, vrne prazen niz ("").

=IF(AND(B2="dostavljeno", C2""), "zaprto", "")

Spodnja slika prikazuje funkcijo IF AND v programu Excel:

Če želite vrniti neko vrednost v primeru, da je logični test ovrednoten kot FALSE, to vrednost navedite v ukazu value_if_false argument. Na primer:

=IF(AND(B2="dostavljeno", C2""), "zaprto", "odprto")

Spremenjena formula izpiše "Zaprto", če je v stolpcu B "dostavljeno" in je v stolpcu C kateri koli datum (ki ni prazen). V vseh drugih primerih izpiše "Odprto":

Opomba: Ko v Excelu uporabljate formulo IF AND za ocenjevanje besedilnih pogojev, upoštevajte, da se male in velike črke obravnavajo kot isti znak. Če iščete formulo IF AND, ki upošteva velike in male črke, zavijte enega ali več argumentov funkcije AND v funkcijo EXACT, kot je to storjeno v povezanem primeru.

Zdaj, ko poznate sintakso Excelovega stavka IF IN, naj vam pokažem, kakšne naloge lahko rešuje.

Excel IF: večji od IN manjši od

V prejšnjem primeru smo testirali dva pogoja v dveh različnih celicah. Včasih pa boste morda morali v isti celici izvesti dva ali več testov. Tipičen primer je preverjanje, ali je vrednost v celici med dvema številoma . To lahko zlahka storite tudi s funkcijo Excel IF IN!

Recimo, da imate nekaj prodajnih številk v stolpcu B in morate označiti zneske, ki so večji od 50 USD in manjši od 100 USD. Če želite to narediti, vstavite to formulo v C2 in jo nato kopirajte navzdol po stolpcu:

=IF(AND(B2>50, B2<100), "x", "")

Če morate vključiti mejne vrednosti (50 in 100), uporabite manj ali enako (<=) in večja ali enaka (>=):

=IF(AND(B2>=50, B2<=100), "x", "")

Če želite obdelati nekatere druge mejne vrednosti, ne da bi spremenili formulo, vnesite najmanjše in največje število v dve ločeni celici in se v formuli sklicujte na ti celici. Da bo formula pravilno delovala v vseh vrsticah, ne pozabite uporabiti absolutnih referenc za mejne celice ($F$1 in $F$2 v našem primeru):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

S podobno formulo lahko preverite, ali je datum pada v določenem območju .

Označimo na primer datume med 10. septembrom 2018 in vključno 30. septembrom 2018. Majhna ovira je, da datumov ni mogoče neposredno posredovati logičnim testom. Da bi Excel razumel datume, jih je treba zapreti v funkcijo DATEVALUE, kot sledi:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Ali pa preprosto vnesite S spletne strani in . Na naslov datume v dveh celicah ($F$1 in $F$2 v tem primeru) in jih iz teh celic "potegnite" s pomočjo že znane formule IF AND:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Za več informacij glejte Excelov stavek IF med dvema številkama ali datumoma.

Če je to in to, potem nekaj izračunajte

Poleg vračanja vnaprej določenih vrednosti lahko Excelova funkcija IF AND izvede tudi različne izračune glede na to, ali so določeni pogoji resnični ali neresnični.

Za prikaz pristopa bomo izračunali 5-odstotni bonus za "zaključene" prodaje, katerih znesek je večji ali enak 100 USD.

Ob predpostavki, da je znesek v stolpcu B, status naročila pa v stolpcu C, je formula naslednja:

=IF(AND(B2>=100, C2="zaprto"), B2*10%, 0)

Zgornja formula preostalim nalogom pripiše ničlo ( value_if_false = 0). Če ste za naročila, ki ne izpolnjujejo pogojev, pripravljeni dati majhen stimulativni bonus, na primer 3 %, vključite ustrezno enačbo v value_if_false argument:

=IF(AND(B2>=100, C2="zaprto"), B2*10%, B2*3%)

Več stavkov IF IN v Excelu

Kot ste morda opazili, smo v vseh zgornjih primerih ocenili le dve merili. Vendar vam nič ne preprečuje, da bi v formule IF IN vključili tri in več testov, če so v skladu s temi splošnimi omejitvami programa Excel:

• V Excelu 2007 in novejših različicah lahko v formuli uporabite do 255 argumentov, pri čemer skupna dolžina formule ne sme presegati 8 192 znakov.
• V Excelu 2003 in nižjih različicah je dovoljenih največ 30 argumentov, katerih skupna dolžina ne sme presegati 1 024 znakov.

Kot primer več pogojev AND si oglejte te pogoje:

• Znesek (B2) mora biti večji ali enak 100 USD.
• Status naročila (C2) je "Zaprto".
• Datum dostave (D2) je v tekočem mesecu

Zdaj potrebujemo izjavo IF AND, da določimo naročila, za katera so vsi trije pogoji resnični. In tukaj je:

=IF(AND(B2>=100, C2="Zaprto", MESEC(D2)=MESEC(DANES())), "x", "")

Glede na to, da je bil "tekoči mesec" v času pisanja oktober, formula daje naslednje rezultate:

Vgnezdeni stavki IF IN

Pri delu z velikimi delovnimi listi boste morda morali preveriti več sklopov različnih meril AND naenkrat. Za to uporabite klasično Excelovo vgnezdeno formulo IF in njene logične teste razširite z ukazi AND, kot je ta:

Za splošno predstavo si oglejte naslednji primer.

Recimo, da želite oceniti svojo storitev na podlagi stroškov pošiljanja in predvidenega časa dostave (ETD):

• Odlično : stroški pošiljanja pod 20 $ in ETD pod 3 dni
• Slaba : stroški pošiljanja nad 30 USD in ETD nad 5 dni
• Povprečje : vse, kar je vmes

To lahko storite tako, da napišete dva posamezna stavka IF AND:

IF(AND(B2<20, C2<3), "Odlično", ...)

IF(AND(B2>30, C2>5), "Slaba", ...)

...in se vgnezdite eden v drugega:

=IF(AND(B2>30, C2>5), "Slab", IF(AND(B2<20, C2<3), "Odličen", "Povprečen")

Rezultat bo podoben temu:

Več primerov formul najdete v Excelovih vnešenih stavkih IF AND.

Funkcija IF IN v Excelu, občutljiva na velikost črk

Kot smo omenili na začetku tega vodnika, Excelove formule IF IN ne razlikujejo med velikimi in malimi črkami, saj funkcija AND po svoji naravi ne upošteva velikih in malih črk.

Če delate z , ki upošteva velike in male črke. podatkov in želite oceniti pogoje AND z upoštevanjem primera besedila, izvedite vsak posamezni logični preskus znotraj funkcije EXACT in te funkcije vgnezdite v stavek AND:

V tem primeru bomo označili naročila določene stranke (npr. podjetje z imenom Kibernetski prostor ) z zneskom, ki presega določeno število, na primer 100 USD.

Kot lahko vidite na spodnji sliki zaslona, so nekatera imena podjetij v stolpcu B videti enaka, vendar gre kljub temu za različna podjetja, zato moramo preveriti imena. točno Zneski v stolpcu C so števila, zato zanje izvedemo običajni preizkus "večji od":

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Če želite formulo narediti bolj prilagodljivo, lahko ime ciljne stranke in znesek vnesete v dve ločeni celici in se sklicujete na ti celici. Ne pozabite le zakleniti sklicevanja na celice z znakom $ ($G$1 in $G$2 v našem primeru), da se ne spremenijo, ko formulo kopirate v druge vrstice:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Zdaj lahko v referenčne celice vnesete poljubno ime in znesek, formula pa bo označila ustrezna naročila v tabeli:

IF ALI IN formula v Excelu

V Excelovih formulah IF niste omejeni na uporabo samo ene logične funkcije. Če želite preveriti različne kombinacije več pogojev, lahko kombinirate funkcije IF, AND, OR in druge funkcije, da izvedete zahtevane logične teste. Tukaj je primer formule IF AND OR, ki preverja nekaj pogojev OR znotraj AND. Zdaj vam bom pokazal, kako lahko izvedete dva ali več testov AND znotraj ORfunkcijo.

Recimo, da želite naročila dveh strank označiti z zneskom, ki je večji od določenega števila, na primer 100 USD.

V jeziku Excel so naši pogoji izraženi na ta način:

ALI(IN( Stranka1 , Znesek >100), AND( Stranka2 , Znesek >100)

Če so imena strank v stolpcu B, zneski v stolpcu C, dve ciljni imeni sta v G1 in G2, ciljni znesek pa v G3, s to formulo označite ustrezna naročila z "x":

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Enake rezultate je mogoče doseči z bolj kompaktno sintakso:

=IF(AND(OR(B2=$G$1,B2=$G$2), C2>$G$3), "x", "")

Niste prepričani, da popolnoma razumete logiko formule? Več informacij najdete v Excel IF z več pogoji AND/OR.

Tako v Excelu skupaj uporabljate funkciji IF in AND. Hvala za branje in se vidimo naslednji teden!

Delovni zvezek za prakso

IF IN Excel - primeri formul (.xlsx datoteka)