В урока е показано как да използвате IF заедно с функцията AND в Excel за проверка на няколко условия в една формула.

Някои неща в света са крайни, други са безкрайни и функцията IF изглежда е едно от тези неща. В нашия блог вече имаме няколко урока за IF в Excel и всеки ден откриваме нови приложения. Днес ще разгледаме как можете да използвате IF заедно с функцията AND, за да оцените две или повече условия едновременно.

Изявлението IF AND в Excel

За да съставите декларацията IF AND, очевидно трябва да комбинирате функциите IF и AND в една формула. Ето как:

Преведена на обикновен английски език, формулата гласи следното: АКО условие 1 е вярно И условие 2 е вярно, направете едно нещо, в противен случай направете нещо друго.

Като пример, нека направим формула, която проверява дали B2 е "доставено" и C2 не е празен, и в зависимост от резултатите прави едно от следните действия:

• Ако и двете условия са TRUE, маркирайте поръчката като "Затворена".
• Ако някое от двете условия е FALSE или и двете са FALSE, се връща празен низ ("").

=IF(AND(B2="доставено", C2""), "Затворено", "")

Снимката на екрана по-долу показва функцията IF AND в Excel:

Ако желаете да върнете някаква стойност в случай, че логическият тест се окаже FALSE, въведете тази стойност в value_if_false аргумент. Например:

=IF(AND(B2="доставено", C2""), "затворено", "отворено")

Модифицираната формула дава резултат "Затворено", ако колона B е "доставено" и в колона C има някаква дата (не празна). Във всички останали случаи тя дава резултат "Отворено":

Забележка: Когато използвате формула IF AND в Excel за оценяване на текстови условия, имайте предвид, че малките и големите букви се третират като един и същ символ. Ако търсите формула IF AND с отчитане на малките и големите букви, обвийте един или повече аргументи на AND във функцията EXACT, както е направено в свързания пример.

След като вече знаете синтаксиса на оператора IF AND в Excel, нека ви покажа какви задачи може да решава той.

Excel IF: по-голямо от И по-малко от

В предишния пример тествахме две условия в две различни клетки. Но понякога може да се наложи да извършите два или повече теста в една и съща клетка. Типичен пример е проверката дали стойността на дадена клетка е между две числа . Функцията IF AND на Excel също може лесно да направи това!

Да речем, че имате някои числа за продажби в колона B и от вас се иска да маркирате сумите, по-големи от 50 USD, но по-малки от 100 USD. За да го направите, поставете тази формула в C2 и след това я копирайте надолу по колоната:

=IF(AND(B2>50, B2<100), "x", "")

Ако трябва да включите гранични стойности (50 и 100), използвайте по-малък или равен на оператор (<=) и по-голям или равен на (>=) оператор:

=IF(AND(B2>=50, B2<=100), "x", "")

За да обработите някои други гранични стойности, без да променяте формулата, въведете минималните и максималните числа в две отделни клетки и направете препратка към тези клетки във формулата си. За да работи правилно формулата във всички редове, не забравяйте да използвате абсолютни препратки за граничните клетки ($F$1 и $F$2 в нашия случай):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

С помощта на подобна формула можете да проверите дали даден дата пада в рамките на определен диапазон .

Например, нека маркираме дати между 10 септември 2018 г. и 30 септември 2018 г. включително. Малка пречка е, че датите не могат да се предоставят директно на логическите тестове. За да може Excel да разбере датите, те трябва да бъдат затворени във функцията DATEVALUE, както е показано по-долу:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Или просто въведете От и За дати в две клетки ($F$1 и $F$2 в този пример) и да ги "извадите" от тези клетки, като използвате вече познатата формула IF AND:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

За повече информация, моля, вижте Excel IF декларация между две числа или дати.

Ако това И това, тогава изчислете нещо

Освен че връща предварително зададени стойности, функцията IF AND на Excel може да извършва и различни изчисления в зависимост от това дали зададените условия са TRUE или FALSE.

За да демонстрираме подхода, ще изчислим бонус от 5% за "затворени" продажби със сума, по-голяма или равна на 100 USD.

Ако приемем, че сумата е в колона Б, а статусът на поръчката - в колона В, формулата е следната:

=IF(AND(B2>=100, C2="затворен"), B2*10%, 0)

В горната формула на останалите поръчки се присвоява нула ( value_if_false = Ако сте готови да дадете малък стимулиращ бонус, например 3%, за поръчки, които не отговарят на условията, включете съответното уравнение в value_if_false аргумент:

=IF(AND(B2>=100, C2="затворен"), B2*10%, B2*3%)

Множество изявления IF AND в Excel

Както може би сте забелязали, във всички горепосочени примери сме оценили само два критерия. Но нищо не ви пречи да включите три и повече теста във формулите си IF AND, стига те да са съобразени с тези общи ограничения на Excel:

• В Excel 2007 и по-нови версии във формула могат да се използват до 255 аргумента, като общата дължина на формулата не може да надвишава 8 192 символа.
• В Excel 2003 и по-ниски версии са разрешени не повече от 30 аргумента, като общата им дължина не може да надвишава 1024 символа.

Като пример за многократни условия AND разгледайте тези:

• Сумата (B2) трябва да е по-голяма или равна на 100 USD.
• Статусът на поръчката (C2) е "Затворена".
• Датата на доставка (D2) е в рамките на текущия месец

Сега се нуждаем от изявление IF AND, за да определим поръчките, за които и трите условия са верни. Ето го и него:

=IF(AND(B2>=100, C2="Затворено", MONTH(D2)=MONTH(TODAY())), "x", "")

Като се има предвид, че "текущият месец" в момента на писане е октомври, формулата дава следните резултати:

Вложени твърдения IF AND

Когато работите с големи работни листове, има вероятност да се наложи да проверявате няколко набора от различни критерии AND едновременно. За тази цел се използва класическата вложена формула IF на Excel и се разширяват логическите ѝ тестове с оператори AND, както е показано по-долу:

За да добиете обща представа, разгледайте следния пример.

Да предположим, че искате да оцените услугата си въз основа на цената на пратката и очакваното време за доставка (ЕТД):

• Отличен : цена на пратката под 20 долара и ETD под 3 дни
• Беден : цена на пратката над 30 USD и ЕТД над 5 дни
• Средно : всичко между тях

За да го направите, трябва да напишете два отделни оператора IF AND:

IF(AND(B2<20, C2<3), "Excellent", ...)

IF(AND(B2>30, C2>5), "Беден", ...)

...и се вмъквате един в друг:

=IF(AND(B2>30, C2>5), "Слаб", IF(AND(B2<20, C2<3), "Отличен", "Среден")

Резултатът ще изглежда по следния начин:

Повече примери за формули можете да намерите в Excel вложени оператори IF AND.

Функцията IF AND в Excel, чувствителна към малки и големи букви

Както беше споменато в началото на този урок, формулите IF AND на Excel не правят разлика между главни и малки букви, тъй като функцията AND по своята същност не различава големи и малки букви.

Ако работите с отчитане на малки и големи букви данни и искате да оцените условията AND, като вземете предвид текстовия случай, направете всеки отделен логически тест във функцията EXACT и вложете тези функции в оператора AND:

В този пример ще маркираме поръчките на конкретен клиент (напр. компанията с име Киберпространство ) със сума, надвишаваща определено число, например 100 USD.

Както можете да видите на долната снимка, някои имена на компании в колона В изглеждат еднакво, но въпреки това са различни компании, така че трябва да проверим имената. точно Сумите в колона В са числа и за тях се извършва обикновен тест "по-голямо от":

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

За да направите формулата по-гъвкава, можете да въведете името на целевия клиент и сумата в две отделни клетки и да се позовавате на тези клетки. Само не забравяйте да заключите препратките към клетките със знака $ ($G$1 и $G$2 в нашия случай), за да не се променят, когато копирате формулата в други редове:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Сега можете да въведете всяко име и сума в посочените клетки и формулата ще маркира съответните поръчки в таблицата:

Ако ИЛИ И формула в Excel

Във формулите IF на Excel не сте ограничени да използвате само една логическа функция. За да проверите различни комбинации от множество условия, можете да комбинирате функциите IF, AND, OR и други, за да извършите необходимите логически тестове. Ето един пример за формула IF AND OR, която проверява няколко условия OR в рамките на AND. А сега ще ви покажа как можете да направите два или повече теста AND в рамките на ORфункция.

Да предположим, че искате да маркирате поръчките на двама клиенти със сума, по-голяма от определено число, например 100 USD.

На езика Excel нашите условия се изразяват по следния начин:

ИЛИ(И( Клиент1 , Сума >100), AND( Клиент2 , Сума >100)

Ако приемете, че имената на клиентите са в колона B, сумите - в колона C, двете целеви имена са в G1 и G2, а целевата сума - в G3, използвайте тази формула, за да маркирате съответните поръчки с "x":

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Същите резултати могат да бъдат постигнати с по-компактен синтаксис:

=IF(AND(OR(B2=$G$1,B2=$G$2), C2>$G$3), "x", "")

Не сте сигурни, че напълно разбирате логиката на формулата? Повече информация можете да намерите в Excel IF с множество условия AND/OR.

Ето как се използват функциите IF и AND заедно в Excel. Благодарим ви, че прочетохте, и се виждаме следващата седмица!

Практическа работна тетрадка

IF AND Excel - примери за формули (.xlsx файл)