Õpetus näitab, kuidas kasutada Excelis IF koos AND-funktsiooniga, et kontrollida mitut tingimust ühes valemis.

Mõned asjad maailmas on lõplikud. Teised on lõputud ja IF funktsioon tundub olevat üks sellistest asjadest. Meie blogis on juba käputäis Exceli IF õpetusi ja avastame ikka veel iga päev uusi kasutusvõimalusi. Täna vaatame, kuidas saab IF-i koos AND funktsiooniga kasutada kahe või enama tingimuse samaaegseks hindamiseks.

IF AND avaldus Excelis

IF AND avaldise koostamiseks tuleb ilmselgelt ühendada IF ja AND funktsioonid ühte valemisse. Järgnevalt on kirjeldatud, kuidas:

Lihtsasse inglise keelde tõlgituna kõlab valem järgmiselt: KUI tingimus 1 on tõene JA tingimus 2 on tõene, tee üks asi, muidu tee midagi muud.

Tehkem näiteks valem, mis kontrollib, kas B2 on "tarnitud" ja C2 ei ole tühi, ning teeb sõltuvalt tulemustest ühe järgmistest:

• Kui mõlemad tingimused on tõesed, märkige tellimus "Suletud".
• Kui kumbki tingimus on FALSE või mõlemad on FALSE, siis tagastab tühja stringi ("").

=IF(AND(B2="tarnitud", C2""), "Suletud", "")

Allpool olev ekraanipilt näitab IF AND funktsiooni Excelis:

Kui soovite tagastada mingi väärtuse juhul, kui loogiline test annab tulemuseks FALSE, siis esitage see väärtus failis value_if_false Näiteks:

=IF(AND(B2="tarnitud", C2""), "Suletud", "Avatud")

Muudetud valem annab tulemuseks "Suletud", kui veerus B on "tarnitud" ja veerus C on mis tahes kuupäev (mitte tühi). Kõikidel muudel juhtudel annab see tulemuseks "Avatud":

Märkus. Kui kasutate Excelis tekstitingimuste hindamiseks valemit IF AND, pidage meeles, et väikseid ja suuri tähti käsitletakse ühe ja sama märgina. Kui otsite IF AND-vormelit, mille puhul on suur- ja väiketähtedest sõltuv, mähkige üks või mitu AND-i argumenti funktsiooni EXACT sisse, nagu on tehtud lingitud näites.

Nüüd, kui te teate Exceli IF AND avalduse süntaksit, näitan teile, milliseid ülesandeid sellega saab lahendada.

Excel IF: suurem kui JA väiksem kui

Eelmises näites testisime kahte tingimust kahes erinevas lahtris. Kuid mõnikord võib olla vaja teha kaks või rohkem testi ühes lahtris. Tüüpiline näide on kontrollida, kas lahtri väärtus on kahe numbri vahel Exceli IF AND-funktsiooniga saab ka seda hõlpsasti teha!

Oletame, et teil on mõned müüginumbrid veerus B ja teil palutakse märkida summad, mis on suuremad kui 50 dollarit, kuid väiksemad kui 100 dollarit. Selleks sisestage see valem veergu C2 ja seejärel kopeerige see veerus alla:

=IF(AND(B2>50, B2<100), "x", "")

Kui teil on vaja lisada piirväärtused (50 ja 100), kasutage väiksem või võrdne operaator (<=) ja suurem või võrdne (>=) operaator:

=IF(AND(B2>=50, B2<=100), "x", "")

Teiste piirväärtuste töötlemiseks ilma valemit muutmata, sisestage minimaalne ja maksimaalne arv kahte eraldi lahtrisse ja viita nendele lahtritele oma valemis. Et valem töötaks õigesti kõigis ridades, kasutage kindlasti absoluutseid viiteid piiriruumidele (meie puhul $F$1 ja $F$2):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Kasutades sarnast valemit, saate kontrollida, kas kuupäev langeb kindlaksmääratud vahemikus .

Näiteks märgistame kuupäevad vahemikus 10-Sep-2018 kuni 30-Sep-2018 (kaasa arvatud). Väike takistus on see, et kuupäevi ei saa loogilistele testidele otse esitada. Et Excel saaks kuupäevadest aru, tuleb need lisada DATEVALUE-funktsiooni, näiteks nii:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Või lihtsalt sisestage Alates ja aadressile kuupäevad kahes lahtris (antud näites $F$1 ja $F$2) ja "tõmmake" need neist lahtritest, kasutades juba tuttavat IF AND valemit:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Lisateavet leiate Exceli IF-avaldusest kahe numbri või kuupäeva vahel.

Kui see JA see, siis arvuta midagi

Lisaks etteantud väärtuste tagastamisele võib Exceli funktsioon IF AND teha ka erinevaid arvutusi sõltuvalt sellest, kas määratud tingimused on TRUE või FALSE.

Lähenemisviisi näitamiseks arvutame 5% boonust "Suletud" müügi puhul, mille summa on suurem või võrdne 100 dollariga.

Eeldades, et summa on veerus B ja tellimuse staatus veerus C, on valem järgmine:

=IF(AND(B2>=100, C2="suletud"), B2*10%, 0)

Ülaltoodud valemiga määratakse ülejäänud korraldused nulliks ( value_if_false = 0). Kui olete valmis andma väikest stimuleerivat boonust, näiteks 3%, tellimustele, mis ei vasta tingimustele, lisage vastav võrrandisse value_if_false argument:

=IF(AND(B2>=100, C2="suletud"), B2*10%, B2*3%)

Mitu IF AND avaldust Excelis

Nagu olete ehk märganud, oleme kõigis ülaltoodud näidetes hinnanud ainult kahte kriteeriumi. Kuid miski ei takista teid lisamast oma IF AND-valemitesse kolme ja enamat testi, kui need vastavad nendele Exceli üldistele piirangutele:

• Excel 2007 ja uuemates versioonides võib valemis kasutada kuni 255 argumenti, kusjuures valemi kogupikkus ei tohi ületada 8192 tähemärki.
• Excel 2003 ja madalamates versioonides on lubatud maksimaalselt 30 argumenti, mille kogupikkus ei tohi ületada 1024 märki.

Näitena mitme JA tingimuse kohta vaadake neid:

• Summa (B2) peaks olema suurem või võrdne 100 dollariga.
• Tellimuse staatus (C2) on "Suletud".
• Tarnekuupäev (D2) on jooksva kuu jooksul.

Nüüd vajame IF AND avaldust, et tuvastada tellimused, mille puhul kõik 3 tingimust on TRUE. Ja siin on see:

=IF(AND(B2>=100, C2="Suletud", KUU(D2)=MONTH(TODAY())), "x", "")

Arvestades, et "jooksev kuu" oli kirjutamise hetkel oktoober, annab valem alljärgnevad tulemused:

Sisestatud IF AND avaldused

Kui töötate suurte töölehtedega, on tõenäoline, et teil on vaja kontrollida korraga mitut erinevat AND-kriteeriumi. Selleks võtate klassikalise Exceli sisendatud IF-vormeli ja laiendate selle loogilisi teste AND-lauseid, näiteks järgmiselt:

Üldise ettekujutuse saamiseks vaadake järgmist näidet.

Oletame, et soovite oma teenust hinnata saatmiskulude ja eeldatava tarneaja (ETD) alusel:

• Suurepärane : saatekulu alla 20 dollari ja ETD alla 3 päeva.
• Vaene : saatekulu üle 30 dollari ja ETD üle 5 päeva.
• Keskmine : midagi vahepealset

Selleks kirjutate kaks eraldi IF AND avaldust:

IF(AND(B2<20, C2<3), "Suurepärane", ...)

IF(AND(B2>30, C2>5), "Poor", ...)

...ja pesitsevad üksteise sisse:

=IF(AND(B2>30, C2>5), "Halb", IF(AND(B2<20, C2<3), "Suurepärane", "Keskmine"))

Tulemus näeb välja umbes nii:

Rohkem näiteid valemite kohta leiate Exceli sisseehitatud IF AND avaldustest.

Suur- ja väiketähtedega IF AND funktsioon Excelis

Nagu selle õpetuse alguses mainitud, ei tee Exceli IF AND-vormelites vahet suur- ja väiketähtede vahel, sest AND-funktsioon on oma olemuselt suur- ja väiketähtede suhtes tundmatu.

Kui te töötate koos suur- ja väiketähelepanu andmeid ja soovite hinnata AND-tingimusi, võttes arvesse teksti juhtumit, tehke iga üksikut loogilist testi EXACT-funktsiooni sees ja pesitsege need funktsioonid oma AND-avaldusse:

Selles näites märgistame konkreetse kliendi tellimusi (nt ettevõtte nimega Küberruumi ), mille summa ületab teatud arvu, näiteks 100 dollarit.

Nagu allpool oleval ekraanipildil näha, näevad mõned ettevõtete nimed veerus B välja samasuguse väljavõtte tähemärkide puhul, kuid sellest hoolimata on tegemist erinevate ettevõtetega, seega peame kontrollima nimesid. täpselt Veerus C olevad summad on arvud ja me teeme nende jaoks tavalise "suurem kui" testi:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Valemi paindlikumaks muutmiseks võite sisestada sihtkliendi nime ja summa kahte eraldi lahtrisse ja viidata nendele lahtritele. Ärge unustage lihtsalt lukustada lahtriviited $-märgiga (meie puhul $G$1 ja $G$2), et need ei muutuks, kui kopeerite valemi teistesse ridadesse:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Nüüd võite sisestada viidatud lahtritesse mis tahes nime ja summa ning valem märgistab vastavad tellimused teie tabelis:

IF OR AND valem Excelis

Exceli IF-vormelites ei ole te piiratud ainult ühe loogilise funktsiooni kasutamisega. Mitme tingimuse erinevate kombinatsioonide kontrollimiseks võite vabalt kombineerida IF, AND, OR ja muid funktsioone, et teha vajalikke loogilisi teste. Siin on näide IF AND OR-vormelist, mis testib paar OR-tingimust AND-i sees. Ja nüüd näitan teile, kuidas saate teha kaks või enam AND-testi OR-i sees.funktsioon.

Oletame, et soovite märkida kahe kliendi tellimusi, mille summa ületab teatud arvu, näiteks 100 dollarit.

Exceli keeles väljendatakse meie tingimusi järgmiselt:

VÕI(JA( Klient1 , Summa >100), AND( Klient2 , Summa >100)

Eeldades, et klientide nimed on veerus B, summad veerus C, 2 sihtnime on veergudes G1 ja G2 ning sihtmaht on veerus G3, kasutate seda valemit vastavate tellimuste märkimiseks "x":

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Samu tulemusi saab saavutada ka kompaktsema süntaksiga:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

Ei ole kindel, et saate valemi loogikast täielikult aru? Lisateavet leiate Excelist IF koos mitme AND/OR tingimusega.

Nii kasutate Excelis IF ja AND funktsioone koos. Tänan teid lugemise eest ja kohtumiseni järgmisel nädalal!

Praktiline töövihik

IF AND Excel - valemite näited (.xlsx fail)