Упатството покажува како да се користи IF заедно со функцијата AND во Excel за проверка на повеќе услови во една формула.

Некои работи во светот се конечни. Другите се бесконечни, а функцијата IF се чини дека е една од таквите работи. На нашиот блог, веќе имаме неколку упатства за Excel IF и сè уште откриваме нови употреби секој ден. Денес, ќе разгледаме како можете да го користите IF заедно со функцијата AND за да оцените два или повеќе услови во исто време.

IF AND изјава во Excel

За да ја изградите изјавата IF AND, очигледно треба да ги комбинирате функциите IF и AND во една формула. Еве како:

Преведено на обичен англиски, формулата гласи како што следува: IF услов 1 е точно И условот 2 е вистина, направи едно, инаку направи нешто друго.

Како пример, да направиме формула која проверува дали B2 е „испорачан“ и C2 не е празен и во зависност од резултатите , прави едно од следново:

• Ако двата услови се ТОЧНИ, означете го редоследот како „Затворено“.
• Ако еден од условите е НЕТОЧЕН или и двата се НЕТОЧНИ, тогаш вратете празен низа ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

На сликата подолу е прикажана функцијата IF AND во Excel:

Ако би сакал да врати некоја вредност во случај логичкиот тест да се оцени на FALSE, наведете ја таа вредност во value_if_false аргумент. На пример:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

Модифицираната формула дава „Затворено“ ако колоната B е „испорачана“ и C има било кој датум во неа (не празно). Во сите други случаи, враќа „Отворено“:

Забелешка. Кога користите формула АКО И во Excel за да ги оцените условите на текстот, имајте на ум дека малите и големите букви се третираат како ист знак. Ако барате формула чувствителна на букви АКО И, завиткајте еден или повеќе аргументи на И во функцијата EXACT како што е направено во поврзаниот пример.

Сега кога ја знаете синтаксата на изјавата на Excel IF AND, дозволете ми да ви покажам какви задачи може да реши.

Excel IF: поголема од И помала од

Во претходниот пример, тестиравме две состојби во две различни ќелии. Но, понекогаш можеби ќе треба да извршите два или повеќе тестови на иста ќелија. Типичен пример е проверката дали вредноста на ќелијата е помеѓу два броја . Функцијата Excel IF AND може лесно да го стори тоа исто така!

Да речеме дека имате некои продажни броеви во колоната Б и од вас се бара да ги означите износите поголеми од 50 долари, но помали од 100 долари. За да го направите тоа, вметнете ја оваа формула во C2 и потоа копирајте ја во колоната:

=IF(AND(B2>50, B2<100), "x", "")

Ако треба да ја вклучите границата вредности (50 и 100), користете го операторот помал или еднаков на (<=) и поголем или еднаков на (>=):

=IF(AND(B2>=50, B2<=100), "x", "")

За обработка на некои другиграничните вредности без промена на формулата, внесете ги минималните и максималните броеви во две посебни ќелии и упатете се на тие ќелии во вашата формула. За формулата да работи правилно во сите редови, не заборавајте да користите апсолутни референци за граничните ќелии ($F$1 и $F$2 во нашиот случај):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Со користење на слична формула, можете да проверите дали датум паѓа во одреден опсег .

На пример, ајде да ги означиме датумите помеѓу 10 -Сеп-2018 и 30-сеп-2018, вклучително. Мала пречка е тоа што датумите не можат директно да се доставуваат до логичките тестови. За Excel да ги разбере датумите, тие треба да бидат приложени во функцијата DATEVALUE, вака:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Или едноставно внесете ги Од и До датира во две ќелии ($F$1 и $F$2 во овој пример) и „повлечете“ ги од тие ќелии користејќи ја веќе познатата формула IF AND:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

За повеќе информации, погледнете ја изјавата Excel IF помеѓу два броја или датуми.

Ако ова И она, тогаш пресметајте нешто

Покрај враќањето на претходно дефинираните вредности, Excel IF И функцијата исто така може да врши различни пресметки во зависност од тоа дали наведените услови се ТОЧНИ или НЕТОЧНИ.

За да го покажеме пристапот, ќе пресметаме бонус од 5% за „Затворена“ продажба со износ поголем или еднаков до $100.

Претпоставувајќи дека износот е во колоната Б и статусот на нарачката во колоната C,формулата оди на следниов начин:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

Горената формула доделува нула на останатите нарачки ( value_if_false = 0) . Ако сте спремни да дадете мал стимулирачки бонус, да речеме 3%, на нарачки кои не ги исполнуваат условите, вклучете ја соодветната равенка во аргументот value_if_false :

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

Повеќе IF AND изјави во Excel

Како што можеби забележавте, оценивме само два критериуми во сите горенаведени примери. Но, нема ништо што би ве спречило да вклучите три или повеќе тестови во вашите формули IF AND се додека тие се во согласност со овие општи ограничувања на Excel:

• Во Excel 2007 и повисоко, до 255 аргументи може да се користи во формула, со вкупна должина на формула што не надминува 8.192 знаци.
• Во Excel 2003 и пониски, не се дозволени повеќе од 30 аргументи, со вкупна должина не поголема од 1.024 знаци.
• 5>

  Како пример за повеќе AND услови, разгледајте ги овие:

  • Износот (B2) треба да биде поголем или еднаков на $100
  • Статус на нарачката (C2) е „Затворено“
  • Датумот на испорака (D2) е во тековниот месец

  Сега, ни треба изјава АКО И за да ги идентификуваме нарачките за кои сите 3 услови се ВИСТИНИ. И еве го:

  =IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

  Со оглед на тоа што „тековниот месец“ во моментот на пишување беше октомври, формулата ги дава следните резултати:

  Исто така види: Како да се потсетите на е-пошта во Outlook

  

  Вгнездени АКО Иискази

  Кога работите со големи работни листови, веројатно е дека ќе треба да проверите неколку групи на различни И критериуми истовремено. За ова, земате класична Excel вгнездена формула IF и ги проширувате нејзините логички тестови со AND изјави, како ова:

  IF(AND(…), излез1 , IF(AND(…), излез2 , IF(AND(…), излез3 , излез4 )))

  За да ја добиете општата идеја, погледнете го следниот пример.

  Да претпоставиме дека сакате да ја оцените вашата услуга врз основа на трошоците за пратката и проценетото време на испорака (ETD):

  • Одлично : цена на испорака под $20 и ETD под 3 дена
  • Слабо : цена на испорака над $30 и ETD во текот на 5 дена
  • Просечно : нешто помеѓу

  До завршете го тоа, напишете две поединечни IF AND искази:

  IF(AND(B2<20, C2<3), "Excellent", …)

  IF(AND(B2>30, C2>5), "Poor", …)

  ...и вгнездувајте еден во друг:

  =IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

  Резултатот ќе изгледа слично на ова:

  

  Повеќе примери на формули може да се најдат во Excel вгнездени IF AND изјави.

  Осетливи на големи букви IF AND функција во Excel

  Како што беше споменато во почетокот на ова упатство, формулите на Excel IF AND не прават разлика помеѓу големи и мали букви затоа што функцијата AND е по природа без чувствителност на букви.

  Ако работите со податоци чувствителни на букви и сакате да ги процените И условите земајќи го предвид текстот на буквите, направете го секој поединечен логички тест внатре во функцијата EXACT и гнездототие функции во вашата изјава AND:

  IF(AND(EXACT( ќелија ," услов1 "), EXACT( ќелија ," состојба2 ")), value_if_true, value_if_false)

  За овој пример, ќе ги означиме нарачките на одреден клиент (на пр. компанијата со име Сајбер простор ) со износ што надминува одреден број, да речеме УСД. 13>. Износите во колоната C се бројки и ние спроведуваме редовен тест „поголемо од“ за нив:

  =IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

  За да ја направите формулата пофлексибилна, можете да го внесете името на целниот клиент и износот во две посебни ќелии и се однесуваат на тие ќелии. Само не заборавајте да ги заклучите референците на ќелиите со знакот $ ($G$1 и $G$2 во нашиот случај) за да не се менуваат кога ќе ја копирате формулата во други редови:

  =IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

  Сега, можете да напишете кое било име и износ во референтните ќелии, а формулата ќе ги означи соодветните нарачки во вашата табела:

  

  АКО ИЛИ И формула во Excel

  Во формулите на Excel IF, не сте ограничени на користење само на една логичка функција. За да проверите различни комбинации на повеќе услови, можете слободно да ги комбинирате IF, AND, OR и други функции за да ги извршите потребните логички тестови. Еве пример за формулата АКО И ИЛИ која тестира неколкуИЛИ услови во рамките на И. И сега, ќе ви покажам како можете да направите два или повеќе И тестови во рамките на функцијата ИЛИ.

  Да претпоставиме дека сакате да ги означите нарачките на двајца клиенти со износ поголем од одреден број, да речеме 100 долари.

  Во јазикот Excel, нашите услови се изразени на вака:

  OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

  Претпоставувајќи дека имињата на клиентите се во колоната Б, износите во колоната C, 2-те целни имиња се во G1 и G2, а целната сума е во G3, ја користите оваа формула за да ги означите соодветните нарачки со „x“:

  =IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

  Истите резултати може да се постигнат со повеќе компактна синтакса:

  =IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

  

  Не сте сигурни дека целосно ја разбирате логиката на формулата? Повеќе информации може да најдете во Excel IF со повеќе И/ИЛИ услови.

  Така ги користите функциите IF и AND заедно во Excel. Ви благодариме што прочитавте и се гледаме следната недела!

  Вежбајте работна книга

  IF И Excel – примери на формули (датотека .xlsx)