Hướng dẫn chỉ ra cách sử dụng IF cùng với hàm AND trong Excel để kiểm tra nhiều điều kiện trong một công thức.

Một số thứ trên thế giới là hữu hạn. Những thứ khác là vô hạn và hàm IF dường như là một trong những thứ như vậy. Trên blog của chúng tôi, chúng tôi đã có một số hướng dẫn về Excel IF và vẫn khám phá những cách sử dụng mới mỗi ngày. Hôm nay, chúng ta sẽ xem xét cách bạn có thể sử dụng IF cùng với hàm AND để đánh giá hai hoặc nhiều điều kiện cùng một lúc.

Câu lệnh IF AND trong Excel

Để xây dựng câu lệnh IF AND, rõ ràng bạn cần kết hợp hàm IF và hàm AND trong một công thức. Đây là cách thực hiện:

Được dịch sang tiếng Anh thuần túy, công thức như sau: NẾU điều kiện 1 là đúng VÀ điều kiện 2 là đúng, làm một việc, nếu không thì làm việc khác.

Ví dụ: hãy tạo một công thức để kiểm tra xem B2 có được "giao" hay không và C2 không trống và tùy thuộc vào kết quả , thực hiện một trong các thao tác sau:

• Nếu cả hai điều kiện đều là ĐÚNG, hãy đánh dấu đơn hàng là "Đã đóng".
• Nếu một trong hai điều kiện là SAI hoặc cả hai điều kiện đều SAI, thì trả về một khoảng trống chuỗi ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

Ảnh chụp màn hình bên dưới hiển thị hàm IF AND trong Excel:

Nếu bạn 'muốn trả lại một số giá trị trong trường hợp kiểm tra logic đánh giá là SAI, hãy cung cấp giá trị đó trong value_if_false tranh luận. Ví dụ:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

Công thức đã sửa đổi cho kết quả là "Đã đóng" nếu cột B là "đã gửi" và C có bất kỳ ngày nào trong đó (không để trống). Trong tất cả các trường hợp khác, nó trả về "Mở":

Lưu ý. Khi sử dụng công thức IF AND trong Excel để đánh giá các điều kiện văn bản, xin lưu ý rằng chữ thường và chữ hoa được coi là cùng một ký tự. Nếu bạn đang tìm kiếm một công thức IF AND phân biệt chữ hoa chữ thường, hãy bọc một hoặc nhiều đối số của AND vào hàm EXACT như được thực hiện trong ví dụ được liên kết.

Bây giờ bạn đã biết cú pháp của câu lệnh IF AND trong Excel, hãy để tôi chỉ cho bạn những loại nhiệm vụ mà nó có thể giải quyết.

Excel IF: lớn hơn AND nhỏ hơn

Trong ví dụ trước, chúng tôi đã thử nghiệm hai điều kiện trong hai ô khác nhau. Nhưng đôi khi bạn có thể cần chạy hai hoặc nhiều thử nghiệm trên cùng một ô. Một ví dụ điển hình là kiểm tra xem giá trị ô có nằm trong khoảng giữa hai số hay không. Hàm IF AND của Excel cũng có thể dễ dàng thực hiện điều đó!

Giả sử bạn có một số doanh số bán hàng trong cột B và bạn được yêu cầu gắn cờ số tiền lớn hơn $50 nhưng nhỏ hơn $100. Để hoàn thành, hãy chèn công thức này vào C2 rồi sao chép nó xuống cột:

=IF(AND(B2>50, B2<100), "x", "")

Nếu bạn cần bao gồm ranh giới giá trị (50 và 100), hãy sử dụng toán tử nhỏ hơn hoặc bằng (<=) và lớn hơn hoặc bằng (>=):

=IF(AND(B2>=50, B2<=100), "x", "")

Để xử lý một số khácgiá trị biên mà không thay đổi công thức, hãy nhập số tối thiểu và tối đa vào hai ô riêng biệt và tham chiếu đến các ô đó trong công thức của bạn. Để công thức hoạt động chính xác trong tất cả các hàng, hãy đảm bảo sử dụng tham chiếu tuyệt đối cho các ô biên ($F$1 và $F$2 trong trường hợp của chúng tôi):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Bằng cách sử dụng một công thức tương tự, bạn có thể kiểm tra xem ngày có nằm trong trong phạm vi được chỉ định không .

Ví dụ: hãy gắn cờ các ngày giữa 10 -Tháng 9 năm 2018 và ngày 30 tháng 9 năm 2018, bao gồm cả. Một trở ngại nhỏ là ngày tháng không thể được cung cấp trực tiếp cho các bài kiểm tra logic. Để Excel hiểu được ngày tháng, chúng phải được đặt trong hàm DATEVALUE, như sau:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Hoặc chỉ cần nhập From và To ngày tháng trong hai ô ($F$1 và $F$2 trong ví dụ này) và "kéo" chúng từ các ô đó bằng cách sử dụng công thức IF AND quen thuộc:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Để biết thêm thông tin, vui lòng xem câu lệnh IF trong Excel giữa hai số hoặc ngày.

NẾU cái này VÀ cái kia, sau đó tính toán điều gì đó

Ngoài việc trả về các giá trị được xác định trước, hàm IF trong Excel Hàm AND cũng có thể thực hiện các phép tính khác nhau tùy thuộc vào việc các điều kiện đã chỉ định là ĐÚNG hay SAI.

Để minh họa cho phương pháp này, chúng tôi sẽ tính tiền thưởng 5% cho doanh số bán hàng "Đã chốt" với số tiền lớn hơn hoặc bằng đến $100.

Giả sử số tiền ở cột B và trạng thái đơn hàng ở cột C,công thức như sau:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

Công thức trên gán 0 cho các đơn đặt hàng còn lại ( value_if_false = 0) . Nếu bạn sẵn sàng tặng một khoản tiền thưởng kích thích nhỏ, chẳng hạn như 3%, cho các đơn đặt hàng không đáp ứng các điều kiện, hãy bao gồm phương trình tương ứng trong đối số value_if_false :

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

Nhiều câu lệnh IF AND trong Excel

Như bạn có thể nhận thấy, chúng tôi chỉ đánh giá hai tiêu chí trong tất cả các ví dụ trên. Nhưng không gì có thể ngăn cản bạn đưa ba phép thử trở lên vào công thức IF AND của mình miễn là chúng tuân thủ các giới hạn chung sau của Excel:

• Trong Excel 2007 trở lên, có tới 255 đối số có thể được sử dụng trong một công thức, với tổng độ dài công thức không vượt quá 8.192 ký tự.
• Trong Excel 2003 trở xuống, không được phép sử dụng quá 30 đối số, với tổng độ dài không vượt quá 1.024 ký tự.

Ví dụ về nhiều điều kiện AND, vui lòng xem xét những điều kiện sau:

• Số tiền (B2) phải lớn hơn hoặc bằng $100
• Trạng thái đơn hàng (C2) là "Đã đóng"
• Ngày giao hàng (D2) nằm trong tháng hiện tại

Bây giờ, chúng ta cần một câu lệnh NẾU VÀ để xác định các đơn đặt hàng có cả 3 điều kiện là ĐÚNG. Và đây là:

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

Cho rằng 'tháng hiện tại' tại thời điểm viết là tháng 10, công thức cho kết quả dưới đây:

NẾU AND lồng nhaucâu lệnh

Khi làm việc với các trang tính lớn, rất có thể bạn được yêu cầu kiểm tra một vài bộ tiêu chí AND khác nhau cùng một lúc. Đối với điều này, bạn sử dụng công thức IF lồng nhau cổ điển của Excel và mở rộng các kiểm tra logic của nó bằng các câu lệnh AND, như sau:

Để hiểu ý chung, vui lòng xem ví dụ sau.

Giả sử bạn muốn xếp hạng dịch vụ của mình dựa trên chi phí vận chuyển và thời gian giao hàng ước tính (ETD):

• Xuất sắc : chi phí vận chuyển dưới 20 đô la và ETD dưới 3 ngày
• Kém : chi phí vận chuyển trên $30 và ETD trong 5 ngày
• Trung bình : bất cứ điều gì ở giữa

Đến hoàn thành, bạn viết hai câu lệnh IF AND riêng lẻ:

IF(AND(B2<20, C2<3), "Excellent", …)

IF(AND(B2>30, C2>5), "Poor", …)

…và lồng cái này vào cái kia:

=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

Kết quả sẽ trông giống như sau:

Bạn có thể tìm thấy nhiều ví dụ về công thức hơn trong các câu lệnh IF AND lồng nhau của Excel.

IF AND phân biệt chữ hoa chữ thường hàm trong Excel

Như đã đề cập ở phần đầu của hướng dẫn này, các công thức IF AND của Excel không phân biệt chữ hoa và chữ thường vì bản chất hàm AND không phân biệt chữ hoa chữ thường.

Nếu bạn đang làm việc với dữ liệu phân biệt chữ hoa chữ thường và muốn đánh giá các điều kiện AND có tính đến trường hợp văn bản, hãy thực hiện từng kiểm tra logic riêng lẻ bên trong hàm EXACT và tổcác hàm đó vào câu lệnh AND của bạn:

Đối với ví dụ này, chúng tôi sẽ gắn cờ các đơn đặt hàng của một khách hàng cụ thể (ví dụ: công ty có tên Cyberspace ) với số tiền vượt quá một số nhất định, chẳng hạn như $100.

Như bạn có thể thấy trong ảnh chụp màn hình bên dưới, một số tên công ty trong cột B trông giống như phần trích dẫn cách viết hoa chữ thường, tuy nhiên chúng là các công ty khác nhau, vì vậy chúng tôi phải kiểm tra tên chính xác . Số tiền trong cột C là số và chúng tôi chạy thử nghiệm "lớn hơn" thông thường cho chúng:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Để làm cho công thức linh hoạt hơn, bạn có thể nhập tên khách hàng mục tiêu và số tiền trong hai ô riêng biệt và tham chiếu đến các ô đó. Chỉ cần nhớ khóa các tham chiếu ô bằng ký hiệu $ ($G$1 và $G$2 trong trường hợp của chúng tôi) để chúng không thay đổi khi bạn sao chép công thức sang các hàng khác:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Giờ đây, bạn có thể nhập bất kỳ tên và số tiền nào vào các ô được tham chiếu và công thức sẽ đánh dấu các đơn đặt hàng tương ứng trong bảng của bạn:

Công thức IF OR AND trong Excel

Trong công thức IF của Excel, bạn không bị giới hạn chỉ sử dụng một hàm logic. Để kiểm tra các cách kết hợp khác nhau của nhiều điều kiện, bạn có thể tự do kết hợp các hàm IF, AND, OR và các hàm khác để chạy các kiểm tra lô-gic cần thiết. Đây là một ví dụ về công thức IF AND OR kiểm tra một vàiOR điều kiện trong AND. Và bây giờ, tôi sẽ chỉ cho bạn cách bạn có thể thực hiện hai hoặc nhiều phép thử AND trong hàm OR.

Giả sử, bạn muốn đánh dấu đơn đặt hàng của hai khách hàng với số tiền lớn hơn một số nhất định, chẳng hạn như $100.

Trong ngôn ngữ Excel, các điều kiện của chúng tôi được thể hiện theo cách này:

OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

Giả sử tên khách hàng ở cột B, số tiền ở cột C, 2 tên mục tiêu nằm trong G1 và G2 và số tiền mục tiêu nằm trong G3, bạn sử dụng công thức này để đánh dấu các đơn đặt hàng tương ứng bằng "x":

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Có thể đạt được kết quả tương tự với nhiều hơn cú pháp nhỏ gọn:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

Bạn không chắc mình hoàn toàn hiểu logic của công thức? Bạn có thể tìm thêm thông tin trong Excel IF với nhiều điều kiện AND/OR.

Đó là cách bạn sử dụng hàm IF và AND cùng nhau trong Excel. Cảm ơn bạn đã đọc và hẹn gặp lại bạn vào tuần tới!

Sách bài tập thực hành

IF AND Excel – ví dụ về công thức (tệp .xlsx)