Το σεμινάριο δείχνει πώς να χρησιμοποιείτε το IF μαζί με τη συνάρτηση AND στο Excel για να ελέγχετε πολλαπλές συνθήκες σε έναν τύπο.

Μερικά πράγματα στον κόσμο είναι πεπερασμένα. Άλλα είναι άπειρα, και η συνάρτηση IF φαίνεται να είναι ένα από αυτά τα πράγματα. Στο ιστολόγιό μας, έχουμε ήδη μια χούφτα σεμινάρια για την IF του Excel και εξακολουθούμε να ανακαλύπτουμε νέες χρήσεις κάθε μέρα. Σήμερα, θα δούμε πώς μπορείτε να χρησιμοποιήσετε την IF μαζί με τη συνάρτηση AND για να αξιολογήσετε δύο ή περισσότερες συνθήκες ταυτόχρονα.

Δήλωση IF AND στο Excel

Για να δημιουργήσετε τη δήλωση IF AND, πρέπει προφανώς να συνδυάσετε τις συναρτήσεις IF και AND σε έναν τύπο. Ακούστε πώς:

Μεταφρασμένος σε απλά αγγλικά, ο τύπος έχει ως εξής: ΑΝ η συνθήκη 1 είναι αληθής ΚΑΙ η συνθήκη 2 είναι αληθής, κάνε ένα πράγμα, διαφορετικά κάνε κάτι άλλο.

Για παράδειγμα, ας φτιάξουμε έναν τύπο που ελέγχει αν το B2 είναι "παραδοτέο" και το C2 δεν είναι κενό και ανάλογα με τα αποτελέσματα κάνει ένα από τα ακόλουθα:

• Εάν και οι δύο συνθήκες είναι ΑΛΗΘΙΝΕΣ, χαρακτηρίστε την παραγγελία ως "Κλειστή".
• Εάν μία από τις δύο συνθήκες είναι FALSE ή και οι δύο είναι FALSE, τότε επιστρέφεται ένα κενό αλφαριθμητικό ("").

=IF(AND(B2="παραδοτέο", C2""), "Κλειστό", "")

Το παρακάτω στιγμιότυπο οθόνης δείχνει τη συνάρτηση IF AND στο Excel:

Αν θέλετε να επιστρέψετε κάποια τιμή σε περίπτωση που το λογικό τεστ καταλήξει σε FALSE, δώστε την τιμή αυτή στην εντολή value_if_false επιχείρημα. Για παράδειγμα:

=IF(AND(B2="παραδοτέο", C2""), "Κλειστό", "Ανοιχτό")

Ο τροποποιημένος τύπος δίνει την ένδειξη "Κλειστό" εάν η στήλη Β είναι "παραδοτέα" και η Γ έχει οποιαδήποτε ημερομηνία (μη κενή). Σε όλες τις άλλες περιπτώσεις, δίνει την ένδειξη "Ανοιχτό":

Σημείωση. Όταν χρησιμοποιείτε έναν τύπο IF AND στο Excel για την αξιολόγηση συνθηκών κειμένου, λάβετε υπόψη σας ότι τα πεζά και κεφαλαία αντιμετωπίζονται ως ο ίδιος χαρακτήρας. Εάν αναζητάτε έναν τύπο IF AND με ευαισθησία στην πεζότητα, τυλίξτε ένα ή περισσότερα ορίσματα του AND στη συνάρτηση EXACT, όπως γίνεται στο παράδειγμα που παρατίθεται στον σύνδεσμο.

Τώρα που γνωρίζετε τη σύνταξη της δήλωσης IF AND του Excel, επιτρέψτε μου να σας δείξω τι είδους εργασίες μπορεί να επιλύσει.

Excel IF: μεγαλύτερο από και μικρότερο από

Στο προηγούμενο παράδειγμα, ελέγξαμε δύο συνθήκες σε δύο διαφορετικά κελιά. Αλλά μερικές φορές μπορεί να χρειαστεί να εκτελέσετε δύο ή περισσότερες δοκιμές στο ίδιο κελί. Ένα τυπικό παράδειγμα είναι ο έλεγχος αν η τιμή ενός κελιού είναι μεταξύ δύο αριθμών Η συνάρτηση IF AND του Excel μπορεί εύκολα να το κάνει και αυτό!

Ας υποθέσουμε ότι έχετε ορισμένους αριθμούς πωλήσεων στη στήλη Β και σας ζητείται να επισημάνετε τα ποσά που είναι μεγαλύτερα από $50 αλλά μικρότερα από $100. Για να το κάνετε, εισάγετε αυτόν τον τύπο στη στήλη C2 και στη συνέχεια αντιγράψτε τον προς τα κάτω στη στήλη:

=IF(AND(B2>50, B2<100), "x", "")

Εάν πρέπει να συμπεριλάβετε το οριακές τιμές (50 και 100), χρησιμοποιήστε το μικρότερη ή ίση με τελεστής (<=) και μεγαλύτερη ή ίση με (>=) τελεστής:

=IF(AND(B2>=50, B2<=100), "x", "")

Για να επεξεργαστείτε κάποιες άλλες οριακές τιμές χωρίς να αλλάξετε τον τύπο, εισαγάγετε τους ελάχιστους και τους μέγιστους αριθμούς σε δύο ξεχωριστά κελιά και αναφερθείτε σε αυτά τα κελιά στον τύπο σας. Για να λειτουργήσει σωστά ο τύπος σε όλες τις γραμμές, φροντίστε να χρησιμοποιήσετε απόλυτες αναφορές για τα οριακά κελιά ($F$1 και $F$2 στην περίπτωσή μας):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Χρησιμοποιώντας έναν παρόμοιο τύπο, μπορείτε να ελέγξετε αν ένα ημερομηνία πέφτει μέσα σε ένα καθορισμένο εύρος .

Για παράδειγμα, ας επισημάνουμε ημερομηνίες μεταξύ 10-Sep-2018 και 30-Sep-2018, συμπεριλαμβανομένων. Ένα μικρό εμπόδιο είναι ότι οι ημερομηνίες δεν μπορούν να παρέχονται απευθείας στις λογικές δοκιμές. Για να κατανοήσει το Excel τις ημερομηνίες, θα πρέπει να περικλείονται στη συνάρτηση DATEVALUE, όπως παρακάτω:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Ή απλά εισάγετε το Από το και Προς ημερομηνίες σε δύο κελιά ($F$1 και $F$2 σε αυτό το παράδειγμα) και να τις "τραβήξετε" από αυτά τα κελιά χρησιμοποιώντας τον ήδη γνωστό τύπο IF AND:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Για περισσότερες πληροφορίες, ανατρέξτε στη δήλωση IF του Excel μεταξύ δύο αριθμών ή ημερομηνιών.

ΑΝ αυτό ΚΑΙ εκείνο, τότε υπολογίστε κάτι

Εκτός από την επιστροφή προκαθορισμένων τιμών, η συνάρτηση IF AND του Excel μπορεί επίσης να εκτελέσει διαφορετικούς υπολογισμούς ανάλογα με το αν οι καθορισμένες συνθήκες είναι TRUE ή FALSE.

Για να καταδείξουμε την προσέγγιση, θα υπολογίσουμε ένα μπόνους 5% για "Κλειστές" πωλήσεις με ποσό μεγαλύτερο ή ίσο των 100 δολαρίων.

Υποθέτοντας ότι το ποσό βρίσκεται στη στήλη Β και η κατάσταση της παραγγελίας στη στήλη Γ, ο τύπος έχει ως εξής:

=IF(AND(B2>=100, C2="κλειστό"), B2*10%, 0)

Ο παραπάνω τύπος αποδίδει μηδέν στις υπόλοιπες εντολές ( value_if_false = 0). Εάν είστε πρόθυμοι να δώσετε ένα μικρό μπόνους τόνωσης, π.χ. 3%, στις παραγγελίες που δεν πληρούν τις προϋποθέσεις, συμπεριλάβετε την αντίστοιχη εξίσωση στην value_if_false επιχείρημα:

=IF(AND(B2>=100, C2="κλειστό"), B2*10%, B2*3%)

Πολλαπλές δηλώσεις IF AND στο Excel

Όπως ίσως έχετε παρατηρήσει, έχουμε αξιολογήσει μόνο δύο κριτήρια σε όλα τα παραπάνω παραδείγματα. Αλλά δεν υπάρχει τίποτα που να σας εμποδίζει να συμπεριλάβετε τρεις και περισσότερες δοκιμές στους τύπους IF AND, αρκεί να συμμορφώνονται με αυτούς τους γενικούς περιορισμούς του Excel:

• Στο Excel 2007 και νεότερες εκδόσεις, σε έναν τύπο μπορούν να χρησιμοποιηθούν έως και 255 ορίσματα, ενώ το συνολικό μήκος του τύπου δεν μπορεί να υπερβαίνει τους 8.192 χαρακτήρες.
• Στο Excel 2003 και νεότερες εκδόσεις, δεν επιτρέπονται περισσότερα από 30 ορίσματα, με συνολικό μήκος που δεν υπερβαίνει τους 1.024 χαρακτήρες.

Ως παράδειγμα πολλαπλών συνθηκών AND, αναλογιστείτε αυτές:

• Το ποσό (Β2) πρέπει να είναι μεγαλύτερο ή ίσο με 100 $.
• Η κατάσταση της παραγγελίας (C2) είναι "Κλειστό"
• Η ημερομηνία παράδοσης (D2) είναι εντός του τρέχοντος μήνα

Τώρα, χρειαζόμαστε μια δήλωση IF AND για να προσδιορίσουμε τις παραγγελίες για τις οποίες και οι 3 συνθήκες είναι ΑΛΗΘΙΝΕΣ. Και εδώ είναι:

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

Δεδομένου ότι ο "τρέχων μήνας" κατά τη στιγμή της σύνταξης του κειμένου ήταν ο Οκτώβριος, ο τύπος παρέχει τα παρακάτω αποτελέσματα:

Ενσωματωμένες δηλώσεις IF AND

Όταν εργάζεστε με μεγάλα φύλλα εργασίας, υπάρχει πιθανότητα να χρειαστεί να ελέγξετε μερικά σύνολα διαφορετικών κριτηρίων AND κάθε φορά. Για το σκοπό αυτό, παίρνετε έναν κλασικό ένθετο τύπο IF του Excel και επεκτείνετε τις λογικές δοκιμές του με δηλώσεις AND, όπως εδώ:

Για να καταλάβετε τη γενική ιδέα, δείτε το ακόλουθο παράδειγμα.

Ας υποθέσουμε ότι θέλετε να αξιολογήσετε την υπηρεσία σας με βάση το κόστος αποστολής και τον εκτιμώμενο χρόνο παράδοσης (ETD):

• Εξαιρετικό : κόστος αποστολής κάτω από $20 και ETD κάτω από 3 ημέρες
• Φτωχό : κόστος αποστολής πάνω από 30 δολάρια και ETD πάνω από 5 ημέρες
• Μέσος όρος : οτιδήποτε ενδιάμεσο

Για να το πετύχετε, γράφετε δύο μεμονωμένες δηλώσεις IF AND:

IF(AND(B2<20, C2<3), "Excellent", ...)

IF(AND(B2>30, C2>5), "Φτωχός", ...)

...και να φωλιάσει το ένα μέσα στο άλλο:

=IF(AND(B2>30, C2>5), "Κακή", IF(AND(B2<20, C2<3), "Εξαιρετική", "Μέτρια"))

Το αποτέλεσμα θα μοιάζει με αυτό:

Περισσότερα παραδείγματα τύπων μπορείτε να βρείτε στο Excel nested IF AND statements.

Συνάρτηση IF AND με ευαισθησία στην πεζότητα στο Excel

Όπως αναφέρθηκε στην αρχή αυτού του σεμιναρίου, οι τύποι IF AND του Excel δεν κάνουν διάκριση μεταξύ κεφαλαίων και πεζών χαρακτήρων, επειδή η συνάρτηση AND δεν λαμβάνει υπόψη την πεζότητα από τη φύση της.

Εάν εργάζεστε με case-sensitive δεδομένα και θέλετε να αξιολογήσετε τις συνθήκες AND λαμβάνοντας υπόψη την περίπτωση κειμένου, κάντε κάθε μεμονωμένη λογική δοκιμή μέσα στη συνάρτηση EXACT και ενσωματώστε αυτές τις συναρτήσεις στην εντολή AND:

Για αυτό το παράδειγμα, θα επισημάνουμε τις παραγγελίες ενός συγκεκριμένου πελάτη (π.χ. της εταιρείας με την επωνυμία Κυβερνοχώρος ) με ποσό που υπερβαίνει έναν ορισμένο αριθμό, ας πούμε 100 δολάρια.

Όπως μπορείτε να δείτε στο παρακάτω στιγμιότυπο οθόνης, ορισμένα ονόματα εταιρειών στη στήλη Β μοιάζουν με το ίδιο εξώδικο με τους χαρακτήρες, και παρ' όλα αυτά είναι διαφορετικές εταιρείες, οπότε πρέπει να ελέγξουμε τα ονόματα ακριβώς Τα ποσά στη στήλη C είναι αριθμοί και εκτελούμε μια κανονική δοκιμή "μεγαλύτερο από" για αυτά:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Για να κάνετε τον τύπο πιο ευέλικτο, μπορείτε να εισαγάγετε το όνομα του πελάτη-στόχου και το ποσό σε δύο ξεχωριστά κελιά και να αναφέρεστε σε αυτά τα κελιά. Απλά θυμηθείτε να κλειδώσετε τις αναφορές των κελιών με το σύμβολο $ ($G$1 και $G$2 στην περίπτωσή μας), ώστε να μην αλλάζουν όταν αντιγράφετε τον τύπο σε άλλες γραμμές:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Τώρα, μπορείτε να πληκτρολογήσετε οποιοδήποτε όνομα και ποσό στα αναφερόμενα κελιά και ο τύπος θα επισημάνει τις αντίστοιχες παραγγελίες στον πίνακα σας:

Τύπος IF OR AND στο Excel

Στους τύπους IF του Excel, δεν περιορίζεστε στη χρήση μόνο μιας λογικής συνάρτησης. Για να ελέγξετε διάφορους συνδυασμούς πολλαπλών συνθηκών, είστε ελεύθεροι να συνδυάσετε τις συναρτήσεις IF, AND, OR και άλλες συναρτήσεις για να εκτελέσετε τους απαιτούμενους λογικούς ελέγχους. Εδώ είναι ένα παράδειγμα τύπου IF AND OR που ελέγχει δύο συνθήκες OR μέσα στο AND. Και τώρα, θα σας δείξω πώς μπορείτε να κάνετε δύο ή περισσότερες δοκιμές AND μέσα στο ORλειτουργία.

Ας υποθέσουμε ότι επιθυμείτε να επισημάνετε τις παραγγελίες δύο πελατών με ποσό μεγαλύτερο από έναν ορισμένο αριθμό, ας πούμε 100 δολάρια.

Στη γλώσσα του Excel, οι όροι μας εκφράζονται ως εξής:

OR(AND( Πελάτης1 , Ποσό >100), AND( Πελάτης2 , Ποσό >100)

Υποθέτοντας ότι τα ονόματα των πελατών βρίσκονται στη στήλη Β, τα ποσά στη στήλη Γ, τα 2 ονόματα στόχων βρίσκονται στα G1 και G2 και το ποσό-στόχος βρίσκεται στο G3, χρησιμοποιείτε αυτόν τον τύπο για να επισημάνετε τις αντίστοιχες παραγγελίες με "x":

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Τα ίδια αποτελέσματα μπορούν να επιτευχθούν με μια πιο συμπαγή σύνταξη:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

Δεν είστε σίγουροι ότι έχετε κατανοήσει πλήρως τη λογική του τύπου; Περισσότερες πληροφορίες μπορείτε να βρείτε στο Excel IF με πολλαπλές συνθήκες AND/OR.

Έτσι χρησιμοποιείτε τις συναρτήσεις IF και AND μαζί στο Excel. Σας ευχαριστούμε για την ανάγνωση και τα λέμε την επόμενη εβδομάδα!

Βιβλίο ασκήσεων

IF AND Excel - παραδείγματα τύπων (.xlsx αρχείο)