ٹیوٹوریل دکھاتا ہے کہ ایک فارمولے میں متعدد شرائط کو چیک کرنے کے لیے ایکسل میں AND فنکشن کے ساتھ IF کا استعمال کیسے کریں۔

دنیا میں کچھ چیزیں محدود ہیں۔ دوسرے لامحدود ہیں، اور IF فنکشن ایسی چیزوں میں سے ایک لگتا ہے۔ ہمارے بلاگ پر، ہمارے پاس پہلے سے ہی مٹھی بھر Excel IF ٹیوٹوریلز موجود ہیں اور پھر بھی ہر روز نئے استعمال دریافت کرتے ہیں۔ آج، ہم یہ دیکھنے جا رہے ہیں کہ آپ بیک وقت دو یا دو سے زیادہ شرائط کا اندازہ لگانے کے لیے AND فنکشن کے ساتھ IF کو کس طرح استعمال کر سکتے ہیں۔

ایکسل میں IF اور اسٹیٹمنٹ

IF AND سٹیٹمنٹ بنانے کے لیے، آپ کو ظاہر ہے کہ IF اور AND فنکشنز کو ایک فارمولے میں ملانا ہو گا۔ یہاں طریقہ ہے:

سادہ انگریزی میں ترجمہ کیا گیا، فارمولہ اس طرح پڑھتا ہے: IF شرط 1 صحیح ہے اور شرط 2 درست ہے، ایک کام کرو، ورنہ کچھ اور کرو۔

مثال کے طور پر، آئیے ایک فارمولہ بناتے ہیں جو چیک کرتا ہے کہ آیا B2 "ڈیلیور" ہوا ہے اور C2 خالی نہیں ہے، اور نتائج پر منحصر ہے , مندرجہ ذیل میں سے ایک کرتا ہے:

• اگر دونوں شرائط درست ہیں، تو آرڈر کو "بند" کے بطور نشان زد کریں۔
• اگر دونوں میں سے کوئی ایک شرط غلط ہے یا دونوں غلط ہیں، تو خالی واپس کریں۔ سٹرنگ ("")۔

=IF(AND(B2="delivered", C2""), "Closed", "")

نیچے دیا گیا اسکرین شاٹ ایکسل میں IF AND فنکشن دکھاتا ہے:

اگر آپ اگر منطقی ٹیسٹ FALSE کی تشخیص کرتا ہے تو کچھ قدر واپس کرنا چاہتا ہوں، اس قدر کو value_if_false میں فراہم کریں۔دلیل. مثال کے طور پر:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

تبدیل شدہ فارمولہ "بند" نکلتا ہے اگر کالم B "ڈیلیور" ہو اور C میں کوئی تاریخ ہو (غیر خالی)۔ دیگر تمام معاملات میں، یہ "Open":

نوٹ لوٹاتا ہے۔ ایکسل میں IF AND فارمولہ استعمال کرتے وقت ٹیکسٹ حالات کا اندازہ لگاتے ہیں، براہ کرم ذہن میں رکھیں کہ چھوٹے اور بڑے حروف کو ایک ہی کردار کے طور پر سمجھا جاتا ہے۔ اگر آپ کیس سے متعلق حساس IF AND فارمولہ تلاش کر رہے ہیں تو AND کے ایک یا زیادہ دلائل کو EXACT فنکشن میں لپیٹیں جیسا کہ لنک کردہ مثال میں کیا گیا ہے۔

اب جب کہ آپ Excel IF AND اسٹیٹمنٹ کا نحو جانتے ہیں، تو میں آپ کو دکھاتا ہوں کہ یہ کس قسم کے کاموں کو حل کر سکتا ہے۔

Excel IF: سے بڑا اور اس سے کم

میں پچھلی مثال، ہم دو مختلف خلیوں میں دو حالات کی جانچ کر رہے تھے۔ لیکن بعض اوقات آپ کو ایک ہی سیل پر دو یا زیادہ ٹیسٹ چلانے کی ضرورت پڑ سکتی ہے۔ ایک عام مثال یہ جانچ رہی ہے کہ آیا سیل کی قیمت دو نمبروں کے درمیان ہے ۔ Excel IF AND فنکشن بھی آسانی سے ایسا کر سکتا ہے!

آئیے کہتے ہیں کہ آپ کے پاس کالم B میں کچھ سیلز نمبر ہیں اور آپ سے درخواست ہے کہ $50 سے زیادہ لیکن $100 سے کم رقم کو جھنڈا لگائیں۔ اسے مکمل کرنے کے لیے، اس فارمولے کو C2 میں داخل کریں اور پھر اسے کالم کے نیچے کاپی کریں:

=IF(AND(B2>50, B2<100), "x", "")

اگر آپ کو باؤنڈری شامل کرنے کی ضرورت ہے قدریں (50 اور 100)، سے کم یا اس کے برابر آپریٹر (<=) اور سے بڑا یا اس کے برابر (>=) آپریٹر کا استعمال کریں:

=IF(AND(B2>=50, B2<=100), "x", "")

کسی دوسرے پر کارروائی کرنے کے لیےفارمولے کو تبدیل کیے بغیر باؤنڈری ویلیوز، دو الگ سیلز میں کم از کم اور زیادہ سے زیادہ نمبر درج کریں اور اپنے فارمولے میں ان سیلز کا حوالہ دیں۔ تمام قطاروں میں فارمولہ درست طریقے سے کام کرنے کے لیے، باؤنڈری سیلز ($F$1 اور $F$2 ہمارے معاملے میں):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

کے لیے مطلق حوالہ جات کا استعمال یقینی بنائیں۔

اس سے ملتا جلتا فارمولہ استعمال کرکے، آپ چیک کر سکتے ہیں کہ آیا تاریخ ایک مخصوص رینج کے اندر آتی ہے ۔

مثال کے طور پر، آئیے 10 کے درمیان تاریخوں کو جھنڈا لگائیں۔ -Sep-2018 اور 30-Sep-2018، بشمول۔ ایک چھوٹی سی رکاوٹ یہ ہے کہ تاریخیں براہ راست منطقی امتحانات میں فراہم نہیں کی جا سکتیں۔ ایکسل کے لیے تاریخوں کو سمجھنے کے لیے، انہیں DATEVALUE فنکشن میں اس طرح بند کیا جانا چاہیے:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

یا صرف From اور To<2 داخل کریں دو سیلز میں تاریخیں ($F$1 اور $F$2 اس مثال میں) اور پہلے سے واقف IF AND فارمولہ استعمال کرکے انہیں ان سیلز سے "کھینچیں" کریں:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

مزید معلومات کے لیے، براہ کرم ایکسل IF اسٹیٹمنٹ کو دو نمبروں یا تاریخوں کے درمیان دیکھیں۔

اگر یہ اور وہ، پھر کچھ کا حساب لگائیں

پہلے سے طے شدہ اقدار واپس کرنے کے علاوہ، Excel IF AND فنکشن اس بات پر منحصر ہے کہ آیا متعین حالات درست ہیں یا غلط۔ مختلف حسابات بھی انجام دے سکتے ہیں۔

طریقہ کار کو ظاہر کرنے کے لیے، ہم "بند" سیلز کے لیے 5% بونس کا حساب لگا رہے ہیں جس کی رقم اس سے زیادہ یا اس کے برابر ہے۔ $100 تک۔

یہ فرض کرتے ہوئے کہ رقم کالم B میں ہے اور کالم C میں آرڈر کی حیثیت،فارمولہ مندرجہ ذیل ہے:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

اوپر والا فارمولا باقی آرڈرز کو صفر تفویض کرتا ہے ( value_if_false = 0) . اگر آپ ایک چھوٹا حوصلہ افزا بونس دینے کے لیے تیار ہیں، تو 3% کہیے، ایسے آرڈرز کے لیے جو شرائط پر پورا نہیں اترتے، value_if_false دلیل میں متعلقہ مساوات شامل کریں:

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

ایکسل میں ایک سے زیادہ IF اور اسٹیٹمنٹس

جیسا کہ آپ نے دیکھا ہوگا، ہم نے اوپر دی گئی تمام مثالوں میں صرف دو معیاروں کا جائزہ لیا ہے۔ لیکن ایسی کوئی چیز نہیں ہے جو آپ کو اپنے IF اور فارمولوں میں تین اور اس سے زیادہ ٹیسٹ شامل کرنے سے روکے جب تک کہ وہ Excel کی ان عمومی حدود کی تعمیل کرتے ہیں:

• ایکسل 2007 اور اس سے زیادہ میں، 255 تک دلائل فارمولے میں استعمال کیا جا سکتا ہے، جس میں فارمولے کی کل لمبائی 8,192 حروف سے زیادہ نہ ہو۔
• ایکسل 2003 اور اس سے کم میں، 30 سے ​​زیادہ دلائل کی اجازت نہیں ہے، جس کی کل لمبائی 1,024 حروف سے زیادہ نہ ہو۔

متعدد اور شرائط کی مثال کے طور پر، براہ کرم ان پر غور کریں:

• رقم (B2) $100 سے زیادہ یا اس کے برابر ہونی چاہیے
• آرڈر کی حیثیت (C2) کیا "بند" ہے
• ڈیلیوری کی تاریخ (D2) موجودہ مہینے کے اندر ہے

اب، ہمیں آرڈرز کی شناخت کے لیے IF اور اسٹیٹمنٹ کی ضرورت ہے جس کے لیے تمام 3 شرائط درست ہیں۔ اور یہ ہے:

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

یہ دیکھتے ہوئے کہ تحریر کے وقت 'موجودہ مہینہ' اکتوبر تھا، فارمولہ ذیل کے نتائج فراہم کرتا ہے:

نیسٹڈ IF ANDبیانات

بڑی ورک شیٹس کے ساتھ کام کرتے وقت، اس بات کے امکانات ہوتے ہیں کہ آپ کو ایک وقت میں مختلف اور معیارات کے چند سیٹ چیک کرنے کی ضرورت پڑسکتی ہے۔ اس کے لیے، آپ ایک کلاسک ایکسل نیسٹڈ IF فارمولہ لیتے ہیں اور اس کے منطقی ٹیسٹ کو AND اسٹیٹمنٹس کے ساتھ بڑھاتے ہیں، اس طرح:

عام خیال حاصل کرنے کے لیے، براہ کرم درج ذیل مثال کو دیکھیں۔

فرض کریں کہ آپ شپمنٹ کی لاگت اور ڈیلیوری کے تخمینی وقت (ETD) کی بنیاد پر اپنی سروس کی درجہ بندی کرنا چاہتے ہیں:

• بہترین : شپمنٹ کی قیمت $20 سے کم اور ETD 3 دن سے کم
• ناقص : کھیپ کی قیمت $30 سے ​​زیادہ اور ETD 5 دنوں میں
• اوسط : اس کے درمیان کچھ بھی

تک اسے مکمل کرو، آپ دو انفرادی IF AND اسٹیٹمنٹس لکھتے ہیں:

IF(AND(B2<20, C2<3), "Excellent", …)

IF(AND(B2>30, C2>5), "Poor", …)

…اور ایک کو دوسرے میں نیسٹ کریں:

=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

نتیجہ اس سے ملتا جلتا نظر آئے گا:

مزید فارمولے کی مثالیں Excel nested IF AND سٹیٹمنٹس میں مل سکتی ہیں۔

کیس حساس IF AND ایکسل میں فنکشن

جیسا کہ اس ٹیوٹوریل کے آغاز میں بتایا گیا ہے، Excel IF اور فارمولے بڑے اور چھوٹے حروف میں فرق نہیں کرتے کیونکہ AND فنکشن فطرت کے لحاظ سے کیس کے لیے غیر حساس ہے۔

اگر آپ کیس حساس ڈیٹا کے ساتھ کام کر رہے ہیں اور ٹیکسٹ کیس کو مدنظر رکھتے ہوئے AND حالات کا جائزہ لینا چاہتے ہیں تو ہر فرد کی منطقی جانچ کریں۔ EXACT فنکشن اور نیسٹ کے اندروہ فنکشنز آپ کے AND اسٹیٹمنٹ میں:

اس مثال کے لیے، ہم ایک مخصوص گاہک (جیسے سائبر اسپیس نامی کمپنی) کے آرڈرز کو جھنڈا لگانے جا رہے ہیں جس کی رقم ایک خاص تعداد سے زیادہ ہے، کہتے ہیں $100۔

جیسا کہ آپ نیچے دیے گئے اسکرین شاٹ میں دیکھ سکتے ہیں، کالم B میں کچھ کمپنیوں کے نام کرداروں کے معاملے میں ایک ہی اقتباس میں نظر آتے ہیں، اور اس کے باوجود وہ مختلف کمپنیاں ہیں، اس لیے ہمیں ناموں کو چیک کرنا ہوگا بالکل ۔ کالم C میں مقداریں نمبرز ہیں، اور ہم ان کے لیے باقاعدہ "زیادہ سے بڑا" ٹیسٹ چلاتے ہیں:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

فارمولے کو مزید لچکدار بنانے کے لیے، آپ ہدف والے صارف کا نام اور رقم درج کر سکتے ہیں۔ دو الگ الگ خلیوں میں اور ان خلیوں کا حوالہ دیں۔ بس یاد رکھیں کہ سیل حوالوں کو $sign ($G$1 اور $G$2 ہمارے معاملے میں) کے ساتھ مقفل کریں تاکہ جب آپ فارمولہ کو دوسری قطاروں میں کاپی کریں گے تو وہ تبدیل نہیں ہوں گے:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

اب، آپ حوالہ شدہ سیلز میں کوئی بھی نام اور رقم ٹائپ کر سکتے ہیں، اور فارمولہ آپ کے ٹیبل میں متعلقہ آرڈرز کو جھنڈا لگائے گا:

ایکسل میں اگر یا اور فارمولہ

ایکسل IF فارمولوں میں، آپ صرف ایک منطقی فنکشن استعمال کرنے تک محدود نہیں ہیں۔ متعدد شرائط کے مختلف مجموعوں کو چیک کرنے کے لیے، آپ مطلوبہ منطقی ٹیسٹ چلانے کے لیے IF، AND، OR اور دیگر افعال کو یکجا کرنے کے لیے آزاد ہیں۔ یہاں IF AND OR فارمولہ کی ایک مثال ہے جو کہ ایک جوڑے کی جانچ کرتی ہے۔یا AND کے اندر حالات۔ اور اب، میں آپ کو دکھاؤں گا کہ آپ OR فنکشن کے اندر دو یا دو سے زیادہ اور ٹیسٹ کیسے کر سکتے ہیں۔

فرض کریں، آپ دو کسٹمرز کے آرڈرز کو ایک مخصوص نمبر سے زیادہ رقم کے ساتھ نشان زد کرنا چاہتے ہیں، کہیے کہ $100۔

ایکسل کی زبان میں، ہماری شرائط کا اظہار اس طرح کیا جاتا ہے:

OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

یہ فرض کرتے ہوئے کہ گاہک کے نام کالم B میں ہیں، کالم C میں رقم، 2 ہدف کے نام G1 اور G2 میں ہیں، اور ہدف کی رقم G3 میں ہے، آپ متعلقہ آرڈرز کو "x" کے ساتھ نشان زد کرنے کے لیے اس فارمولے کا استعمال کرتے ہیں:

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

اسی نتائج کو مزید حاصل کیا جا سکتا ہے۔ کمپیکٹ نحو:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

یقین نہیں کہ آپ فارمولے کی منطق کو پوری طرح سمجھتے ہیں؟ مزید معلومات Excel IF میں متعدد AND/OR شرائط کے ساتھ مل سکتی ہیں۔

اس طرح آپ Excel میں IF اور AND فنکشنز کو ایک ساتھ استعمال کرتے ہیں۔ پڑھنے کے لیے آپ کا شکریہ اور اگلے ہفتے ملیں گے!

پریکٹس ورک بک

IF AND Excel – فارمولے کی مثالیں (.xlsx فائل)