Bu eğitimde, tek bir formülde birden fazla koşulu kontrol etmek için Excel'de EĞER ile birlikte VE işlevinin nasıl kullanılacağı gösterilmektedir.

Dünyadaki bazı şeyler sonlu, bazıları ise sonsuzdur ve IF fonksiyonu da bu tür şeylerden biri gibi görünüyor. Blogumuzda, halihazırda bir avuç Excel IF öğreticimiz var ve hala her gün yeni kullanımlar keşfediyoruz. Bugün, aynı anda iki veya daha fazla koşulu değerlendirmek için IF'yi AND işleviyle birlikte nasıl kullanabileceğinize bakacağız.

Excel'de EĞER VE deyimi

EĞER VE ifadesini oluşturmak için, EĞER ve VE işlevlerini tek bir formülde birleştirmeniz gerekir. İşte nasıl yapılacağı:

Düz İngilizceye çevrildiğinde formül şu şekildedir: EĞER koşul 1 doğruysa VE koşul 2 doğruysa, bir şey yap, aksi takdirde başka bir şey yap.

Örnek olarak, B2'nin "teslim edildi" olup olmadığını ve C2'nin boş olup olmadığını kontrol eden ve sonuçlara bağlı olarak aşağıdakilerden birini yapan bir formül yapalım:

• Her iki koşul da DOĞRU ise, siparişi "Kapalı" olarak işaretleyin.
• Koşullardan biri YANLIŞ veya her ikisi de YANLIŞ ise, boş bir dize ("") döndürür.

=IF(AND(B2="teslim edildi", C2""), "Kapalı", "")

Aşağıdaki ekran görüntüsü Excel'deki EĞER VE işlevini göstermektedir:

Mantıksal testin FALSE olarak değerlendirilmesi durumunda bir değer döndürmek istiyorsanız, bu değeri value_if_false argüman. Örneğin:

=IF(AND(B2="teslim edildi", C2""), "Kapalı", "Açık")

Değiştirilen formül, B sütunu "teslim edildi" ise ve C'de herhangi bir tarih varsa (boş olmayan) "Kapalı" çıktısı verir. Diğer tüm durumlarda "Açık" çıktısı verir:

Not: Metin koşullarını değerlendirmek için Excel'de EĞER VE formülü kullanırken, küçük ve büyük harflerin aynı karakter olarak ele alındığını lütfen unutmayın. Büyük/küçük harfe duyarlı bir EĞER VE formülü arıyorsanız, bağlantılı örnekte yapıldığı gibi, bir veya daha fazla AND bağımsız değişkenini TAM işlevine sarın.

Artık Excel IF AND deyiminin sözdizimini bildiğinize göre, size ne tür görevleri çözebileceğini göstereyim.

Excel EĞER: daha büyük VE daha küçük

Önceki örnekte, iki farklı hücrede iki koşulu test ediyorduk. Ancak bazen aynı hücre üzerinde iki veya daha fazla test çalıştırmanız gerekebilir. Tipik bir örnek, bir hücre değerinin iki sayı arasında Excel EĞER VE işlevi bunu da kolayca yapabilir!

Diyelim ki B sütununda bazı satış rakamlarınız var ve sizden 50 $'dan büyük ancak 100 $'dan küçük tutarları işaretlemeniz isteniyor. Bunu yapmak için, bu formülü C2'ye ekleyin ve ardından sütundan aşağı kopyalayın:

=IF(AND(B2>50, B2<100), "x", "")

Eklemeniz gerekiyorsa sınır değerleri (50 ve 100), kullanın daha az veya eşit operatörü (<=) ve 'den büyük veya eşit (>=) operatörü:

=IF(AND(B2>=50, B2<=100), "x", "")

Formülü değiştirmeden diğer bazı sınır değerleri işlemek için, minimum ve maksimum sayıları iki ayrı hücreye girin ve formülünüzde bu hücrelere atıfta bulunun. Formülün tüm satırlarda doğru çalışması için, sınır hücreleri için mutlak referanslar kullandığınızdan emin olun (bizim durumumuzda $F$1 ve $F$2):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Benzer bir formül kullanarak, bir Tarih düşer belirli bir aralık içinde .

Örneğin, 10-Eylül-2018 ile 30-Eylül-2018 arasındaki tarihleri işaretleyelim. Küçük bir engel, tarihlerin mantıksal testlere doğrudan sağlanamamasıdır. Excel'in tarihleri anlaması için, aşağıdaki gibi DATEVALUE işlevi içine alınmaları gerekir:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Ya da sadece Kimden ve için tarihleri iki hücrede (bu örnekte $F$1 ve $F$2) toplayın ve zaten tanıdık olan EĞER VE formülünü kullanarak bu hücrelerden "çekin":

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Daha fazla bilgi için lütfen iki sayı veya tarih arasındaki Excel IF deyimine bakın.

EĞER bu VE bu ise, o zaman bir şey hesaplayın

Excel EĞER VE işlevi, önceden tanımlanmış değerleri döndürmenin yanı sıra, belirtilen koşulların DOĞRU veya YANLIŞ olmasına bağlı olarak farklı hesaplamalar da gerçekleştirebilir.

Yaklaşımı göstermek için, tutarı 100 $ veya daha fazla olan "Kapalı" satışlar için %5'lik bir bonus hesaplayacağız.

Tutarın B sütununda ve sipariş durumunun C sütununda olduğunu varsayarsak, formül aşağıdaki gibi olur:

=IF(AND(B2>=100, C2="kapalı"), B2*10%, 0)

Yukarıdaki formül geri kalan emirlere sıfır atar ( value_if_false = Koşulları karşılamayan siparişlere %3 gibi küçük bir teşvik primi vermeye istekliyseniz, ilgili denklemi value_if_false Tartışma:

=IF(AND(B2>=100, C2="kapalı"), B2*10%, B2*3%)

Excel'de birden çok EĞER VE ifadesi

Fark etmiş olabileceğiniz gibi, yukarıdaki tüm örneklerde sadece iki kriteri değerlendirdik. Ancak, Excel'in bu genel sınırlamalarına uydukları sürece EĞER VE formüllerinize üç ve daha fazla test eklemenizi engelleyecek hiçbir şey yoktur:

• Excel 2007 ve sonraki sürümlerde, bir formülde en fazla 255 bağımsız değişken kullanılabilir ve toplam formül uzunluğu 8.192 karakteri geçemez.
• Excel 2003 ve daha düşük sürümlerde, toplam uzunluğu 1.024 karakteri aşmayacak şekilde 30'dan fazla bağımsız değişkene izin verilmez.

Çoklu VE koşullarına örnek olarak lütfen şunları göz önünde bulundurun:

• Tutar (B2) 100 $'dan büyük veya eşit olmalıdır
• Sipariş durumu (C2) "Kapalı"
• Teslim tarihi (D2) cari ay içinde

Şimdi, 3 koşulun da DOĞRU olduğu siparişleri belirlemek için bir EĞER VE ifadesine ihtiyacımız var ve işte burada:

=IF(AND(B2>=100, C2="Kapalı", MONTH(D2)=MONTH(TODAY()), "x", "")

Yazının yazıldığı anda 'içinde bulunulan ayın' Ekim olduğu göz önünde bulundurulduğunda, formül aşağıdaki sonuçları vermektedir:

İç içe EĞER VE ifadeleri

Büyük çalışma sayfalarıyla çalışırken, bir seferde birkaç farklı AND ölçütü kümesini kontrol etmeniz gerekebilir. Bunun için, klasik bir Excel iç içe EĞER formülünü alır ve mantıksal testlerini bunun gibi AND ifadeleriyle genişletirsiniz:

Genel bir fikir edinmek için lütfen aşağıdaki örneğe bakın.

Hizmetinizi gönderi maliyeti ve tahmini teslimat süresine (ETD) göre derecelendirmek istediğinizi varsayalım:

• Mükemmel : 20 doların altında sevkiyat maliyeti ve 3 günün altında ETD
• Zayıf : gönderi ücreti 30 doların üzerinde ve ETD 5 günün üzerinde
• Ortalama Aradaki her şey

Bunu yapmak için iki ayrı IF AND ifadesi yazarsınız:

IF(AND(B2<20, C2<3), "Mükemmel", ...)

IF(AND(B2>30, C2>5), "Zayıf", ...)

...ve birini diğerinin içine yerleştirin:

=IF(AND(B2>30, C2>5), "Zayıf", IF(AND(B2<20, C2<3), "Mükemmel", "Ortalama"))

Sonuç buna benzer görünecektir:

Excel iç içe EĞER VE ifadelerinde daha fazla formül örneği bulunabilir.

Excel'de büyük/küçük harfe duyarlı EĞER VE işlevi

Bu eğitimin başında belirtildiği gibi, Excel EĞER VE formülleri büyük ve küçük harfler arasında ayrım yapmaz çünkü VE işlevi doğası gereği büyük/küçük harfe duyarsızdır.

Eğer birlikte çalışıyorsanız büyük/küçük harfe duyarlı verilerini ve metin durumunu dikkate alarak AND koşullarını değerlendirmek istiyorsanız, her bir mantıksal testi EXACT işlevinin içinde yapın ve bu işlevleri AND deyiminize yerleştirin:

Bu örnek için, belirli bir müşterinin siparişlerini işaretleyeceğiz (ör. Siber Uzay ) belirli bir rakamı, örneğin 100 $'ı aşan bir tutarla.

Aşağıdaki ekran görüntüsünde de görebileceğiniz gibi, B sütunundaki bazı şirket adları aynı görünmektedir, ancak bunlar farklı şirketlerdir, bu nedenle adları kontrol etmemiz gerekir tam olarak C sütunundaki tutarlar sayıdır ve bunlar için normal bir "büyüktür" testi uygularız:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Formülü daha esnek hale getirmek için, hedef müşteri adını ve tutarı iki ayrı hücreye girebilir ve bu hücrelere başvurabilirsiniz. Formülü diğer satırlara kopyaladığınızda değişmemeleri için hücre başvurularını $ işaretiyle (bizim durumumuzda $G$1 ve $G$2) kilitlemeyi unutmayın:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Şimdi, başvurulan hücrelere herhangi bir ad ve tutar yazabilirsiniz ve formül tablonuzdaki ilgili siparişleri işaretleyecektir:

Excel'de EĞER VEYA VE formülü

Excel EĞER formüllerinde, yalnızca bir mantıksal işlev kullanmakla sınırlı değilsiniz. Birden çok koşulun çeşitli kombinasyonlarını kontrol etmek için, gerekli mantıksal testleri çalıştırmak üzere EĞER, VE, VEYA ve diğer işlevleri birleştirmekte özgürsünüz. İşte VE içinde birkaç VE koşulunu test eden bir EĞER VE VEYA formülü örneği. Şimdi size VE içinde iki veya daha fazla VE testini nasıl yapabileceğinizi göstereceğimfonksiyon.

Diyelim ki, iki müşterinin siparişlerini belirli bir sayıdan, örneğin 100 $'dan daha büyük bir tutarla işaretlemek istiyorsunuz.

Excel dilinde koşullarımız bu şekilde ifade edilir:

VEYA(VE( Müşteri1 , Miktar >100), VE( Müşteri2 , Miktar >100)

Müşteri adlarının B sütununda, tutarların C sütununda, 2 hedef adın G1 ve G2'de ve hedef tutarın G3'te olduğunu varsayarsak, ilgili siparişleri "x" ile işaretlemek için bu formülü kullanırsınız:

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Aynı sonuçlar daha kompakt bir sözdizimi ile de elde edilebilir:

=IF(AND(OR(B2=$G$1,B2=$G$2), C2>$G$3), "x", "")

Formülün mantığını tam olarak anladığınızdan emin değil misiniz? Daha fazla bilgi için Excel IF with multiple AND/OR conditions bölümüne bakabilirsiniz.

Excel'de EĞER ve VE işlevlerini birlikte bu şekilde kullanabilirsiniz. Okuduğunuz için teşekkürler ve gelecek hafta görüşmek üzere!

Alıştırma çalışma kitabı

EĞER VE Excel - formül örnekleri (.xlsx dosyası)