Vodič pokazuje kako koristiti IF zajedno s funkcijom I u Excelu za provjeru više uvjeta u jednoj formuli.

Neke stvari u svijetu su konačne. Druge su beskonačne, a čini se da je funkcija IF jedna od takvih stvari. Na našem blogu već imamo pregršt vodiča za Excel IF i svaki dan otkrivamo nove namjene. Danas ćemo pogledati kako možete koristiti IF zajedno s funkcijom AND za procjenu dva ili više uvjeta u isto vrijeme.

IF I naredba u Excelu

Da biste izgradili naredbu IF AND, očito morate kombinirati IF i AND funkcije u jednoj formuli. Evo kako:

Prevedeno na običan engleski, formula glasi kako slijedi: IF uslov 1 je istina I uslov 2 je istinit, uradite jedno, u suprotnom uradite nešto drugo.

Kao primjer, napravimo formulu koja provjerava da li je B2 "isporučen", a C2 nije prazan, iu zavisnosti od rezultata , radi jedno od sljedećeg:

• Ako su oba uvjeta TRUE, označite nalog kao "Zatvoreno".
• Ako je bilo koji od uvjeta FALSE ili su oba FALSE, onda vratite prazan string ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

Snimak ekrana ispod prikazuje funkciju IF I u Excelu:

Ako Želio bih vratiti neku vrijednost u slučaju da logički test procijeni na FALSE, navedite tu vrijednost u value_if_false argument. Na primjer:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

Izmijenjena formula daje "Zatvoreno" ako je stupac B "isporučen" i C ima bilo koji datum u sebi (nije prazan). U svim ostalim slučajevima, vraća "Otvoreno":

Napomena. Kada koristite formulu IF I u Excelu za procjenu uslova teksta, imajte na umu da se mala i velika slova tretiraju kao isti znak. Ako tražite formulu IF AND koja je osjetljiva na velika i mala slova, umotajte jedan ili više argumenata AND u funkciju EXACT kao što je to učinjeno u povezanom primjeru.

Sada kada znate sintaksu naredbe Excel IF AND, dozvolite mi da vam pokažem kakve zadatke može riješiti.

Excel IF: veće od I manje od

U prethodni primjer, testirali smo dva stanja u dvije različite ćelije. Ali ponekad ćete možda morati da pokrenete dva ili više testova na istoj ćeliji. Tipičan primjer je provjera da li je vrijednost ćelije između dva broja . Excel IF AND funkcija može to lako učiniti!

Recimo da imate neke prodajne brojeve u koloni B i od vas se traži da označite iznose veće od 50 USD, ali manje od 100 USD. Da biste to učinili, umetnite ovu formulu u C2, a zatim je kopirajte niz kolonu:

=IF(AND(B2>50, B2<100), "x", "")

Ako trebate uključiti granicu vrijednosti (50 i 100), koristite manje ili jednako operator (<=) i veće ili jednako (>=) operator:

=IF(AND(B2>=50, B2<=100), "x", "")

Za obradu nekog drugoggranične vrijednosti bez promjene formule, unesite minimalni i maksimalni broj u dvije odvojene ćelije i uputite se na te ćelije u vašoj formuli. Da bi formula radila ispravno u svim redovima, obavezno koristite apsolutne reference za granične ćelije ($F$1 i $F$2 u našem slučaju):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Upotrebom slične formule, možete provjeriti da li datum spada unutar specificiranog raspona .

Na primjer, označimo datume između 10 -Sep-2018 i 30-sept-2018, uključujući. Mala prepreka je to što se datumi ne mogu direktno dostaviti logičkim testovima. Da bi Excel razumio datume, oni bi trebali biti zatvoreni u funkciji DATEVALUE, ovako:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Ili jednostavno unesite Od i Do datume u dvije ćelije ($F$1 i $F$2 u ovom primjeru) i "izvucite" ih iz tih ćelija koristeći već poznatu IF I formulu:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Za više informacija pogledajte Excel IF izraz između dva broja ili datuma.

Ako ovo I ono, onda izračunajte nešto

Osim vraćanja unaprijed definiranih vrijednosti, Excel IF Funkcija I također može izvršiti različite proračune ovisno o tome da li su navedeni uvjeti TRUE ili FALSE.

Da bismo demonstrirali pristup, izračunat ćemo bonus od 5% za "Zatvorenu" prodaju sa iznosom većim ili jednakim do $100.

Pod pretpostavkom da je iznos u koloni B, a status narudžbe u koloni C,formula ide kako slijedi:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

Gorenja formula dodjeljuje nulu ostatku naloga ( value_if_false = 0) . Ako ste voljni dati mali stimulativni bonus, recimo 3%, narudžbama koje ne ispunjavaju uvjete, uključite odgovarajuću jednačinu u argument value_if_false :

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

Više IF I naredbi u Excel-u

Kao što ste možda primijetili, procijenili smo samo dva kriterija u svim gornjim primjerima. Ali ne postoji ništa što bi vas spriječilo da u svoje formule IF I uključite tri i više testova sve dok su u skladu s ovim općim ograničenjima Excela:

• U Excelu 2007 i novijim, do 255 argumenata može se koristiti u formuli, čija ukupna dužina formule ne prelazi 8.192 znaka.
• U Excelu 2003 i starijim verzijama nije dozvoljeno više od 30 argumenata, a ukupna dužina ne prelazi 1.024 znaka.

Kao primjer višestrukih I uvjeta, razmotrite ove:

• Iznos (B2) bi trebao biti veći ili jednak $100
• Status narudžbe (C2) je "Zatvoreno"
• Datum isporuke (D2) je unutar tekućeg mjeseca

Sada nam je potrebna IF I izjava da identifikujemo narudžbe za koje su sva 3 uslova TRUE. A evo ga:

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

S obzirom da je 'trenutni mjesec' u trenutku pisanja bio oktobar, formula daje sljedeće rezultate:

Ugniježđeno IF ANDizjave

Kada radite s velikim radnim listovima, velike su šanse da ćete možda morati provjeriti nekoliko skupova različitih kriterija I istovremeno. Za ovo, uzimate klasičnu Excel formulu ugniježđenu IF i proširujete njene logičke testove sa AND naredbama, na primjer:

Da biste dobili opću ideju, pogledajte sljedeći primjer.

Pretpostavimo da želite ocijeniti svoju uslugu na osnovu cijene isporuke i procijenjenog vremena isporuke (ETD):

• Odlično : cijena isporuke ispod 20 USD i ETD ispod 3 dana
• Loše : troškovi dostave preko 30 USD i ETD za 5 dana
• Prosjek : sve između

Do završite, napišete dvije pojedinačne IF AND izjave:

IF(AND(B2<20, C2<3), "Excellent", …)

IF(AND(B2>30, C2>5), "Poor", …)

...i ugnijezdite jednu u drugu:

=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

Rezultat će izgledati slično ovome:

Više primjera formula može se naći u Excelu ugniježđenim IF AND naredbama.

Više malih i malih slova IF AND funkcija u Excelu

Kao što je spomenuto na početku ovog vodiča, Excel IF I formule ne razlikuju velika i mala slova jer je funkcija AND po prirodi neosjetljiva na velika i mala slova.

Ako radite sa podacima manim i malim slovima i želite procijeniti uslove I uzimajući u obzir mala i mala slova, uradite svaki pojedinačni logički test unutar funkcije EXACT i gnijezdote funkcije u vašu AND naredbu:

Za ovaj primjer, označit ćemo narudžbe određenog kupca (npr. kompanije pod nazivom Cyberspace ) s iznosom koji prelazi određeni broj, recimo 100 dolara.

Kao što možete vidjeti na snimku ekrana ispod, neka imena kompanija u koloni B izgledaju isto kao i mala slova, a ipak se radi o različitim kompanijama, tako da moramo provjeriti imena tačno . Iznosi u koloni C su brojevi i za njih provodimo redovni test "veće od":

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Da biste formulu učinili fleksibilnijom, možete unijeti ime i iznos ciljanog kupca u dvije odvojene ćelije i odnose se na te ćelije. Samo zapamtite da zaključate reference ćelije sa znakom $ ($G$1 i $G$2 u našem slučaju) kako se one neće promijeniti kada kopirate formulu u druge redove:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Sada možete upisati bilo koje ime i iznos u referencirane ćelije, a formula će označiti odgovarajuće narudžbe u vašoj tablici:

IF ILI I formula u Excelu

U Excel IF formulama niste ograničeni na korištenje samo jedne logičke funkcije. Da biste provjerili različite kombinacije više uvjeta, slobodni ste kombinirati IF, AND, OR i druge funkcije kako biste pokrenuli potrebne logičke testove. Evo primjera formule IF AND OR koja testira nekolikoILI uslovi unutar AND. A sada ću vam pokazati kako možete napraviti dva ili više I testova unutar funkcije ILI.

Pretpostavimo da želite da označite narudžbe dva kupca iznosom većim od određenog broja, recimo 100$.

U Excel jeziku, naši uslovi su izraženi na ovaj način:

OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

Pod pretpostavkom da su imena kupaca u koloni B, iznosi u koloni C, 2 ciljana imena su u G1 i G2, a ciljni iznos je u G3, koristite ovu formulu da označite odgovarajuće naloge sa "x":

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Isti rezultati se mogu postići sa više kompaktna sintaksa:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

Niste sigurni da potpuno razumijete logiku formule? Više informacija možete pronaći u Excelu IF sa više uslova I/ILI.

Tako koristite funkcije IF i AND zajedno u Excelu. Hvala vam što čitate i vidimo se sljedeće sedmice!

Vježbanje

IF I Excel – primjeri formula (.xlsx datoteka)