Töflureiknar bjóða upp á frábæran vettvang til að stjórna gagnatöflum. En eru einhverjar auðveldar Google Sheets aðgerðir fyrir daglega útreikninga? Kynntu þér það hér að neðan.

SUM aðgerð Google Sheets

Ég tel að mest nauðsynlega aðgerðin í töflum sé að finna heildarsummu mismunandi gilda. Það fyrsta sem kemur upp í hugann er að bæta við hverri einustu frumu sem vekur áhuga:

=E2+E4+E8+E13

En þessi formúla verður mjög tímafrek ef það eru of margar frumur til að taka tillit til.

Rétta leiðin til að bæta við frumum er að nota sérstaka Google Sheets aðgerð – SUM – sem skráir allar frumur sjálfkrafa með því að nota kommur:

=SUM(E2,E4,E8,E13)

Ef svæðið samanstendur af aðliggjandi frumum , einfaldlega tilgreinið fyrstu og síðustu hólf hennar, jafnvel þó að það séu auðar einhvers staðar á milli. Þannig muntu forðast að telja upp hvern einasta reit í Google Sheets SUM formúlunni.

Ábending. Önnur leið til að bæta SUM við er að velja dálkinn með tölum og velja SUM undir tákninu Formúlur :

Niðurstaðan mun vera settur inn í reit rétt fyrir neðan valið svið.

Ábending. Rafmagnsverkfæri okkar eru með AutoSum eiginleika. Einn smellur - og virka reiturinn þinn mun skila summu gilda úr öllum dálknum hér að ofan.

Leyfðu mér að flækja verkefnið. Ég vil bæta við tölum frá mismunandi gagnasviðum á mörgum blöðum, til dæmis A4:A8 frá Sheet1 og B4:B7 frá Sheet2 . Og ég vil draga þær samaneinn reit:

=SUM('Sheet1'!A4:A8,'Sheet2'!B4:B7)

Eins og þú sérð bætti ég bara einu blaði í viðbót inn í Google Sheets SUM formúlu og aðskildi tvö mismunandi svið með kommu.

Prósentuformúlur

Ég heyri oft fólk spyrja um að finna prósentu af mismunandi heildartölum. Þetta er venjulega reiknað með Google Sheets prósentuformúlunni svona:

Það sama virkar líka þegar þú þarft að athuga hvaða hluti þessi eða þessi tala táknar af heildarfjöldanum:

Ábending. Master prósenta af heildar, samtals & amp; upphæð með prósentum, aukning þess & amp; lækkun í þessari kennslu.

Í töflunni minni þar sem ég geymi skrár yfir alla sölu síðustu 10 daga get ég reiknað út hlutfall hverrar sölu af heildarsölu.

Fyrst fer ég til E12 og finn heildarsölu:

=SUM(E2:E11)

Þá athuga ég hvaða hluti salan á fyrsta degi er af heildarsölunni í F2:

=E2/$E$12

Ég mæli með því að gera nokkrar breytingar líka:

1. Snúðu E2 í algjöra tilvísun – $E$12 – til að tryggja að þú skiptir útsölu hvers dags með sömu heildartölu.
2. Settu prósentutölusniðinu á reiti í F dálki.
3. Afrita formúluna úr F2 yfir í allar reiti fyrir neðan – allt að F11.

Ábending. Til að afrita formúluna skaltu nota eina af þeim leiðum sem ég nefndi áðan.

Ábending. Til að ganga úr skugga um að útreikningar þínir séu réttir skaltu slá inn þann fyrir neðan í F12:

=SUM(F2:F11 )

Ef það skilar 100% –allt er rétt.

Hvers vegna mæli ég með því að nota prósentusniðið?

Jæja, annars vegar til að forðast að margfalda hverja niðurstöðu með 100 ef þú vilt fá prósentum. Hins vegar til að forðast að deila niðurstöðunum í 100 ef þú vilt nota þær fyrir frekari stærðfræðiaðgerðir sem ekki eru prósentustig.

Hér er það sem ég á við:

Ég nota prósentutölusniðið í hólfum C4, B10 og B15. Allar formúlur Google Sheets sem vísa til þessara hólfa eru miklu auðveldari. Ég þarf ekki að deila með 100 eða bæta prósentutákninu (%) við formúlur í C10 og C15.

Það sama er ekki hægt að segja um C8, C9 og C14. Ég verð að gera þessar aukaleiðréttingar til að fá rétta niðurstöðu.

Array formúlur

Til að vinna með fullt af gögnum í Google Sheets eru hreiður aðgerðir og aðrir flóknari útreikningar notaðir að jafnaði. Fylkisformúlur eru einnig til í Google Sheets í þeim tilgangi.

Til dæmis hef ég töflu yfir sölu á hvern viðskiptavin. Mér leikur forvitni á að finna hámarkssölu á mjólkursúkkulaði til Smith til að athuga hvort ég geti gefið honum aukaafslátt næst. Ég nota næstu fylkisformúlu í E18:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith")*($C$2:$C$13="Milk Chocolate"),$E$2:$E$13,"")))

Athugið. Til að klára hvaða fylkisformúlu sem er í Google Sheets, ýttu á Ctrl+Shift+Enter frekar en einfaldlega Enter.

Ég hef fengið $259 í kjölfarið.

Fyrsta fylkisformúlan mín í E16 skilar hámarkskaupum sem Smith gerði – $366:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith"),$E$2:$E$13)))

E17 sýna hámarkiðpeningum varið í mjólkursúkkulaði – $518:

=ArrayFormula(MAX(IF(($C$2:$C$13="Milk Chocolate"),$E$2:$E$13)))

Nú ætla ég að skipta út öllum gildum sem notuð eru í formúlum Google Sheets fyrir frumutilvísanir:

Hefurðu tekið eftir því hvað hefur breyst?

=ArrayFormula(MAX(IF(($B$2:$B$13=B18)*($C$2:$C$13=C18),$E$2:$E$13,"")))

Hér er það sem ég hafði áður:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith")*($C$2:$C$13="Milk Chocolate"),$E$2:$E$13,"")))

Svona, bara með gildum í hólfum sem þú vísar til geturðu fljótt fengið mismunandi niðurstöður miðað við mismunandi aðstæður án þess að breyta formúlunni sjálfri.

Google Sheets formúlur til daglegrar notkunar

Við skulum skoða nokkrar fleiri aðgerðir og formúludæmi gagnleg til daglegrar notkunar.

Dæmi 1

Segjum sem svo að gögnin þín séu að hluta skrifuð sem tölur og að hluta sem texti: 300 evrur , alls – 400 dollara . En þú þarft aðeins að draga út tölur.

Ég veit bara fall fyrir það:

Það dregur textann eftir grímu með reglulegri tjáningu.

• texti – það getur verið frumuvísun eða hvaða texti sem er í tvöföldum gæsalöppum.
• venjuleg_tjáning – textagríman þín. Einnig innan tveggja gæsalappa. Það gerir þér kleift að búa til nánast hvaða textakerfi sem er mögulegt.

Textinn í mínu tilfelli er hólf með gögnum ( A2 ). Og ég nota þessa reglulegu segð: [0-9]+

Það þýðir að ég er að leita að hvaða magni sem er ( + ) af tölum frá 0 til 9 ( [0-9] ) skrifað hver á eftir öðrum:

Ef tölur eru með brot mun regluleg segð líta svona út:

"[0-9]*\.[0-9]+[0-9]+" fyrirtölur með tveimur aukastöfum

"[0-9]*\.[0-9]+" fyrir tölur með einum aukastaf

Athugið. Google Sheets sér útdrætt gildi sem texta. Þú þarft að umbreyta þeim í tölur með VALUE fallinu eða með Convert tólinu okkar.

Dæmi 2 – sameina texta með formúlu

Formúlur innan textans hjálpa til við að fá fallega útlitslínu með sumum heildartölum – tölur með stuttum lýsingum þeirra.

Ég ætla að búa til slíkar línur í línum 14 og 15. Til að byrja með sameina ég reiti í þeim línum með Format > Sameina frumur og teldu svo summan fyrir dálk E:

=SUM(E2:E13)

Svo set ég textann sem ég vil hafa sem lýsingu við tvöfaldar gæsalappir og sameina hann með formúlunni nota ampermerki:

="Total chocolate sales: "&SUM(E2:E13)&" dollars"

Til að gera tölurnar mínar aukastafi nota ég TEXT fallið og stilli sniðið: "#,## 0"

Önnur leið er að nota Google Sheets CONCATENATE aðgerðina, eins og ég notaði í A15:

=CONCATENATE("Total discount for customers: ",TEXT(SUM(F2:F13),"#.##")," dollars")

Dæmi 3

Hvað ef þú hleður upp gögnunum einhvers staðar frá og allar tölur birtast með bilum, eins og 8 544 í stað 8544 ? Google Sheets mun skila þessu sem texta, þú veist.

Svona á að breyta þessum gildum sem eru skrifuð sem texta í "venjulegar tölur":

=VALUE(SUBSTITUTE("8 544"," ",""))

eða

=VALUE(SUBSTITUTE(A2," ",""))

þar sem A2 inniheldur 8 544 .

Hvernig virkar það? SUBSTITUTE aðgerðin kemur í stað allra bila í textanum (athugaðu aðra röksemd – það er bil í tvöföldum gæsalappa) fyrir „tómtstring" (þriðju rökin). Síðan breytir VALUE texta í tölur.

Dæmi 4

Það eru nokkrar Google Sheets aðgerðir sem hjálpa til við að vinna með texta í töflureiknunum þínum, til dæmis breyta hástöfum ef þú ert með eitthvað skrítið eins og upprunagögn geturðu fengið upprunagögn í staðinn:

Leyfðu mér að útskýra það í smáatriðum.Ég tek fyrsta stafinn í reit:

=LEFT(A1,1)

og skipti yfir í hástafi:

=UPPER(LEFT(A1,1))

Svo tek ég textinn sem eftir er:

=RIGHT(A1,LEN(A1)-1)

og þvinga hann í lágstafi:

=LOWER(RIGHT(A1,LEN(A1)-1))

Að lokum tek ég alla hluta formúlunnar saman með og-merki :

=UPPER(LEFT(A1,1))&LOWER(RIGHT(A1,LEN(A1)-1))

Ábending. Þú getur skipt á milli mála með einum smelli með tilheyrandi tóli úr rafmagnsverkfærunum okkar.

Auðvitað er miklu meira sem Google Sheets hefur upp á að bjóða. Ekki gera það ekki vera hræddur við mismunandi flóknar formúlur - reyndu bara og gerðu tilraunir. Eftir allt saman, þessi verkfærasett gera okkur kleift að leysa mörg mismunandi verkefni. Gangi þér vel! :)