Tutorial menunjukkan cara menggunakan IF bersama dengan fungsi AND di Excel untuk memeriksa beberapa kondisi dalam satu rumus.

Beberapa hal di dunia ini terbatas. Yang lainnya tidak terbatas, dan fungsi IF tampaknya menjadi salah satu dari hal-hal tersebut. Di blog kami, kami sudah memiliki beberapa tutorial IF Excel dan masih menemukan penggunaan baru setiap hari. Hari ini, kita akan melihat bagaimana Anda dapat menggunakan IF bersama dengan fungsi AND untuk mengevaluasi dua atau lebih kondisi pada saat yang bersamaan.

Pernyataan IF AND di Excel

Untuk membuat pernyataan IF AND, Anda jelas perlu menggabungkan fungsi IF dan AND dalam satu rumus. Begini caranya:

Diterjemahkan ke dalam bahasa Inggris sederhana, rumusnya berbunyi sebagai berikut: JIKA kondisi 1 benar DAN kondisi 2 benar, lakukan satu hal, jika tidak, lakukan sesuatu yang lain.

Sebagai contoh, mari kita buat rumus yang memeriksa apakah B2 adalah "delivered" dan C2 tidak kosong, dan tergantung pada hasilnya, lakukan salah satu hal berikut:

• Jika kedua kondisi tersebut TRUE, tandai pesanan sebagai "Closed".
• Jika salah satu kondisi adalah FALSE atau keduanya FALSE, maka kembalikan string kosong ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

Tangkapan layar di bawah ini menunjukkan fungsi IF AND di Excel:

Jika Anda ingin mengembalikan beberapa nilai jika tes logika dievaluasi menjadi FALSE, berikan nilai itu di dalam value_if_false argumen. Misalnya:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

Rumus yang dimodifikasi menghasilkan "Closed" jika kolom B adalah "delivered" dan C memiliki tanggal apa pun di dalamnya (tidak kosong). Dalam semua kasus lainnya, ia mengembalikan "Open":

Catatan. Saat menggunakan rumus IF AND di Excel untuk mengevaluasi kondisi teks, harap diingat bahwa huruf kecil dan huruf besar diperlakukan sebagai karakter yang sama. Jika Anda mencari rumus IF AND yang peka huruf besar-kecil, bungkus satu atau lebih argumen AND ke dalam fungsi EXACT seperti yang dilakukan dalam contoh tertaut.

Sekarang setelah Anda mengetahui sintaks pernyataan IF AND Excel, izinkan saya menunjukkan kepada Anda tugas apa yang bisa diselesaikannya.

Excel JIKA: lebih besar dari DAN kurang dari

Pada contoh sebelumnya, kita menguji dua kondisi dalam dua sel yang berbeda. Namun terkadang Anda mungkin perlu menjalankan dua atau lebih pengujian pada sel yang sama. Contoh tipikal adalah memeriksa apakah nilai sel adalah antara dua angka Fungsi IF AND Excel dapat dengan mudah melakukannya juga!

Katakanlah Anda memiliki beberapa nomor penjualan di kolom B dan Anda diminta untuk menandai jumlah yang lebih besar dari $ 50 tetapi kurang dari $ 100. Untuk menyelesaikannya, masukkan rumus ini di C2 dan kemudian salin ke bawah kolom:

=IF(AND(B2>50, B2<100), "x", "")

Jika Anda perlu menyertakan nilai batas (50 dan 100), gunakan kurang dari atau sama dengan operator (<=) dan lebih besar dari atau sama dengan (>=) operator:

=IF(AND(B2>=50, B2<=100), "x", "")

Untuk memproses beberapa nilai batas lainnya tanpa mengubah rumus, masukkan angka minimum dan maksimum dalam dua sel terpisah dan rujuk ke sel tersebut dalam rumus Anda. Agar rumus berfungsi dengan benar di semua baris, pastikan untuk menggunakan referensi absolut untuk sel batas ($ F $ 1 dan $ F $ 2 dalam kasus kami):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Dengan menggunakan rumus yang sama, Anda bisa mengecek apakah suatu tanggal jatuh dalam kisaran tertentu .

Misalnya, mari kita tandai tanggal antara 10-Sep-2018 dan 30-Sep-2018, inklusif. Rintangan kecil adalah bahwa tanggal tidak dapat diberikan ke tes logis secara langsung. Agar Excel memahami tanggal, mereka harus diapit oleh fungsi DATEVALUE, seperti ini:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Atau, cukup masukkan Dari dan Untuk tanggal dalam dua sel ($ F $ 1 dan $ F $ 2 dalam contoh ini) dan "menarik" mereka dari sel tersebut dengan menggunakan rumus IF AND yang sudah dikenal:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Untuk informasi lebih lanjut, silakan lihat pernyataan IF Excel antara dua angka atau tanggal.

JIKA ini DAN itu, maka hitunglah sesuatu

Selain mengembalikan nilai yang telah ditentukan sebelumnya, fungsi Excel IF AND juga dapat melakukan perhitungan yang berbeda tergantung pada apakah kondisi yang ditentukan adalah TRUE atau FALSE.

Untuk mendemonstrasikan pendekatan ini, kami akan menghitung bonus 5% untuk penjualan "Closed" dengan jumlah lebih besar atau sama dengan $100.

Dengan mengasumsikan jumlah di kolom B dan status pesanan di kolom C, rumusnya adalah sebagai berikut:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

Rumus di atas menetapkan nol untuk sisa order ( value_if_false = Jika Anda bersedia memberikan bonus stimulasi kecil, katakanlah 3%, untuk pesanan yang tidak memenuhi kondisi, sertakan persamaan yang sesuai dalam persamaan value_if_false argumen:

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

Beberapa pernyataan IF AND di Excel

Seperti yang mungkin sudah kamu perhatikan, kita hanya mengevaluasi dua kriteria dalam semua contoh di atas. Namun, tidak ada yang bisa mencegahmu untuk menyertakan tiga atau lebih tes dalam rumus IF ANDmu selama mereka mematuhi batasan umum Excel ini:

• Di Excel 2007 dan yang lebih tinggi, hingga 255 argumen dapat digunakan dalam rumus, dengan total panjang rumus tidak melebihi 8.192 karakter.
• Di Excel 2003 dan yang lebih rendah, tidak lebih dari 30 argumen yang diperbolehkan, dengan panjang total tidak melebihi 1.024 karakter.

Sebagai contoh kondisi multiple AND, harap pertimbangkan yang ini:

• Jumlah (B2) harus lebih besar dari atau sama dengan $100
• Status pesanan (C2) adalah "Ditutup"
• Tanggal pengiriman (D2) adalah dalam bulan berjalan

Sekarang, kita memerlukan pernyataan IF AND untuk mengidentifikasi order yang ketiga kondisinya BENAR. Dan inilah dia:

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

Mengingat bahwa 'bulan saat ini' pada saat penulisan adalah bulan Oktober, rumus ini memberikan hasil di bawah ini:

Pernyataan IF AND bersarang

Ketika bekerja dengan lembar kerja yang besar, kemungkinan besar Anda mungkin diminta untuk memeriksa beberapa set kriteria AND yang berbeda pada satu waktu. Untuk ini, Anda mengambil rumus IF bersarang Excel klasik dan memperluas tes logisnya dengan pernyataan AND, seperti ini:

Untuk mendapatkan gambaran umum, silakan lihat contoh berikut ini.

Misalkan Anda ingin menilai layanan Anda berdasarkan biaya pengiriman dan perkiraan waktu pengiriman (ETD):

• Sangat baik : biaya pengiriman di bawah $20 dan ETD di bawah 3 hari
• Buruk : biaya pengiriman lebih dari $30 dan ETD lebih dari 5 hari
• Rata-rata : apa pun di antara keduanya

Untuk menyelesaikannya, Anda menulis dua pernyataan IF AND individual:

IF(AND(B2<20, C2<3), "Excellent", ...)

IF(AND(B2>30, C2>5), "Poor", ...)

...dan menyarangkan satu ke yang lain:

=IF(AND(B2>30, C2>5), "Buruk", IF(AND(B2<20, C2<3), "Sangat Baik", "Rata-rata"))

Hasilnya akan terlihat mirip dengan ini:

Lebih banyak contoh rumus dapat ditemukan di pernyataan IF AND bersarang Excel.

Fungsi IF AND yang peka huruf besar-kecil di Excel

Seperti yang disebutkan di awal tutorial ini, rumus IF AND Excel tidak membedakan antara karakter huruf besar dan huruf kecil karena fungsi AND bersifat case-insensitive.

Jika Anda bekerja dengan peka huruf besar-kecil dan ingin mengevaluasi kondisi AND dengan mempertimbangkan kasus teks, lakukan setiap uji logika individual di dalam fungsi EXACT dan sarangkan fungsi-fungsi tersebut ke dalam pernyataan AND Anda:

Untuk contoh ini, kita akan menandai pesanan dari pelanggan tertentu (misalnya, perusahaan bernama Dunia Maya ) dengan jumlah yang melebihi angka tertentu, katakanlah $100.

Seperti yang bisa Anda lihat pada tangkapan layar di bawah ini, beberapa nama perusahaan di kolom B terlihat sama dengan kutipan karakter, namun demikian, mereka adalah perusahaan yang berbeda, jadi kita harus memeriksa nama-namanya persis Jumlah-jumlah dalam kolom C adalah angka-angka, dan kita menjalankan uji "lebih besar daripada" biasa untuk mereka:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Untuk membuat rumusnya lebih fleksibel, kamu bisa memasukkan nama pelanggan target dan jumlahnya dalam dua cell terpisah dan mereferensikan cell-cell tersebut. Ingatlah untuk mengunci referensi cellnya dengan tanda $ ($G$1 dan $G$2 dalam kasus kita ini) agar tidak berubah ketika kamu menyalin rumusnya ke baris lain:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Sekarang, Anda bisa mengetikkan nama dan jumlah apa pun dalam cell yang direferensikan, dan formula akan menandai order yang sesuai dalam tabel Anda:

Rumus IF ATAU AND di Excel

Di rumus IF Excel, Anda tidak terbatas hanya menggunakan satu fungsi logika. Untuk memeriksa berbagai kombinasi dari beberapa kondisi, Anda bebas menggabungkan fungsi IF, AND, OR, dan fungsi lainnya untuk menjalankan tes logis yang diperlukan. Berikut adalah contoh rumus IF AND OR yang menguji beberapa kondisi OR dalam AND. Dan sekarang, saya akan menunjukkan kepada Anda bagaimana Anda dapat melakukan dua atau lebih tes AND dalam ORfungsi.

Misalkan, Anda ingin menandai pesanan dua pelanggan dengan jumlah yang lebih besar dari angka tertentu, katakanlah $100.

Dalam bahasa Excel, kondisi kita dinyatakan dengan cara ini:

ATAU (DAN( Pelanggan1 , Jumlah >100), DAN( Pelanggan2 , Jumlah >100)

Dengan asumsi nama pelanggan ada di kolom B, jumlah di kolom C, 2 nama target ada di G1 dan G2, dan jumlah target ada di G3, Anda menggunakan rumus ini untuk menandai pesanan yang sesuai dengan "x":

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Hasil yang sama bisa dicapai dengan sintaksis yang lebih ringkas:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

Tidak yakin kamu benar-benar memahami logika rumusnya? Informasi lebih lanjut dapat ditemukan di Excel IF dengan beberapa kondisi AND/OR.

Begitulah cara Anda menggunakan fungsi IF dan AND bersama-sama di Excel. Terima kasih telah membaca dan sampai jumpa minggu depan!

Buku kerja praktik

IF AND Excel - contoh rumus (file .xlsx)