Þó að Microsoft Excel býður upp á fjölda aðgerða til að vinna með virka daga, mánuði og ár, er aðeins ein tiltæk í margar vikur - WEEKNUM aðgerðin. Þannig að ef þú ert að leita að leið til að fá vikunúmer frá dagsetningu, þá er WEEKNUM aðgerðin sem þú vilt.

Í þessu stutta kennsluefni munum við tala stuttlega um setningafræði og röksemdir Excel WEEKNUM, og Ræddu síðan nokkur formúludæmi sem sýna hvernig þú getur notað WEEKNUM aðgerðina til að reikna út vikutölur í Excel vinnublöðunum þínum.

Excel WEEKNUM aðgerðin - setningafræði

WEEKNUM aðgerðin er notað í Excel til að skila vikunúmeri ákveðinnar dagsetningar á árinu (tala á milli 1 og 54). Það hefur tvö rök, fyrsta er krafist og annað er valfrjálst:

• Raðnúmer - hvaða dagsetning innan vikunnar sem þú ert að reyna að nota að finna. Þetta getur verið tilvísun í reit sem inniheldur dagsetninguna, dagsetningu sem er slegin inn með því að nota DATE fallið eða skilað með einhverri annarri formúlu.
• Return_type (valfrjálst) - tala sem ákvarðar hvaða dag sem vikan hefst. Ef því er sleppt er sjálfgefin gerð 1 notuð (vikan sem hefst á sunnudag).

Hér er heildarlisti yfir return_type gildin sem studd eru í WEEKNUM formúlum.

Í WEEKNUM fallinu eru tvö mismunandi vikunúmerakerfi notuð:

• Kerfi 1. Vikan sem inniheldur 1. janúar er talin 1. vika ársins og er númeruð vika 1. Í þessu kerfi byrjar vikan að venju á sunnudegi.
• Kerfi 2. Þetta er ISO vikudagsetningarkerfið sem er hluti af ISO 8601 dagsetningar- og tímastaðall. Í þessu kerfi byrjar vikan á mánudegi og vikan sem inniheldur fyrsta fimmtudag ársins telst til vika 1. Það er almennt þekkt sem evrópska vikunúmerakerfið og það er aðallega notað í stjórnvöldum og viðskiptum fyrir reikningsár og tímatöku.

Allar skilategundirnar sem taldar eru upp hér að ofan eiga við um kerfi 1, nema skilategund 21 sem er notuð í kerfi 2.

Athugið. Í Excel 2007 og eldri útgáfum eru aðeins valkostir 1 og 2 í boði. Skilagerðir 11 til 21 eru aðeins studdar í Excel 2010 og Excel 2013.

Excel WEEKNUM formúlur til að umbreyta dagsetningu í vikunúmer (frá 1 í 54)

Eftirfarandi skjáskot sýnir hvernig þú getur fengið vikunúmer úr dagsetningum með einföldustu =WEEKNUM(A2) formúlunni:

Í ofangreinduformúlunni, return_type röksemdinni er sleppt, sem þýðir að sjálfgefna tegund 1 er notuð - vikan sem hefst á sunnudegi.

Ef þú vilt frekar byrja á einhverjum öðrum degi vikunnar, segðu mánudag, notaðu þá 2 í seinni röksemdinni:

=WEEKNUM(A2, 2)

Í stað þess að vísa í reit geturðu tilgreint dagsetninguna beint í formúlunni með því að nota DATE(ár, mánuður, dagur), til dæmis:

=WEEKNUM(DATE(2015,4,15), 2)

Ofangreind formúla skilar 16, sem er númer vikunnar sem inniheldur 15. apríl 2015, með viku sem hefst á mánudegi.

Í raunveruleikasviðum , Excel WEEKNUM aðgerðin er sjaldan notuð ein og sér. Oftast myndirðu nota það ásamt öðrum aðgerðum til að framkvæma ýmsa útreikninga byggða á vikunúmerinu, eins og sýnt er í frekari dæmum.

Hvernig á að breyta vikunúmeri í dagsetningu í Excel

Eins og þú hef bara séð, það er ekkert mál að breyta dagsetningu í vikunúmer með því að nota Excel WEEKNUM aðgerðina. En hvað ef þú ert að leita að hinu gagnstæða, þ.e.a.s. breyta vikunúmeri í dagsetningu? Því miður, það er engin Excel aðgerð sem gæti gert þetta strax. Þannig að við verðum að búa til okkar eigin formúlur.

Svo sem að þú sért með ár í reit A2 og vikunúmer í B2 og nú viltu reikna út upphafs- og lokadagsetningar í þessari viku.

Athugið. Þetta formúludæmi er byggt á ISO-vikunúmerum, þar sem vika hefst á mánudegi.

Formúlan til að skila Startdagsetning vikunnar er sem hér segir:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

Þar sem A2 er árið og B2 er vikunúmerið.

Athugið að formúlan skilar dagsetningunni sem raðnúmer og til að það sé birt sem dagsetning þarftu að forsníða hólfið í samræmi við það. Þú getur fundið nákvæmar leiðbeiningar í Breyta dagsetningarsniði í Excel. Og hér er niðurstaðan sem formúlan skilar:

Auðvitað er formúlan til að breyta vikunúmeri í dagsetningu ekki léttvæg og það getur tekið smá tíma að ná höfuðið í kringum rökfræðina. Engu að síður mun ég gera mitt besta til að koma með málefnalegar skýringar fyrir þá sem eru forvitnir um að komast niður á botninn.

Eins og þú sérð samanstendur formúlan okkar af 2 hlutum:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - reiknar út dagsetningu síðasta mánudags árið áður.
• B2 * 7 - bætir við fjölda vikna margfaldað með 7 (fjölda daga vikunnar) til að fá mánudaginn (upphafsdagur) vikunnar í spurning.

Í ISO vikunúmerakerfinu er vika 1 sú vika sem inniheldur fyrsta fimmtudag ársins. Þar af leiðandi er fyrsti mánudagurinn alltaf á milli 29. desember og 4. janúar. Þannig að til að finna þá dagsetningu verðum við að finna mánudaginn rétt fyrir 5. janúar.

Í Microsoft Excel er hægt að draga út vikudag frá kl. dagsetningu með því að nota WEEKDAY aðgerðina. Og þú getur notað eftirfarandi almennu formúlu til að fá mánudaginn strax fyrir hvaða dagsetningu sem er:

Ef okkarlokamarkmiðið var að finna mánudaginn strax fyrir 5. janúar ársins í A2, við gætum notað eftirfarandi DATE föll:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

En það sem við þurfum í raun og veru er ekki fyrsti mánudagurinn í á þessu ári, heldur síðasta mánudag fyrra árs. Svo þú þarft að draga 7 daga frá 5. janúar og þar af leiðandi færðu -2 í fyrstu DATE fallinu:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

Í samanburði við erfiðu formúluna sem þú varst nýbúinn að læra, reiknarðu Lokadagsetning vikunnar er algjör snilld :) Til að fá sunnudag vikunnar sem um ræðir bætir þú einfaldlega 6 dögum við Startdaginn , þ.e.a.s. =D2+6

Að öðrum kosti gætirðu bætt við 6 beint í formúluna:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

Til að tryggja að formúlurnar skili alltaf réttar dagsetningum skaltu skoða eftirfarandi skjáskot. Formúlurnar fyrir upphafsdagsetningu og lokadagsetningu sem fjallað er um hér að ofan eru afritaðar yfir dálk D og E, í sömu röð:

Aðrar leiðir til að umbreyta vikunúmeri í dagsetningu í Excel

Ef ofangreind formúla sem byggir á ISO vikudagsetningarkerfinu uppfyllir ekki kröfur þínar skaltu prófa eina af eftirfarandi lausnum.

Formúla 1. Vika sem inniheldur Jan-1 er vika 1, mán-sun vika

Eins og þú manst þá virkar fyrri formúlan út frá ISO dagsetningarkerfinu þar sem fyrsti fimmtudagur ársins telst til vika 1. Ef unnið er út frá dagsetningarkerfi þar sem vikan sem inniheldur 1. janúar telst til vika 1, nota eftirfarandiformúlur:

Upphafsdagur:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

Lokadagur:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

Formúla 2. Vika sem inniheldur Jan-1 er vika 1, Sun-Laur vika

Þessar formúlur eru svipaðar ofangreindum með þeim eina mun að þær eru skrifaðar fyrir sunnudaga - laugardaga viku.

Upphafsdagur:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

Lokadagur:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

Formúla 3. Byrjaðu alltaf að telja 1. janúar, mán-sunnviku

Á meðan fyrri formúlur skila mánudegi (eða sunnudag) viku 1, óháð hvort sem falla innan þessa árs eða fyrra árs, þá skilar þessi upphafsdagsetningarformúla alltaf 1. janúar sem upphafsdagsetningu viku 1, óháð vikudegi. Með hliðstæðum hætti skilar lokadagsetningarformúlan alltaf 31.desember sem lokadagsetningu síðustu viku ársins, óháð vikudegi. Að öllu öðru leyti virka þessar formúlur svipað og Formúla 1 hér að ofan.

Upphafsdagur:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

Lokadagur:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

Formúla 4. Byrjaðu alltaf að telja 1. janúar, sunnudags-laugarviku

Til að reikna út upphafs- og lokadagsetningar fyrir sunnudaga - laugardaga viku þarf ekki annað en eina smá aðlögun í formúlunum hér að ofan :)

Upphafsdagur:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

Lokadagsetning:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

Hvernig á að fá mánuð úr vikunúmeri

Til að fá mánuð sem samsvarar vikunni númer, þú finnur fyrsta daginn í tiltekinni viku eins og útskýrt er í þessudæmi, og settu síðan formúluna inn í Excel MONTH fallið svona:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

Athugið. Vinsamlega mundu að ofangreind formúla virkar út frá ISO vikudagsetningarkerfinu , þar sem vikan byrjar á mánudegi og vikan sem inniheldur 1. fimmtudag ársins telst til vika 1. Til dæmis, árið 2016, fyrsti fimmtudagurinn er 7. janúar og þess vegna hefst vika 1 4. jan-2016.

Hvernig á að fá vikunúmer í mánuði (frá 1 til 6)

Ef viðskiptarökfræði þín krefst þess að umbreyta tiltekinni dagsetningu í vikunúmer innan samsvarandi mánaðar geturðu notað samsetninguna af WEEKNUM, DATE og MONTH föll:

Að því gefnu að reit A2 innihaldi upphaflega dagsetningu, notaðu eftirfarandi formúlu fyrir viku sem hefst á mánudagur (tilkynning 21 í WEEKNUM's return_type argument):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

Fyrir viku sem hefst á sunnudag skaltu sleppa return_type röksemdinni:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

Hvernig á að summa gildi og finna meðaltal eftir vikunúmeri

Nú þegar þú veist hvernig á að breyta dagsetningu í vikunúmer í Excel, skulum við sjá hvernig þú getur notað vikutölur í öðrum útreikningum.

Segjum sem svo. , þú ert með nokkrar mánaðarlegar sölutölur og þú vilt vita heildarfjöldann fyrir hverja viku.

Til að byrja með skulum við finna út vikunúmer sem samsvarar hverri sölu. Ef dagsetningar þínar eru í dálki A og sala í dálki B, afritaðu =WEEKNUM(A2) formúluna yfir dálk C sem byrjar í reitC2.

Og gerðu síðan lista yfir vikunúmer í einhverjum öðrum dálki (t.d. í dálki E) og reiknaðu út söluna fyrir hverja viku með því að nota eftirfarandi SUMIF formúlu:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

Þar sem E2 er vikunúmerið.

Í þessu dæmi erum við að vinna með lista yfir marssölur, þannig að við höfum vikunúmer 10 til 14, sem sýnt í eftirfarandi skjáskoti:

Á svipaðan hátt geturðu reiknað út sölumeðaltal fyrir tiltekna viku:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

Ef hjálpardálkurinn með WEEKNUM formúlunni passar ekki vel inn í gagnaskipulagið þitt, þá þykir mér miður að segja þér að það er engin einföld leið til að losna við hann því Excel WEEKNUM er ein af þessum aðgerðum sem samþykkir ekki sviðsrök. Þess vegna er ekki hægt að nota það innan SUMPRODUCT eða nokkurrar annarrar fylkisformúlu eins og MONTH fallið í svipaðri atburðarás.

Hvernig á að auðkenna frumur út frá vikunúmerinu

Segjum að þú hafir langan lista dagsetningar í einhverjum dálki og þú vilt aðeins draga fram þær sem tengjast tiltekinni viku. Allt sem þú þarft er skilyrt sniðsreglu með WEEKNUM formúlu svipaða þessari:

=WEEKNUM($A2)=10

Eins og sýnt er á skjáskotinu hér að neðan, undirstrikar reglan sölu sem fór fram innan viku 10, sem er fyrstu vikuna í mars 2015. Þar sem reglan á við um A2:B15, undirstrikar hún gildi í báðum dálkum. Þú getur lært meira um að búa til skilyrtar sniðreglur í þessukennsla: Skilyrt snið í Excel byggt á öðru hólfsgildi.

Svona er hægt að reikna vikutölur í Excel, umbreyta vikunúmeri í dagsetningu og draga út vikunúmer úr dagsetningu. Vonandi munu WEEKNUM formúlurnar sem þú hefur lært í dag reynast gagnlegar í vinnublöðunum þínum. Í næsta kennsluefni munum við tala um að reikna út aldur og ár í Excel. Ég þakka þér fyrir lesturinn og sjáumst vonandi í næstu viku!