I handledningen visas hur du använder IF tillsammans med AND-funktionen i Excel för att kontrollera flera villkor i en formel.

Vissa saker i världen är ändliga, andra är oändliga, och IF-funktionen verkar vara en sådan sak. På vår blogg har vi redan en handfull Excel IF-tutorials och upptäcker fortfarande nya användningsområden varje dag. Idag ska vi titta på hur du kan använda IF tillsammans med AND-funktionen för att utvärdera två eller flera villkor samtidigt.

IF AND-uttalande i Excel

För att bygga upp IF AND-satsen måste du naturligtvis kombinera IF- och AND-funktionerna i en formel. Så här gör du:

Översatt till vanlig engelska lyder formeln så här: OM villkor 1 är sant OCH villkor 2 är sant, gör en sak, annars gör något annat.

Låt oss till exempel skapa en formel som kontrollerar om B2 är "levererad" och C2 inte är tom, och som beroende på resultatet gör något av följande:

• Om båda villkoren är VARA, markerar du beställningen som "Stängd".
• Om något av villkoren är FALSK eller om båda är FALSK återges en tom sträng ("").

=IF(AND(B2="levererad", C2""), "Stängt", "")

Skärmbilden nedan visar IF AND-funktionen i Excel:

Om du vill returnera ett värde om det logiska testet utvärderas till FALSE, anger du det värdet i value_if_false argument. Till exempel:

=IF(AND(B2="levererad", C2""), "Stängt", "Öppet")

Den modifierade formeln ger resultatet "Stängt" om kolumn B är "levererad" och C har ett datum (som inte är tomt), i alla andra fall ger den resultatet "Öppet":

När du använder en IF AND-formel i Excel för att utvärdera textvillkor ska du komma ihåg att små och stora bokstäver behandlas som samma tecken. Om du vill ha en IF AND-formel som tar hänsyn till stor och liten bokstav kan du linda in ett eller flera AND-argument i EXAKT-funktionen, som i det länkade exemplet.

Nu när du känner till syntaxen för Excel IF AND-satsen kan jag visa dig vilken typ av uppgifter den kan lösa.

Excel IF: större än AND mindre än

I det föregående exemplet testade vi två villkor i två olika celler. Men ibland kan du behöva köra två eller flera tester på samma cell. Ett typiskt exempel är att kontrollera om ett cellvärde är mellan två tal Excel IF AND-funktionen kan enkelt göra det också!

Låt oss säga att du har några försäljningssiffror i kolumn B och att du vill markera de belopp som är större än 50 dollar men mindre än 100 dollar. För att göra det, sätt in denna formel i C2 och kopiera den sedan ner i kolumnen:

=IF(AND(B2>50, B2<100), "x", "")

Om du behöver inkludera gränsvärden. (50 och 100), använder du är mindre än eller lika med operatör (<=) och är större än eller lika med (>=):

=IF(AND(B2>=50, B2<=100), "x", "")

Om du vill bearbeta några andra gränsvärden utan att ändra formeln anger du minimi- och maximaltal i två separata celler och hänvisar till dessa celler i formeln. För att formeln ska fungera korrekt i alla rader måste du använda absoluta referenser för gränscellerna ($F$1 och $F$2 i vårt fall):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Genom att använda en liknande formel kan du kontrollera om en datum faller inom ett specificerat intervall .

Låt oss till exempel flagga datum mellan 10-sep-2018 och 30-sep-2018, inklusive. Ett litet hinder är att datum inte kan anges direkt i de logiska testerna. För att Excel ska förstå datumen ska de omslutas av funktionen DATEVALUE, så här:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Du kan också helt enkelt skriva in Från och Till datum i två celler ($F$1 och $F$2 i det här exemplet) och "hämta" dem från dessa celler med hjälp av den redan välkända IF AND-formeln:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Mer information finns i Excel IF-meddelande mellan två siffror eller datum.

OM detta OCH detta, beräkna något.

Excel-funktionen IF AND kan förutom att återge fördefinierade värden även utföra olika beräkningar beroende på om de angivna villkoren är SANNA eller FALSKA.

För att demonstrera tillvägagångssättet kommer vi att beräkna en bonus på 5 % för "slutna" försäljningar med ett belopp på minst 100 dollar.

Om du antar att beloppet finns i kolumn B och orderstatus i kolumn C, så fungerar formeln på följande sätt:

=IF(AND(B2>=100, C2="stängd"), B2*10%, 0)

I formeln ovan tilldelas resten av orderna noll ( value_if_false = 0). Om du är villig att ge en liten stimulansbonus, till exempel 3 %, till order som inte uppfyller villkoren, inkludera motsvarande ekvation i value_if_false argument:

=IF(AND(B2>=100, C2="stängd"), B2*10%, B2*3%)

Flera IF AND-satser i Excel

Som du kanske har märkt har vi bara utvärderat två kriterier i alla ovanstående exempel. Men det finns inget som hindrar dig från att inkludera tre eller fler tester i dina IF AND-formler så länge de följer dessa allmänna begränsningar i Excel:

• I Excel 2007 och senare kan upp till 255 argument användas i en formel, med en total formellängd på högst 8 192 tecken.
• I Excel 2003 och lägre är högst 30 argument tillåtna, med en total längd på högst 1024 tecken.

Som exempel på flera AND-villkor kan nämnas dessa:

• Beloppet (B2) ska vara större än eller lika med 100 dollar.
• Orderstatus (C2) är "Stängd".
• Leveransdatum (D2) är inom den aktuella månaden.

Nu behöver vi ett IF AND-uttalande för att identifiera de order för vilka alla tre villkoren är SANNA, och här är det:

=IF(AND(B2>=100, C2="Stängt", MONTH(D2)=MONTH(TODAY()))), "x", "")

Eftersom den "aktuella månaden" i skrivande stund var oktober, ger formeln följande resultat:

Inbäddade IF AND-satser

När du arbetar med stora kalkylblad är det troligt att du måste kontrollera några uppsättningar av olika AND-kriterier samtidigt. För detta tar du en klassisk Excel-formel med inbäddad IF och utökar dess logiska tester med AND-utsagor, som här:

För att få en allmän uppfattning kan du titta på följande exempel.

Antag att du vill betygsätta din tjänst baserat på fraktkostnad och beräknad leveranstid (ETD):

• Utmärkt : fraktkostnad under 20 dollar och ETD under 3 dagar.
• Dålig : fraktkostnad över 30 dollar och ETD över 5 dagar.
• Genomsnittlig : allt däremellan

För att få det gjort skriver du två enskilda IF AND-satser:

IF(AND(B2<20, C2<3), "Utmärkt", ...)

IF(AND(B2>30, C2>5), "Fattig", ...)

...och bädda in den ena i den andra:

=IF(AND(B2>30, C2>5), "Dålig", IF(AND(B2<20, C2<3), "Utmärkt", "Medel"))

Resultatet kommer att se ut ungefär så här:

Fler exempel på formler hittar du i Excel-nested IF AND-satser.

Funktion IF AND som tar hänsyn till stora bokstäver i Excel

Som vi nämnde i början av den här handledningen skiljer Excel-formlerna IF AND inte mellan stora och små bokstäver eftersom AND-funktionen av naturliga skäl inte är skiftlägeskänslig.

Om du arbetar med Skiftlägeskänslig data och vill utvärdera AND-villkor med hänsyn till textfallet, gör varje enskilt logiskt test i EXACT-funktionen och inbäddar dessa funktioner i AND-angivelsen:

I det här exemplet ska vi flagga beställningar från en specifik kund (t.ex. företaget som heter Cyberrymden ) med ett belopp som överstiger ett visst antal, till exempel 100 dollar.

Som du kan se i skärmdumpen nedan ser vissa företagsnamn i kolumn B likadana ut i teckenbokstäverna, men de är ändå olika företag, så vi måste kontrollera namnen. exakt Beloppen i kolumn C är siffror, och vi kör ett vanligt "större än"-test för dem:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

För att göra formeln mer flexibel kan du ange målkundens namn och belopp i två separata celler och hänvisa till dessa celler. Kom ihåg att låsa cellreferenserna med $-tecknet ($G$1 och $G$2 i vårt fall) så att de inte ändras när du kopierar formeln till andra rader:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Nu kan du skriva vilket namn och belopp som helst i de refererade cellerna, och formeln kommer att markera motsvarande order i tabellen:

Formel IF OR AND i Excel

I Excel IF-formler är du inte begränsad till att bara använda en logisk funktion. För att kontrollera olika kombinationer av flera villkor kan du kombinera IF, AND, OR och andra funktioner för att köra de logiska tester som krävs. Här är ett exempel på IF AND OR-formel som testar ett par OR-villkor inom AND. Och nu ska jag visa dig hur du kan göra två eller flera AND-tester inom OR.funktion.

Anta att du vill markera två kunders beställningar med ett belopp som är större än ett visst antal, till exempel 100 dollar.

På Excel-språket uttrycks våra villkor på följande sätt:

OR(AND( Kund1 , Belopp >100), AND( Kund2 , Belopp >100)

Om du antar att kundnamnen finns i kolumn B, beloppen i kolumn C, de två målnamnen finns i G1 och G2 och målbeloppet i G3, använder du den här formeln för att markera motsvarande order med "x":

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Samma resultat kan uppnås med en mer kompakt syntax:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

Om du inte är säker på att du har förstått formelns logik finns mer information i Excel IF med flera AND/OR-villkor.

Det är så du använder funktionerna IF och AND tillsammans i Excel. Tack för att du läste och vi ses nästa vecka!

Arbetsbok för praktiska övningar

IF AND Excel - exempel på formler (.xlsx-fil)