ບົດສອນສະແດງວິທີການໃຊ້ IF ຮ່ວມກັບຟັງຊັນ AND ໃນ Excel ເພື່ອກວດສອບເງື່ອນໄຂຫຼາຍອັນໃນສູດດຽວ.

ບາງອັນໃນໂລກແມ່ນຈຳກັດ. ອື່ນໆແມ່ນບໍ່ມີຂອບເຂດ, ແລະຫນ້າທີ່ IF ເບິ່ງຄືວ່າເປັນຫນຶ່ງໃນສິ່ງດັ່ງກ່າວ. ໃນ blog ຂອງພວກເຮົາ, ພວກເຮົາມີຄູ່ມືຂອງ Excel IF tutorials ແລ້ວແລະຍັງຄົ້ນພົບການນໍາໃຊ້ໃຫມ່ທຸກໆມື້. ມື້ນີ້, ພວກເຮົາຈະມາເບິ່ງວິທີທີ່ທ່ານສາມາດນໍາໃຊ້ IF ຮ່ວມກັນກັບຟັງຊັນ AND ເພື່ອປະເມີນເງື່ອນໄຂສອງຫຼືຫຼາຍໃນເວລາດຽວກັນ.

IF AND ໃນ Excel

ເພື່ອສ້າງຄໍາຖະແຫຼງການ IF AND, ແນ່ນອນທ່ານຈໍາເປັນຕ້ອງລວມຟັງຊັນ IF ແລະ AND ໃນສູດດຽວ. ນີ້ແມ່ນວິທີ:

ແປເປັນພາສາອັງກິດທຳມະດາ, ສູດຄຳນວນອ່ານດັ່ງນີ້: ເງື່ອນໄຂ IF 1. ແມ່ນຄວາມຈິງ AND ເງື່ອນໄຂ 2 ແມ່ນຈິງ, ເຮັດສິ່ງຫນຶ່ງ, ຖ້າບໍ່ດັ່ງນັ້ນເຮັດອັນອື່ນ.

ເປັນຕົວຢ່າງ, ໃຫ້ເຮົາສ້າງສູດທີ່ກວດເບິ່ງວ່າ B2 ແມ່ນ "ສົ່ງ" ແລະ C2 ບໍ່ຫວ່າງ, ແລະຂຶ້ນກັບຜົນໄດ້ຮັບ. , ເຮັດອັນໃດອັນໜຶ່ງຕໍ່ໄປນີ້:

• ຖ້າເງື່ອນໄຂທັງສອງແມ່ນຖືກຕ້ອງ, ໃຫ້ໝາຍຄຳສັ່ງຊື້ເປັນ "ປິດແລ້ວ".
• ຖ້າເງື່ອນໄຂໃດນຶ່ງແມ່ນ FALSE ຫຼືທັງສອງແມ່ນ FALSE, ໃຫ້ສົ່ງຄືນຄ່າຫວ່າງເປົ່າ. string ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

ຮູບໜ້າຈໍຂ້າງລຸ່ມນີ້ສະແດງຟັງຊັນ IF AND ໃນ Excel:

ຖ້າທ່ານ ຕ້ອງການສົ່ງຄືນຄ່າບາງຢ່າງໃນກໍລະນີທີ່ການທົດສອບຕາມເຫດຜົນປະເມີນເປັນ FALSE, ສະໜອງຄ່ານັ້ນໃນ value_if_false ການໂຕ້ຖຽງ. ຕົວຢ່າງ:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

ສູດທີ່ແກ້ໄຂໃຫ້ຜົນໄດ້ຮັບ "ປິດ" ຖ້າຖັນ B ແມ່ນ "ສົ່ງ" ແລະ C ມີວັນທີໃດໆໃນມັນ (ບໍ່ແມ່ນຫວ່າງ). ໃນກໍລະນີອື່ນໆທັງໝົດ, ມັນຈະສົ່ງຄືນ "Open":

ໝາຍເຫດ. ເມື່ອນໍາໃຊ້ສູດ IF AND ໃນ Excel ເພື່ອປະເມີນເງື່ອນໄຂຂອງຂໍ້ຄວາມ, ກະລຸນາຈື່ໄວ້ວ່າຕົວພິມນ້ອຍແລະຕົວພິມໃຫຍ່ຖືກປະຕິບັດເປັນຕົວອັກສອນດຽວກັນ. ຖ້າທ່ານກໍາລັງຊອກຫາສູດ IF AND ທີ່ອ່ອນໄຫວກັບກໍລະນີ, ຫໍ່ຫນຶ່ງຫຼືຫຼາຍ arguments ຂອງ AND ເຂົ້າໄປໃນຫນ້າທີ່ EXACT ຍ້ອນວ່າມັນຖືກເຮັດໃນຕົວຢ່າງທີ່ເຊື່ອມໂຍງ.

ຕອນນີ້ເຈົ້າຮູ້ syntax ຂອງ Excel IF AND, ໃຫ້ຂ້ອຍສະແດງໃຫ້ເຈົ້າຮູ້ວ່າວຽກປະເພດໃດແດ່ທີ່ມັນສາມາດແກ້ໄຂໄດ້.

Excel IF: ໃຫຍ່ກວ່າ AND ໜ້ອຍກວ່າ

ໃນ ຕົວຢ່າງກ່ອນຫນ້ານີ້, ພວກເຮົາໄດ້ທົດສອບສອງເງື່ອນໄຂໃນສອງຈຸລັງທີ່ແຕກຕ່າງກັນ. ແຕ່ບາງຄັ້ງທ່ານອາດຈະຕ້ອງດໍາເນີນການທົດສອບສອງຫຼືຫຼາຍກວ່ານັ້ນຢູ່ໃນຫ້ອງດຽວກັນ. ຕົວຢ່າງປົກກະຕິແມ່ນການກວດສອບວ່າຄ່າຕາລາງແມ່ນ ລະຫວ່າງສອງຕົວເລກ . ຟັງຊັນ Excel IF AND ສາມາດເຮັດໄດ້ງ່າຍຄືກັນ!

ສົມມຸດວ່າເຈົ້າມີຕົວເລກການຂາຍບາງອັນຢູ່ໃນຖັນ B ແລະເຈົ້າຖືກຮ້ອງຂໍໃຫ້ໝາຍຕົວເລກທີ່ສູງກວ່າ $50 ແຕ່ໜ້ອຍກວ່າ $100. ເພື່ອໃຫ້ມັນສໍາເລັດ, ໃສ່ສູດນີ້ຢູ່ໃນ C2 ແລະຫຼັງຈາກນັ້ນຄັດລອກມັນລົງໃນຖັນ:

=IF(AND(B2>50, B2<100), "x", "")

ຖ້າທ່ານຕ້ອງການລວມເອົາ ຂອບເຂດ ຄ່າ (50 ແລະ 100), ໃຊ້ຕົວປະຕິບັດການ ນ້ອຍກວ່າ ຫຼືເທົ່າກັບ (<=) ແລະ ໃຫຍ່ກວ່າ ຫຼືເທົ່າກັບ (>=) ໂຕດຳເນີນການ:

=IF(AND(B2>=50, B2<=100), "x", "")

ເພື່ອປະມວນຜົນບາງອັນຄ່າຂອບເຂດໂດຍບໍ່ມີການປ່ຽນແປງສູດ, ໃສ່ຕົວເລກຕໍາ່ສຸດທີ່ແລະສູງສຸດໃນສອງຈຸລັງແຍກຕ່າງຫາກແລະອ້າງອີງເຖິງຈຸລັງເຫຼົ່ານັ້ນໃນສູດຂອງທ່ານ. ເພື່ອໃຫ້ສູດຄຳນວນເຮັດວຽກໄດ້ຢ່າງຖືກຕ້ອງໃນທຸກແຖວ, ໃຫ້ແນ່ໃຈວ່າໃຊ້ການອ້າງອີງຢ່າງແທ້ຈິງສຳລັບຕາລາງຂອບເຂດ ($F$1 ແລະ $F$2 ໃນກໍລະນີຂອງພວກເຮົາ):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

ໂດຍ​ການ​ນໍາ​ໃຊ້​ສູດ​ທີ່​ຄ້າຍ​ຄື​ກັນ​, ທ່ານ​ສາ​ມາດ​ກວດ​ສອບ​ວ່າ date ຕົກ ຢູ່​ພາຍ​ໃນ​ລະ​ດັບ​ທີ່​ກໍາ​ນົດ​ໄວ້ .

ຕົວ​ຢ່າງ, ໃຫ້​ຫມາຍ​ວັນ​ທີ​ລະ​ຫວ່າງ 10. -Sep-2018 ແລະ 30-Sep-2018, ລວມ. ອຸປະສັກເລັກໆນ້ອຍໆແມ່ນວ່າວັນທີບໍ່ສາມາດຖືກສະຫນອງໃຫ້ແກ່ການທົດສອບຢ່າງມີເຫດຜົນໂດຍກົງ. ເພື່ອໃຫ້ Excel ເຂົ້າໃຈວັນທີ, ພວກມັນຄວນຈະຖືກໃສ່ໄວ້ໃນຟັງຊັນ DATEVALUE, ເຊັ່ນນີ້:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

ຫຼືພຽງແຕ່ໃສ່ ຈາກ ແລະ ເຖິງ ວັນທີໃນສອງເຊລ ($F$1 ແລະ $F$2 ໃນຕົວຢ່າງນີ້) ແລະ "ດຶງ" ພວກມັນອອກຈາກເຊລເຫຼົ່ານັ້ນໂດຍໃຊ້ສູດ IF AND ທີ່ຄຸ້ນເຄີຍແລ້ວ:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

ສຳລັບຂໍ້ມູນເພີ່ມເຕີມ, ກະລຸນາເບິ່ງຄຳຖະແຫຼງ Excel IF ລະຫວ່າງສອງຕົວເລກ ຫຼືວັນທີ.

ຖ້າອັນນີ້ ແລະອັນນັ້ນ, ຈາກນັ້ນໃຫ້ຄຳນວນບາງຢ່າງ

ນອກຈາກຄ່າທີ່ກຳນົດໄວ້ກ່ອນແລ້ວ, Excel IF AND ຟັງຊັນຍັງສາມາດປະຕິບັດການຄິດໄລ່ທີ່ແຕກຕ່າງກັນຂຶ້ນກັບວ່າເງື່ອນໄຂທີ່ລະບຸໄວ້ເປັນຄວາມຈິງຫຼືຜິດ.

ເພື່ອສະແດງໃຫ້ເຫັນວິທີການ, ພວກເຮົາຈະຄິດໄລ່ເງິນໂບນັດຂອງ 5% ສໍາລັບການຂາຍ "ປິດ" ທີ່ມີຈໍານວນຫຼາຍກ່ວາຫຼືເທົ່າກັບ. ເປັນ $100.

ສົມມຸດວ່າຈໍານວນຢູ່ໃນຖັນ B ແລະສະຖານະຄໍາສັ່ງໃນຖັນ C,ສູດ​ດັ່ງ​ຕໍ່​ໄປ​ນີ້:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

ສູດ​ຂ້າງ​ເທິງ​ມອບ​ສູນ​ສູນ​ກັບ​ສ່ວນ​ທີ່​ເຫຼືອ​ຂອງ​ຄໍາ​ສັ່ງ ( value_if_false = 0​) . ຖ້າທ່ານເຕັມໃຈທີ່ຈະໃຫ້ໂບນັດກະຕຸ້ນເລັກນ້ອຍ, ໃຫ້ເວົ້າວ່າ 3%, ໃນຄໍາສັ່ງທີ່ບໍ່ກົງກັບເງື່ອນໄຂ, ປະກອບມີສົມຜົນທີ່ສອດຄ້ອງກັນໃນ argument value_if_false :

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

ຫຼາຍ IF AND statements ໃນ Excel

ດັ່ງທີ່ເຈົ້າອາດຈະສັງເກດເຫັນ, ພວກເຮົາໄດ້ປະເມີນພຽງແຕ່ສອງເງື່ອນໄຂໃນຕົວຢ່າງຂ້າງເທິງທັງໝົດ. ແຕ່ບໍ່ມີຫຍັງທີ່ຈະປ້ອງກັນບໍ່ໃຫ້ທ່ານລວມເອົາການທົດສອບສາມແລະຫຼາຍກວ່ານັ້ນຢູ່ໃນສູດ IF AND ຂອງທ່ານຕາບໃດທີ່ພວກມັນປະຕິບັດຕາມຂໍ້ຈໍາກັດທົ່ວໄປເຫຼົ່ານີ້ຂອງ Excel:

• ໃນ Excel 2007 ແລະສູງກວ່າ, ສູງເຖິງ 255 argument ສາມາດໃຊ້ໃນສູດໄດ້, ໂດຍມີຄວາມຍາວທັງໝົດຂອງສູດບໍ່ເກີນ 8,192 ຕົວອັກສອນ.
• ໃນ Excel 2003 ແລະຕ່ໍາກວ່າ, ບໍ່ເກີນ 30 argument ແມ່ນອະນຸຍາດໃຫ້ມີຄວາມຍາວທັງໝົດບໍ່ເກີນ 1,024 ຕົວອັກສອນ.

ເປັນຕົວຢ່າງຂອງຫຼາຍເງື່ອນໄຂ AND, ກະລຸນາພິຈາລະນາອັນເຫຼົ່ານີ້:

• ຈຳນວນ (B2) ຄວນຫຼາຍກວ່າ ຫຼືເທົ່າກັບ $100
• ສະຖານະການສັ່ງຊື້ (C2) ແມ່ນ "ປິດ"
• ວັນທີຈັດສົ່ງ (D2) ແມ່ນພາຍໃນເດືອນປະຈຸບັນ

ຕອນນີ້, ພວກເຮົາຕ້ອງການຄໍາຖະແຫຼງ IF AND ເພື່ອລະບຸຄໍາສັ່ງທີ່ທັງ 3 ເງື່ອນໄຂແມ່ນຖືກຕ້ອງ. ແລະນີ້ແມ່ນ:

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

ເນື່ອງມາຈາກວ່າ 'ເດືອນປັດຈຸບັນ' ໃນຂະນະຂຽນແມ່ນເດືອນຕຸລາ, ສູດໃຫ້ຜົນໄດ້ຮັບຂ້າງລຸ່ມນີ້:

Nested ຖ້າ ANDຖະແຫຼງການ

ເມື່ອເຮັດວຽກກັບແຜ່ນວຽກໃຫຍ່, ໂອກາດທີ່ທ່ານອາດຈະຕ້ອງກວດເບິ່ງຊຸດຂອງເງື່ອນໄຂ AND ທີ່ແຕກຕ່າງກັນຫຼາຍຄັ້ງຕໍ່ຄັ້ງ. ສໍາລັບການນີ້, ທ່ານໃຊ້ສູດ Excel ຄລາສສິກທີ່ຊ້ອນກັນ IF ແລະຂະຫຍາຍການທົດສອບຢ່າງມີເຫດຜົນດ້ວຍຄໍາຖະແຫຼງທີ່ AND, ເຊັ່ນ:

ເພື່ອໃຫ້ໄດ້ແນວຄວາມຄິດທົ່ວໄປ, ກະລຸນາເບິ່ງຕົວຢ່າງຕໍ່ໄປນີ້.

ສົມມຸດວ່າທ່ານຕ້ອງການໃຫ້ຄະແນນການບໍລິການຂອງທ່ານໂດຍອີງໃສ່ຄ່າຂົນສົ່ງ ແລະເວລາຈັດສົ່ງໂດຍປະມານ (ETD):

• ດີເລີດ : ຄ່າຂົນສົ່ງຕ່ຳກວ່າ $20 ແລະ ETD ພາຍໃຕ້ 3 ມື້
• ບໍ່ດີ : ຄ່າຂົນສົ່ງເກີນ $30 ແລະ ETD ໃນໄລຍະ 5 ມື້
• ສະເລ່ຍ : ທຸກຢ່າງໃນລະຫວ່າງ

ເຖິງ ສຳເລັດແລ້ວ, ທ່ານຂຽນຂໍ້ຄວາມ IF AND ແຕ່ລະອັນ:

IF(AND(B2<20, C2<3), "Excellent", …)

IF(AND(B2>30, C2>5), "Poor", …)

… ແລະວາງອັນໜຶ່ງໃສ່ອີກອັນໜຶ່ງ:

=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

ຜົນໄດ້ຮັບຈະມີລັກສະນະຄ້າຍຄືກັນກັບອັນນີ້:

ຕົວຢ່າງສູດເພີ່ມເຕີມສາມາດພົບໄດ້ໃນ Excel ຊ້ອນກັນ IF AND statements.

ຕົວພິມນ້ອຍໃຫຍ່ IF AND. ຟັງຊັນໃນ Excel

ດັ່ງທີ່ໄດ້ກ່າວໃນຕອນຕົ້ນຂອງບົດສອນນີ້, ສູດ Excel IF AND ບໍ່ໄດ້ຈໍາແນກລະຫວ່າງຕົວພິມໃຫຍ່ ແລະ ຕົວພິມນ້ອຍ. ເນື່ອງຈາກວ່າຟັງຊັນ AND ແມ່ນບໍ່ຖືກຕົວພິມນ້ອຍໂດຍທໍາມະຊາດ.

ຖ້າທ່ານເຮັດວຽກກັບຂໍ້ມູນ ຕົວພິມນ້ອຍໃຫຍ່ ແລະຕ້ອງການປະເມີນເງື່ອນໄຂ AND ໂດຍຄໍານຶງເຖິງກໍລະນີຂໍ້ຄວາມ, ເຮັດການທົດສອບຕາມເຫດຜົນແຕ່ລະຄົນ. ພາຍໃນຟັງຊັນ EXACT ແລະຮັງຟັງຊັນເຫຼົ່ານັ້ນເຂົ້າໄປໃນຄໍາຖະແຫຼງທີ່ AND ຂອງທ່ານ:

ສໍາລັບຕົວຢ່າງນີ້, ພວກເຮົາຈະລາຍງານຄໍາສັ່ງຂອງລູກຄ້າສະເພາະ (ເຊັ່ນ: ບໍລິສັດຊື່ Cyberspace ) ທີ່ມີຈໍານວນເກີນຈໍານວນທີ່ແນ່ນອນ, ເວົ້າວ່າ. $100.

ດັ່ງທີ່ເຈົ້າເຫັນໃນພາບໜ້າຈໍລຸ່ມນີ້, ບາງຊື່ບໍລິສັດໃນຖັນ B ມີລັກສະນະດຽວກັນກັບຕົວລະຄອນທີ່ຫຍໍ້ມາຈາກຕົວໜັງສື, ແລະແນວໃດກໍ່ຕາມພວກມັນແມ່ນບໍລິສັດຕ່າງກັນ, ດັ່ງນັ້ນພວກເຮົາຕ້ອງກວດເບິ່ງຊື່ ແທ້ . ຈໍານວນຢູ່ໃນຖັນ C ແມ່ນຕົວເລກ, ແລະພວກເຮົາດໍາເນີນການທົດສອບ "ຫຼາຍກ່ວາ" ປົກກະຕິສໍາລັບພວກເຂົາ:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

ເພື່ອເຮັດໃຫ້ສູດມີຄວາມຍືດຫຍຸ່ນຫຼາຍ, ທ່ານສາມາດໃສ່ຊື່ລູກຄ້າເປົ້າຫມາຍແລະຈໍານວນ. ໃນສອງຈຸລັງແຍກຕ່າງຫາກແລະຫມາຍເຖິງຈຸລັງເຫຼົ່ານັ້ນ. ພຽງແຕ່ຈື່ໄວ້ວ່າລັອກການອ້າງອີງຕາລາງດ້ວຍ $ sign ($G$1 ແລະ $G$2 ໃນກໍລະນີຂອງພວກເຮົາ) ດັ່ງນັ້ນພວກມັນຈະບໍ່ປ່ຽນແປງເມື່ອທ່ານສຳເນົາສູດຄຳນວນໄປໃສ່ແຖວອື່ນ:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

ດຽວນີ້, ທ່ານສາມາດພິມຊື່ ແລະຈຳນວນໃດນຶ່ງໃນເຊລທີ່ອ້າງອີງໄດ້, ແລະສູດຄຳນວນຈະໝາຍຄໍາສັ່ງທີ່ກົງກັນໃນຕາຕະລາງຂອງເຈົ້າ:

IF OR AND ສູດໃນ Excel

ໃນ Excel IF ສູດ, ທ່ານບໍ່ຈໍາກັດພຽງແຕ່ໃຊ້ຫນຶ່ງຟັງຊັນຢ່າງມີເຫດຜົນ. ເພື່ອກວດສອບການລວມກັນຂອງຫຼາຍເງື່ອນໄຂ, ທ່ານສາມາດສົມທົບການ IF, AND, OR ແລະຟັງຊັນອື່ນໆເພື່ອດໍາເນີນການທົດສອບຕາມເຫດຜົນທີ່ຕ້ອງການ. ນີ້ແມ່ນຕົວຢ່າງຂອງສູດ IF AND OR ທີ່ທົດສອບສອງສາມອັນOR ເງື່ອນໄຂພາຍໃນ AND. ແລະດຽວນີ້, ຂ້ອຍຈະສະແດງວິທີທີ່ເຈົ້າສາມາດເຮັດສອງຫຼືຫຼາຍກວ່ານັ້ນ AND ການທົດສອບພາຍໃນຫນ້າທີ່ OR.

ໃນພາສາ Excel, ເງື່ອນໄຂຂອງພວກເຮົາສະແດງອອກໃນລັກສະນະນີ້:

OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

ສົມມຸດວ່າຊື່ລູກຄ້າຢູ່ໃນຖັນ B, ຈໍານວນຢູ່ໃນຖັນ C, 2 ຊື່ເປົ້າຫມາຍ. ແມ່ນຢູ່ໃນ G1 ແລະ G2, ແລະຈໍານວນເປົ້າຫມາຍແມ່ນຢູ່ໃນ G3, ທ່ານໃຊ້ສູດນີ້ເພື່ອຫມາຍຄໍາສັ່ງທີ່ສອດຄ້ອງກັນດ້ວຍ "x":

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

ຜົນໄດ້ຮັບດຽວກັນສາມາດບັນລຸໄດ້ຫຼາຍ. syntax ຫຍໍ້:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

ບໍ່ແນ່ໃຈວ່າທ່ານເຂົ້າໃຈເຫດຜົນຂອງສູດທັງຫມົດບໍ? ຂໍ້ມູນເພີ່ມເຕີມສາມາດພົບໄດ້ໃນ Excel IF ດ້ວຍເງື່ອນໄຂ AND/OR ຫຼາຍອັນ.

ນັ້ນແມ່ນວິທີທີ່ທ່ານໃຊ້ຟັງຊັນ IF ແລະ AND ຮ່ວມກັນໃນ Excel. ຂອບໃຈສໍາລັບການອ່ານແລະພົບທ່ານໃນອາທິດຕໍ່ໄປ!