ट्यूटोरियल दिखाता है कि एक सूत्र में कई स्थितियों की जांच करने के लिए एक्सेल में AND फ़ंक्शन के साथ IF का उपयोग कैसे करें।

दुनिया में कुछ चीजें परिमित हैं। अन्य अनंत हैं, और IF फ़ंक्शन ऐसी चीजों में से एक प्रतीत होता है। हमारे ब्लॉग पर, हमारे पास पहले से ही मुट्ठी भर एक्सेल IF ट्यूटोरियल हैं और फिर भी हर दिन नए उपयोगों की खोज करते हैं। आज, हम यह देखने जा रहे हैं कि आप एक ही समय में दो या दो से अधिक स्थितियों का मूल्यांकन करने के लिए AND फ़ंक्शन के साथ IF का उपयोग कैसे कर सकते हैं।

Excel में IF AND कथन

IF AND कथन बनाने के लिए, आपको स्पष्ट रूप से IF और AND फ़ंक्शन को एक सूत्र में संयोजित करने की आवश्यकता है। यहां बताया गया है कि कैसे:

सामान्य अंग्रेजी में अनुवादित, फ़ॉर्मूला इस प्रकार है: IF शर्त 1 सही है और शर्त 2 सही है, एक काम करें, अन्यथा कुछ और करें। , निम्न में से कोई एक करता है:

• यदि दोनों स्थितियाँ सत्य हैं, तो आदेश को "बंद" के रूप में चिह्नित करें।
• यदि कोई भी स्थिति FALSE है या दोनों FALSE हैं, तो एक खाली लौटाएँ string ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

नीचे दिया गया स्क्रीनशॉट एक्सेल में IF AND फ़ंक्शन दिखाता है:

अगर आप यदि तार्किक परीक्षण FALSE का मूल्यांकन करता है, तो कुछ मान लौटाना चाहते हैं, उस मान को value_if_false में प्रदान करेंबहस। उदाहरण के लिए:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

यदि कॉलम B "डिलीवर" किया गया है और C में कोई दिनांक है (गैर-खाली) तो संशोधित सूत्र "बंद" आउटपुट करता है। अन्य सभी मामलों में, यह "ओपन" लौटाता है:

नोट। पाठ की स्थिति का मूल्यांकन करने के लिए Excel में IF AND सूत्र का उपयोग करते समय, कृपया ध्यान रखें कि लोअरकेस और अपरकेस को एक ही वर्ण के रूप में माना जाता है। यदि आप एक केस-संवेदी IF AND सूत्र की तलाश कर रहे हैं, तो AND के एक या अधिक तर्कों को EXACT फ़ंक्शन में लपेटें जैसा कि लिंक किए गए उदाहरण में किया गया है।

अब जब आप एक्सेल IF AND स्टेटमेंट के सिंटैक्स को जानते हैं, तो मैं आपको दिखाता हूं कि यह किस प्रकार के कार्यों को हल कर सकता है।

एक्सेल IF: इससे अधिक और इससे कम

में पिछले उदाहरण में, हम दो अलग-अलग सेल में दो स्थितियों का परीक्षण कर रहे थे। लेकिन कभी-कभी आपको एक ही सेल पर दो या अधिक परीक्षण करने पड़ सकते हैं। एक विशिष्ट उदाहरण यह जाँच रहा है कि क्या सेल का मान दो संख्याओं के बीच है। एक्सेल IF AND फ़ंक्शन भी आसानी से ऐसा कर सकता है!

मान लें कि आपके पास कॉलम B में कुछ बिक्री संख्याएं हैं और आपसे $50 से अधिक लेकिन $100 से कम राशि को फ़्लैग करने का अनुरोध किया जाता है। ऐसा करने के लिए, इस सूत्र को C2 में डालें और फिर इसे कॉलम के नीचे कॉपी करें:

=IF(AND(B2>50, B2<100), "x", "")

अगर आपको सीमा शामिल करने की आवश्यकता है मान (50 और 100), इससे कम या इसके बराबर संचालिका (<=) और इससे अधिक या बराबर (>=) संचालिका का उपयोग करें:<3

=IF(AND(B2>=50, B2<=100), "x", "")

कुछ और प्रोसेस करने के लिएसूत्र को बदले बिना सीमा मान, दो अलग-अलग कक्षों में न्यूनतम और अधिकतम संख्या दर्ज करें और उन कक्षों को अपने सूत्र में देखें। सूत्र सभी पंक्तियों में सही ढंग से काम करे, इसके लिए सीमा कोशिकाओं के लिए पूर्ण संदर्भों का उपयोग करना सुनिश्चित करें (हमारे मामले में $F$1 और $F$2):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

समान सूत्र का उपयोग करके, आप जांच सकते हैं कि दिनांक निर्दिष्ट सीमा के भीतर आता है या नहीं।

उदाहरण के लिए, आइए 10 के बीच तिथियों को चिह्नित करें -सितंबर-2018 और 30-सितंबर-2018, सहित। एक छोटी सी बाधा यह है कि तार्किक परीक्षणों को सीधे तारीखें नहीं दी जा सकतीं। एक्सेल के लिए तारीखों को समझने के लिए, उन्हें DATEVALUE फ़ंक्शन में संलग्न किया जाना चाहिए, जैसे:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

या बस से और से<2 इनपुट करें> दो सेल में दिनांक (इस उदाहरण में $F$1 और $F$2) और पहले से परिचित IF AND सूत्र का उपयोग करके उन्हें उन सेल से "खींचें":

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

अधिक जानकारी के लिए, कृपया दो संख्याओं या तिथियों के बीच एक्सेल IF स्टेटमेंट देखें।

यदि यह और वह, तो कुछ गणना करें

पूर्वनिर्धारित मान लौटाने के अलावा, एक्सेल IF AND फ़ंक्शन निर्दिष्ट शर्तों के TRUE या FALSE के आधार पर अलग-अलग गणना भी कर सकता है।

दृष्टिकोण प्रदर्शित करने के लिए, हम "बंद" बिक्री के लिए 5% के बोनस की गणना करेंगे, जिसकी राशि इससे अधिक या बराबर होगी। $100 तक।

यह मानते हुए कि राशि कॉलम बी में है और ऑर्डर की स्थिति कॉलम सी में है,सूत्र इस प्रकार है:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

उपरोक्त सूत्र शेष आदेशों के लिए शून्य निर्दिष्ट करता है ( value_if_false = 0) . यदि आप शर्तों को पूरा नहीं करने वाले ऑर्डर के लिए एक छोटा उत्तेजक बोनस, 3% कहते हैं, देने के इच्छुक हैं, तो value_if_false तर्क में संबंधित समीकरण शामिल करें:

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

एक्सेल में एकाधिक IF AND कथन

जैसा कि आपने देखा होगा, हमने उपरोक्त सभी उदाहरणों में केवल दो मानदंडों का मूल्यांकन किया है। लेकिन ऐसा कुछ भी नहीं है जो आपको अपने IF AND फ़ार्मुलों में तीन या अधिक परीक्षणों को शामिल करने से रोकेगा जब तक कि वे Excel की इन सामान्य सीमाओं का अनुपालन करते हैं:

• Excel 2007 और उच्चतर में, 255 तर्कों तक सूत्र में उपयोग किया जा सकता है, जिसकी कुल सूत्र लंबाई 8,192 वर्णों से अधिक नहीं है।
• Excel 2003 और उससे कम में, 30 से अधिक तर्कों की अनुमति नहीं है, जिसकी कुल लंबाई 1,024 वर्णों से अधिक नहीं है।

कई AND शर्तों के उदाहरण के रूप में, कृपया इन पर विचार करें:

• राशि (B2) $100 से अधिक या उसके बराबर होनी चाहिए
• आदेश की स्थिति (C2) "बंद" है
• डिलीवरी की तारीख (D2) चालू माह के भीतर है

अब, हमें उन ऑर्डर की पहचान करने के लिए एक IF AND स्टेटमेंट की आवश्यकता है जिसके लिए सभी 3 शर्तें TRUE हैं। और यहाँ यह है:

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

यह देखते हुए कि लेखन के समय 'वर्तमान माह' अक्टूबर था, सूत्र नीचे दिए गए परिणाम देता है:

नेस्टेड IF ANDकथन

बड़ी वर्कशीट के साथ काम करते समय, संभावना है कि आपको एक समय में अलग-अलग AND मानदंडों के कुछ सेटों की जांच करने की आवश्यकता हो सकती है। इसके लिए, आप एक क्लासिक एक्सेल नेस्टेड IF फॉर्मूला लेते हैं और इसके तार्किक परीक्षणों को AND स्टेटमेंट्स के साथ बढ़ाते हैं, जैसे:

सामान्य विचार प्राप्त करने के लिए, कृपया निम्न उदाहरण देखें।

मान लें कि आप अपनी सेवा को शिपमेंट लागत और डिलीवरी के अनुमानित समय (ETD) के आधार पर रेट करना चाहते हैं:

• उत्कृष्ट : $20 के तहत शिपमेंट लागत और 3 दिनों के तहत ETD
• खराब : शिपमेंट लागत $30 से अधिक और ETD 5 दिनों में
• औसत : बीच में कुछ भी

तक इसे पूरा करें, आप दो अलग-अलग IF AND स्टेटमेंट लिखते हैं:

IF(AND(B2<20, C2<3), "Excellent", …)

IF(AND(B2>30, C2>5), "Poor", …)

…और एक को दूसरे में नेस्ट करें:

=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

परिणाम इसके समान दिखाई देगा:

Excel नेस्टेड IF AND कथनों में अधिक सूत्र उदाहरण मिल सकते हैं।

केस-संवेदी IF AND एक्सेल में कार्य

जैसा कि इस ट्यूटोरियल की शुरुआत में उल्लेख किया गया है, एक्सेल IF AND सूत्र अपरकेस और लोअरकेस वर्णों के बीच अंतर नहीं करते हैं क्योंकि AND फ़ंक्शन स्वभाव से केस-असंवेदनशील है।

यदि आप केस-संवेदी डेटा के साथ काम कर रहे हैं और टेक्स्ट केस को ध्यान में रखते हुए AND शर्तों का मूल्यांकन करना चाहते हैं, तो प्रत्येक व्यक्तिगत तार्किक परीक्षण करें EXACT फ़ंक्शन और नेस्ट के अंदरवे कार्य आपके AND कथन में:

इस उदाहरण के लिए, हम एक विशिष्ट ग्राहक (जैसे कि साइबरस्पेस नाम की कंपनी) के ऑर्डर फ़्लैग करने जा रहे हैं, जिनकी राशि एक निश्चित संख्या से अधिक है, मान लीजिए $100.

जैसा कि आप नीचे दिए गए स्क्रीनशॉट में देख सकते हैं, कॉलम B में कुछ कंपनी के नाम वर्णों के मामले में समान अंश दिखते हैं, और फिर भी वे अलग-अलग कंपनियां हैं, इसलिए हमें नामों की जांच करनी होगी बिल्कुल< । कॉलम C में राशियाँ संख्याएँ हैं, और हम उनके लिए एक नियमित "से अधिक" परीक्षण चलाते हैं:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

सूत्र को अधिक लचीला बनाने के लिए, आप लक्षित ग्राहक का नाम और राशि इनपुट कर सकते हैं दो अलग-अलग सेल में और उन सेल को देखें। बस सेल संदर्भों को $ चिन्ह (हमारे मामले में $G$1 और $G$2) के साथ लॉक करना याद रखें ताकि जब आप सूत्र को अन्य पंक्तियों में कॉपी करेंगे तो वे नहीं बदलेंगे:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

अब, आप संदर्भित कक्षों में कोई भी नाम और राशि टाइप कर सकते हैं, और सूत्र आपकी तालिका में संबंधित आदेशों को फ़्लैग करेगा:

IF OR AND सूत्र Excel में

Excel IF सूत्रों में, आप केवल एक तार्किक फ़ंक्शन का उपयोग करने तक सीमित नहीं हैं। कई स्थितियों के विभिन्न संयोजनों की जांच करने के लिए, आप आवश्यक तार्किक परीक्षण चलाने के लिए IF, AND, OR और अन्य कार्यों को संयोजित करने के लिए स्वतंत्र हैं। यहाँ IF AND OR सूत्र का एक उदाहरण दिया गया है जो कुछ का परीक्षण करता हैया AND के भीतर स्थितियां। और अब, मैं आपको दिखाऊंगा कि आप OR फ़ंक्शन के भीतर दो या अधिक AND परीक्षण कैसे कर सकते हैं।

मान लीजिए, आप दो ग्राहकों के ऑर्डर को एक निश्चित संख्या से अधिक राशि के साथ चिह्नित करना चाहते हैं, मान लीजिए $100।

एक्सेल भाषा में, हमारी शर्तें इस प्रकार व्यक्त की जाती हैं:

OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

मान लें कि ग्राहक के नाम कॉलम बी में हैं, राशियां कॉलम सी में हैं, 2 लक्ष्य नाम G1 और G2 में हैं, और लक्ष्य राशि G3 में है, आप इस सूत्र का उपयोग "x" के साथ संबंधित ऑर्डर को चिह्नित करने के लिए करते हैं:

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

वही परिणाम अधिक के साथ प्राप्त किए जा सकते हैं कॉम्पैक्ट सिंटैक्स:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

सुनिश्चित नहीं हैं कि आप सूत्र के तर्क को पूरी तरह से समझते हैं? एकाधिक AND/OR शर्तों के साथ Excel IF में अधिक जानकारी प्राप्त की जा सकती है।

इस प्रकार आप Excel में IF और AND फ़ंक्शन का एक साथ उपयोग करते हैं। पढ़ने और अगले सप्ताह आपसे मिलने के लिए धन्यवाद!

अभ्यास कार्यपुस्तिका

IF AND Excel - सूत्र उदाहरण (.xlsx फ़ाइल)