Kennsluefnið útskýrir Excel REPLACE og SUBSTITUTE aðgerðirnar með dæmum um notkun. Sjáðu hvernig á að nota REPLACE aðgerðina með textastrengjum, tölum og dagsetningum og hvernig á að hreiðra nokkrar REPLACE eða SUBSTITUTE föll innan einni formúlu.

Í síðustu viku ræddum við ýmsar leiðir til að nota FIND og SEARCH aðgerðir innan Excel vinnublöðin þín. Í dag munum við skoða tvær aðrar aðgerðir dýpra til að skipta út texta í reit út frá staðsetningu hans eða skipta út einum textastreng fyrir annan út frá innihaldi. Eins og þú hefur kannski giskað á þá er ég að tala um Excel REPLACE og SUBSTITUTE aðgerðirnar.

Excel REPLACE aðgerðin

REPLACE aðgerðin í Excel gerir þér kleift að skipta um eina eða fleiri stafir í textastreng með öðrum staf eða setti af stöfum.

Eins og þú sérð hefur Excel REPLACE aðgerðin 4 frumbreytur, sem öll eru nauðsynleg.

• Gamall_texti - upprunalega textinn (eða tilvísun í hólf með upprunalega textanum) þar sem þú vilt skipta út sumum stöfum.
• Start_num - staðsetning fyrsta stafa innan old_text sem þú vilt skipta út.
• Fjöldi_stafa - fjöldi stafa sem þú vilt skipta út.
• New_text - skiptitextinn.

Til dæmis, til að breyta orðinu " sun " í " son ", geturðu notað eftirfarandiformúla:

=REPLACE("sun", 2, 1, "o")

Og ef þú setur upprunalega orðið í einhvern reit, segjum A2, geturðu gefið upp samsvarandi frumutilvísun í old_text argumentinu:

=REPLACE(A2, 2, 1, "o")

Athugið. Ef upphaf_tala eða tölustafir eru neikvæðar eða ekki tölulegar, skilar Excel Replace formúlunni #VALUE! villa.

Að nota Excel REPLACE aðgerð með tölugildum

REPLACE aðgerðin í Excel er hönnuð til að vinna með textastrengi. Auðvitað geturðu notað það til að skipta út tölustöfum sem eru hluti af textastreng, til dæmis:

=REPLACE(A2, 7, 4, "2016")

Athugið að við látum fylgja með "2016 " í tvöföldum gæsalöppum eins og þú gerir venjulega með textagildi.

Á svipaðan hátt geturðu skipt út einum eða fleiri tölustöfum í tölu. Til dæmis:

=REPLACE(A4, 4, 4,"6")

Og aftur, þú verður að setja skiptigildið innan tveggja gæsalappa ("6").

Athugið. Excel REPLACE formúla skilar alltaf textastreng , ekki tölu. Á skjámyndinni hér að ofan, taktu eftir vinstri röðun textagildisins sem skilað er í B2 og berðu það saman við hægrijafnaða upprunalega töluna í A2. Og vegna þess að það er textagildi muntu ekki geta notað það í öðrum útreikningum nema þú breytir því aftur í tölu, til dæmis með því að margfalda með 1 eða með því að nota aðra aðferð sem lýst er í Hvernig á að breyta texta í tölu.

Að nota Excel REPLACE aðgerðina með dagsetningum

Eins og þú hefur séð nýlega virkar REPLACE aðgerðin vel meðtölur, nema að það skilar textastreng :) Mundu að í innra Excel kerfinu eru dagsetningar geymdar sem tölur, þú gætir prófað að nota nokkrar Skipta út formúlur á dagsetningum. Niðurstöður væru frekar vandræðalegar.

Til dæmis, þú ert með dagsetningu í A2, segjum 1-okt-14, og þú vilt breyta " okt " í " nóv ". Svo þú skrifar formúluna REPLACE(A2, 4, 3, "nóv") sem segir Excel að skipta út 3 stöfum í hólfum A2 sem byrjar á 4. stafnum... og fékk eftirfarandi niðurstöðu:

Af hverju er það? Vegna þess að "01-Oct-14" er aðeins sjónræn framsetning á undirliggjandi raðnúmeri (41913) sem táknar dagsetninguna. Þannig að Skipta út formúlan okkar breytir síðustu 3 tölustöfunum í ofangreindu raðnúmeri í " Nóv " og skilar textastrengnum "419Nov".

Til að fá Excel REPLACE aðgerðina til að virka rétt með dagsetningar, þú getur fyrst umbreytt dagsetningum í textastrengi með því að nota TEXT aðgerðina eða aðra tækni sem sýnd er í Hvernig á að breyta dagsetningu í texta í Excel. Að öðrum kosti geturðu fellt TEXT fallið beint inn í old_text argumentið í REPLACE fallinu:

=REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov")

Vinsamlegast mundu að niðurstaða formúlunnar hér að ofan er textastreng og því virkar þessi lausn aðeins ef þú ætlar ekki að nota breyttar dagsetningar í frekari útreikningum. Ef þú þarft dagsetningar frekar en textastrengi skaltu nota DATEVALUE fallið til að breyta gildunum sem skilað er afExcel REPLACE aðgerðin aftur til dagsetninga:

=DATEVALUE(REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov"))

Nested REPLACE aðgerðir til að gera margar skipti í reit

Oft oft gætirðu þurft að gera fleiri en eina skipti í sama klefan. Auðvitað gætirðu skipt út einu sinni, gefið út milliniðurstöðu í viðbótardálk og síðan notað REPLACE aðgerðina aftur. Hins vegar er betri og faglegri leið að nota hreiðrað REPLACE aðgerðir sem gera þér kleift að skipta út nokkrum sinnum með einni formúlu. Í þessu samhengi þýðir "hreiðrið" að setja eina aðgerð inn í aðra.

Lítum á eftirfarandi dæmi. Segjum sem svo að þú hafir lista yfir símanúmer í dálki A sniðinn sem "123456789" og þú vilt láta þau líta meira út eins og símanúmer með því að bæta við bandstrikum. Með öðrum orðum, markmið þitt er að breyta "123456789" í "123-456-789".

Auðvelt er að setja inn fyrsta bandstrikið. Þú skrifar venjulega Excel Replace formúlu sem kemur í stað núll stafa fyrir bandstrik, þ.e. bætir við bandstrik í 4. stöðu í reit:

=REPLACE(A2,4,0,"-")

Niðurstaðan af hér að ofan Skipta út formúlu er sem hér segir:

Allt í lagi, og nú þurfum við að setja eitt bandstrik í viðbót í 8. stöðu. Til að gera þetta seturðu ofangreinda formúlu í aðra Excel REPLACE aðgerð. Nánar tiltekið, þú fellir það inn í gamall_texti rökin í hinni fallinu, þannig að annað REPLACE fallið mun sjá um gildið sem skilað er affyrst REPLACE, en ekki gildið í reit A2:

=REPLACE(REPLACE(A2,4,0,"-"),8,0,"-")

Sem afleiðing færðu símanúmerin í æskilegu sniði:

Á svipaðan hátt geturðu notað hreiðrað REPLACE aðgerðir til að láta textastrengi líta út eins og dagsetningar með því að bæta við skástrik (/) þar sem við á:

=(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

Þar að auki geturðu umbreytt textastrengjum í alvöru dagsetningar með því að vefja ofangreindri REPLACE formúlu með DATEVALUE fallinu:

=DATEVALUE(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

Og náttúrulega ertu ekki takmarkaður við fjölda aðgerða þú getur hreiðrað innan einni formúlu (nútímaútgáfur af Excel 2010, 2013 og 2016 leyfa allt að 8192 stafi og allt að 64 hreiður föll í formúlu).

Til dæmis geturðu notað 3 hreiðrað REPLACE föll til að láta tala í A2 birtast eins og dagsetning og tími:

=REPLACE(REPLACE(REPLACE(REPLACE(A2,3,0,"/") ,6,0,"/"), 9,0, " "), 12,0, ":")

Að skipta út streng sem birtist á mismunandi stað í hverjum reit

Hingað til höfum við í öllum dæmunum verið að fást við gildi af svipuðum toga og skipt út í sömu stöðu á í hverri klefa. En raunveruleg verkefni eru oft flóknari en það. Í vinnublöðunum þínum er ekki víst að stafirnir sem á að skipta út séu endilega á sama stað í hverjum reit og því verður þú að finna staðsetningu fyrsta stafsins sem ætti að skipta út. Eftirfarandi dæmi mun sýna hvað ég er að tala um.

Svo sem þú ert með lista yfir tölvupóstheimilisfang í dálki A. Og nafn eins fyrirtækis hefur breyst úr „ABC“ í td „BCA“. Þannig að þú verður að uppfæra öll netföng viðskiptavinanna í samræmi við það.

En vandamálið er að nöfn viðskiptavinarins eru mislöng og þess vegna geturðu ekki tilgreint nákvæmlega hvar fyrirtækisnafnið byrjar. Með öðrum orðum, þú veist ekki hvaða gildi á að gefa upp í upphafsnúmerinu í Excel REPLACE fallinu. Til að komast að því, notaðu Excel FIND aðgerðina til að ákvarða staðsetningu fyrstu bleikjunnar í strengnum "@abc":

=FIND("@abc",A2)

Og gefðu síðan upp FIND aðgerðina hér að ofan í start_num rök fyrir REPLACE formúlunni þinni:

=REPLACE(A2, FIND("@abc",A2), 4, "@bca")

Ábending. Við tökum "@" inn í Excel Find and Replace formúluna okkar til að forðast óviljandi skipti í nafnhluta netfönga. Auðvitað eru mjög litlar líkur á því að slíkar samsvörun eigi sér stað, og samt gætirðu viljað vera á öruggu hliðinni.

Eins og þú sérð á eftirfarandi skjáskoti á formúlan ekki í neinum vandræðum með að finna og skipta út gamall texti með þeim nýja. Hins vegar, ef textastrengurinn sem á að skipta út finnst ekki, skilar formúlan #VALUE! villa:

Og við viljum að formúlan skili upprunalegu netfanginu í stað villunnar. Svo, við skulum fylgja FINN okkar & amp; REPLACE formúlu í IFERROR fallinu:

=IFERROR(REPLACE(A2, FIND("@abc",A2), 4, "@bca"),A2)

Og þessi bætta formúla virkar fullkomlega, er það ekki?

Annað hagnýttNotkun REPLACE fallsins er að skrifa fyrsta stafinn í reit með hástöfum. Alltaf þegar þú ert að fást við lista yfir nöfn, vörur og þess háttar geturðu notað formúluna hér að ofan til að breyta fyrsta stafnum í HÁSTASTAF.

Ábending. Ef þú vilt skipta um upprunalegu gögnin, þá væri auðveldara að nota Excel FIND and REPLACE valmyndina.

Excel SUBSTITUTE aðgerðin

SUBSTITUTE aðgerðin í Excel kemur í stað eins eða fleiri tilvika af tilteknum staf eða textastreng með tilteknum staf(um).

Setjafræði Excel SUBSTITUTE fallsins er sem hér segir:

Fyrstu þrjú rökin eru nauðsynleg og sú síðasta er valfrjáls.

• Texti - upprunalega textinn sem þú vilt skipta út stöfum í. Hægt að fá sem prófstreng, frumutilvísun eða afleiðing annarrar formúlu.
• Gamall_texti - stafurinn/stafirnir sem þú vilt skipta út.
• Nýr_texti - nýi stafurinn/stafirnir til að skipta um gamla_texta fyrir.
• Tilvik_númer - tilvik gamla_texta sem þú vilt skipta út. Ef því er sleppt verður öllum tilfellum gamla textans breytt í nýja textann.

Til dæmis koma allar formúlurnar hér að neðan í stað "1" fyrir "2" í reit A2, en skila öðrum niðurstöðum eftir því hvaða númer þú gefur upp í síðustu rifrildi:

=SUBSTITUTE(A2, "1", "2", 1) - Kemur í stað fyrsta tilviks "1" með"2".

=SUBSTITUTE(A2, "1", "2", 2) - Skiptir út öðru tilviki "1" fyrir "2".

=SUBSTITUTE(A2, "1", "2") - Skiptir öllum tilvikum "1" út fyrir "2".

Í reynd er SUBSTITUTE aðgerðin einnig notuð til að fjarlægja óæskilega stafi úr frumum. Fyrir raunveruleg dæmi, vinsamlegast sjáðu:

• Hvernig á að fjarlægja stafi eða orð úr streng
• Hvernig á að eyða óæskilegum stöfum úr frumum

Athugið. SUBSTITUTE fallið í Excel er hástafa og hástöfum . Til dæmis kemur eftirfarandi formúla í stað allra tilvika af hástöfum „X“ fyrir „Y“ í reit A2, en hún kemur ekki í stað neinna tilvika af lágstafi „x“.

Skipta mörgum gildum út fyrir einni formúlu (hreiðrað SUBSTITUTE)

Eins og raunin er með Excel REPLACE aðgerðina geturðu varpað nokkrum SUBSTITUTE föllum innan einni formúlu til að gera nokkrar útskiptingar í einu, þ.e.a.s. nokkrir stafir eða undirstrengir með einni formúlu.

Svo sem að þú sért með textastreng eins og " PR1, ML1, T1 " í reit A2, þar sem "PR" stendur fyrir "Project, "ML " stendur fyrir "Milestone" og "T" þýðir "Task". Það sem þú vilt er að skipta út kóðanum þremur með fullum nöfnum. Til að ná þessu geturðu skrifað 3 mismunandi SUBSTITUTE formúlur:

=SUBSTITUTE(A2,"PR", "Project ")

=SUBSTITUTE(A2, "ML", "Milestone ")

=SUBSTITUTE(A2, "T", "Task ")

Og hreiður þá inn í hvort annað:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,"PR","Project "),"ML","Milestone "),"T","Task ")

Taktu eftir að við höfum bætt við bili í lok hver new_text rök til betri vegarlæsileiki.

Til að læra aðrar leiðir til að skipta um mörg gildi í einu, vinsamlegast sjáðu Hvernig á að gera fjöldaleit og skipta út í Excel.

Excel REPLACE vs. Excel SUBSTITUTE

Excel REPLACE og SUBSTITUTE aðgerðirnar eru mjög svipaðar hvort öðru að því leyti að báðar eru hannaðar til að skipta um textastrengi. Munurinn á aðgerðunum tveimur er sem hér segir:

• SUBSTITUTE kemur í stað eins eða fleiri tilvika af tilteknum staf eða textastreng. Þannig að ef þú veist hvaða texta á að skipta út skaltu nota Excel SUBSTITUTE aðgerðina.
• REPLACE breytir stöfum í tiltekinni stöðu textastrengs. Þannig að ef þú veist staðsetningu stafsins/stafanna sem á að skipta út, notaðu Excel REPLACE aðgerðina.
• Staðgengill aðgerðin í Excel gerir kleift að bæta við valkvæðri færibreytu (tilvik_númer) sem tilgreinir hvaða tilvik af old_text ætti að breyta í new_text.

Svona notar þú SUBSTITUTE og REPLACE aðgerðirnar í Excel. Vonandi munu þessi dæmi reynast gagnleg við að leysa verkefni þín. Ég þakka þér fyrir að lesa og vonast til að sjá á blogginu okkar í næstu viku!

Hlaða niður æfingabók

REPLACE and SUBTITUTE formúludæmi (.xlsx skrá)